CreateFactoryLogistics/build.gradle at master · zznty/CreateFactoryLogistics · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
plugins {
    id 'dev.architectury.loom' version '1.11-SNAPSHOT' apply false
}

allprojects {
    group = rootProject.mod_group_id
}

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"
println "Version: ${version}"

subprojects {
    apply plugin: 'dev.architectury.loom'
    apply plugin: 'maven-publish'

    repositories {
        maven {
            url "https://cursemaven.com"
            content {
                includeGroup "curse.maven"
            }
        }
        maven { url = "https://maven.createmod.net" } // Create, Ponder, Flywheel
        maven { url = "https://modmaven.dev/" } // Registrate
        maven { url = "https://raw.githubusercontent.com/Fuzss/modresources/main/maven/" } // ForgeConfigAPIPort
        maven { url = "https://maven.blamejared.com" } // JEI, Vazkii's Mods
        maven { url = "https://maven.liukrast.net/" } // extra gauges
        maven { url = "https://repo.spongepowered.org/maven/" } // Sponge Mixins
        maven { url = "https://maven.squiddev.cc" } // CC: Tweaked
        mavenCentral()
    }

    loom {
        silentMojangMappingsLicense()

        runs {
            configureEach {
//            jvmArg '-XX:+AllowEnhancedClassRedefinition'
            }
            data {
                data()
                programArgs '--all', '--mod', project.name
                programArgs '--output', project.layout.projectDirectory.file("src/generated/resources/").asFile.absolutePath
                programArgs '--existing', project.layout.projectDirectory.file('src/main/resources/').asFile.absolutePath
            }
        }
    }

    dependencies {
        minecraft "net.minecraft:minecraft:${minecraft_version}"
        mappings loom.officialMojangMappings()
        forge "net.minecraftforge:forge:${minecraft_version}-${forge_version}"

        modCompileOnly "mezz.jei:jei-${minecraft_version}-common-api:${jei_version}"
        modCompileOnly "mezz.jei:jei-${minecraft_version}-forge-api:${jei_version}"
        modCompileOnly "mezz.jei:jei-${minecraft_version}-forge:${jei_version}"
        modRuntimeOnly "mezz.jei:jei-${minecraft_version}-forge:${jei_version}"

        compileOnly "cc.tweaked:cc-tweaked-${minecraft_version}-core-api:${cc_tweaked_version}"
        modCompileOnly "cc.tweaked:cc-tweaked-${minecraft_version}-forge-api:${cc_tweaked_version}", {
            transitive = false
        }

        modImplementation "com.simibubi.create:create-${minecraft_version}:${create_version}:slim", { transitive = false }
        modImplementation "net.createmod.ponder:Ponder-Forge-${minecraft_version}:${ponder_version}"
        modCompileOnly "dev.engine-room.flywheel:flywheel-forge-api-${minecraft_version}:${flywheel_version}"
        modRuntimeOnly "dev.engine-room.flywheel:flywheel-forge-${minecraft_version}:${flywheel_version}"
        modImplementation "com.tterrag.registrate:Registrate:${registrate_version}"
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 17
    }

    tasks.named('jar', Jar).configure {
        manifest {
            attributes([
                    'Specification-Title'     : project.mod_id,
                    'Specification-Vendor'    : mod_authors,
                    'Specification-Version'   : '1', // We are version 1 of ourselves
                    'Implementation-Title'    : project.name,
                    'Implementation-Version'  : project.jar.archiveVersion,
                    'Implementation-Vendor'   : mod_authors,
                    'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
            ])
        }
    }

    // Configure Maven publishing.
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = base.archivesName.get()
                from components.java
            }
        }

        repositories {
            maven {
                name = "zzntyMaven"
                url = "s3://dl.zznty.ru/maven"
                credentials(AwsCredentials) {
                    accessKey = providers.environmentVariable('S3_KEY_ID').getOrNull()
                    secretKey = providers.environmentVariable('S3_KEY').getOrNull()
                }
            }
        }
    }
}