nixify for Nixers playing along at home

.envrc

@@ -0,0 +1,5 @@
+if ! has nix_direnv_version || ! nix_direnv_version 2.3.0; then
+  source_url "https://raw.githubusercontent.com/nix-community/nix-direnv/2.3.0/direnvrc" "sha256-0gsh4bmn8mfc1iszxvpinkkq652b3wr238qcrqp8rwybmn7pwrqf="
+fi
+
+use flake .

.gitignore

@@ -1 +1,2 @@
 /target
+TODO

TODO

@@ -1,6 +1 @@
-TODO: Make a cup of tea
-TODO: Buy a bread
-TODO: Write the todo app
-DONE: Make a cup of tea
-DONE: Start the stream
-DONE: Have a breakfast
+TODO: Rust Module

default.nix

@@ -0,0 +1,56 @@
+# default.nix
+{ lib
+, naersk
+, stdenv
+, clangStdenv
+, hostPlatform
+, targetPlatform
+, pkg-config
+, libiconv
+, rustfmt
+, cargo
+, rustc
+  # , llvmPackages # Optional
+  # , protobuf     # Optional
+}:
+
+let
+  cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));
+in
+
+naersk.lib."${targetPlatform.system}".buildPackage rec {
+  src = ./.;
+
+  buildInputs = [
+    rustfmt
+    pkg-config
+    cargo
+    rustc
+    libiconv
+  ];
+  checkInputs = [ cargo rustc ];
+
+  doCheck = true;
+  CARGO_BUILD_INCREMENTAL = "false";
+  RUST_BACKTRACE = "full";
+  copyLibs = true;
+
+  # Optional things you might need:
+  #
+  # If you depend on `libclang`:
+  # LIBCLANG_PATH = "${llvmPackages.libclang}/lib";
+  #
+  # If you depend on protobuf:
+  # PROTOC = "${protobuf}/bin/protoc";
+  # PROTOC_INCLUDE = "${protobuf}/include";
+
+  name = cargoToml.package.name;
+  version = cargoToml.package.version;
+
+  meta = with lib; {
+    description = cargoToml.package.description;
+    homepage = cargoToml.package.homepage;
+    license = with licenses; [ mit ];
+    maintainers = with maintainers; [ ];
+  };
+}

flake.nix

@@ -0,0 +1,84 @@
+# flake.nix
+{
+  description = "todo-rs";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    naersk.url = "github:nmattia/naersk";
+    naersk.inputs.nixpkgs.follows = "nixpkgs";
+  };
+
+  outputs = { self, nixpkgs, naersk }:
+    let
+      cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" ];
+      forAllSystems = f: nixpkgs.lib.genAttrs supportedSystems (system: f system);
+    in
+    {
+      overlay = final: prev: {
+        "${cargoToml.package.name}" = final.callPackage ./. { inherit naersk; };
+      };
+
+      packages = forAllSystems (system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [
+              self.overlay
+            ];
+          };
+        in
+        {
+          "${cargoToml.package.name}" = pkgs."${cargoToml.package.name}";
+        });
+
+
+      defaultPackage = forAllSystems (system: (import nixpkgs {
+        inherit system;
+        overlays = [ self.overlay ];
+      })."${cargoToml.package.name}");
+
+      checks = forAllSystems (system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [
+              self.overlay
+            ];
+          };
+        in
+        {
+          format = pkgs.runCommand "check-format"
+            {
+              buildInputs = with pkgs; [ cargo rustc ncurses ];
+            } ''
+            ${pkgs.rustfmt}/bin/cargo-fmt fmt --manifest-path ${./.}/Cargo.toml -- --check
+            ${pkgs.nixpkgs-fmt}/bin/nixpkgs-fmt --check ${./.}
+            touch $out # it worked!
+          '';
+          "${cargoToml.package.name}" = pkgs."${cargoToml.package.name}";
+        });
+      devShell = forAllSystems (system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [ self.overlay ];
+          };
+        in
+        pkgs.mkShell {
+          inputsFrom = with pkgs; [
+            pkgs."${cargoToml.package.name}"
+          ];
+          # shellHook = ''
+          #   echo "starting todo list app"
+          #   cargo run TODO
+          # '';
+          buildInputs = with pkgs; [
+            cargo 
+            rustc 
+            ncurses
+          ];
+          LIBCLANG_PATH = "${pkgs.llvmPackages.libclang.lib}/lib";
+        });
+    };
+}

shell.nix

@@ -0,0 +1,13 @@
+{ pkgs ? import <nixpkgs> { } }:
+let
+  todoScript = pkgs.writeScriptBin "todo-rs" ''
+    cargo run TODO
+  '';
+in pkgs.mkShell {
+  name = "todo-rs";
+  buildInputs = [ pkgs.cargo pkgs.rustc pkgs.glibc pkgs.ncurses ];
+
+  shellHook = ''
+    cargo run TODO
+  '';
+}