feat(nix): Introduce a flake.nix to allow building and running engram with Nix

.gitignore

@@ -26,3 +26,6 @@ Thumbs.db
 .codex/skills
 .github/skills
 .gemini/skills
+
+# Nix output
+result

docs/INSTALLATION.md

@@ -3,6 +3,7 @@
 # Installation
 
 - [Homebrew (macOS / Linux)](#homebrew-macos--linux)
+- [Nix](#nix)
 - [Windows](#windows)
 - [Install from source (macOS / Linux)](#install-from-source-macos--linux)
 - [Download binary (all platforms)](#download-binary-all-platforms)
@@ -31,6 +32,70 @@ brew update && brew upgrade engram
 
 ---
 
+## Nix
+
+Run directly without installing:
+
+```bash
+nix run github:Gentleman-Programming/engram
+```
+
+Build locally:
+
+```bash
+nix build
+./result/bin/engram
+```
+
+Enter a development shell:
+
+```bash
+nix develop
+```
+
+<details>
+<summary>Home Manager / NixOS integration</summary>
+
+You can also add Engram from this repository flake into your own Nix configuration.
+
+#### As a flake input
+
+```nix
+{
+  inputs.engram.url = "github:Gentleman-Programming/engram";
+}
+```
+
+#### Home Manager
+
+```nix
+{ inputs, pkgs, ... }:
+
+{
+  home.packages = [
+    inputs.engram.packages.${pkgs.system}.default
+  ];
+}
+```
+
+#### NixOS
+
+```nix
+{ inputs, pkgs, ... }:
+
+{
+  environment.systemPackages = [
+    inputs.engram.packages.${pkgs.system}.default
+  ];
+}
+```
+
+This makes the `engram` binary available in your environment without installing Go manually.
+
+</details>
+
+---
+
 ## Windows
 
 **Option A: Download the binary (recommended)**

flake.nix

@@ -0,0 +1,72 @@
+{
+  description = "engram - Persistent memory for AI coding agents";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+    }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = import nixpkgs { inherit system; };
+
+        pname = "engram";
+        version = "1.10.0";
+
+        engram = pkgs.buildGoModule {
+          inherit pname;
+          inherit version;
+          vendorHash = "sha256-wnRtuBn5H+UdWkXucpfHPEbFosVCUa8i9hVRXg5Wqc4=";
+          proxyVendor = true;
+
+          src = ./.;
+          subPackages = [ "cmd/engram" ];
+
+          env = {
+            CGO_ENABLED = "0";
+          };
+
+          ldflags = [
+            "-s"
+            "-w"
+            "-X main.version=${version}"
+          ];
+
+          meta = with pkgs.lib; {
+            description = "Persistent memory for AI coding agents";
+            homepage = "https://github.com/Gentleman-Programming/engram";
+            license = licenses.mit;
+            mainProgram = "engram";
+            platforms = platforms.linux ++ platforms.darwin;
+          };
+        };
+      in
+      {
+        packages.default = engram;
+        packages.engram = engram;
+
+        apps.default = flake-utils.lib.mkApp {
+          drv = engram;
+        };
+
+        devShells.default = pkgs.mkShell {
+          packages = with pkgs; [
+            go_1_25
+            gopls
+            gotools
+            golangci-lint
+            delve
+          ];
+        };
+
+        formatter = pkgs.nixfmt-rfc-style;
+      }
+    );
+}