hosts/justfile at main · yellowhat/hosts · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# renovate: datasource=docker depName=docker.io/golang
GOLANG_VER := "1.26.2"

set shell := ["bash", "-o", "errexit", "-o", "nounset", "-o", "pipefail", "-c"]

@_:
    just --list --unsorted

# Start interactive go container
env:
    podman run \
        --interactive \
        --tty \
        --rm \
        --volume .:/data:z \
        --workdir /data \
        "docker.io/golang:{{ GOLANG_VER }}"

# Generate new adlist
adlist:
    (cd go && go build -o /tmp/out)
    /tmp/out

# Run blocky container detached
run:
    bash scripts/run_blocky.sh

# Run blocky and test
test: clean run && clean
    bash scripts/test.sh

# Clean cached files and running containers
clean:
    docker rm --force blocky
    rm --recursive --force --verbose \
        **/.venv \
        **/__pycache__ \
        **/.pytest_cache \
        **/.pytype \
        **/.mypy_cache