python-tdigest-ch/justfile at master · vivienm/python-tdigest-ch · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
set shell := ["bash", "-uc"]

ci: cargo-fmt cargo-clippy cargo-audit ruff mypy pytest sphinx pip-audit typos

[group('rust')]
cargo-fmt:
  cargo fmt --check

[group('rust')]
cargo-clippy:
  cargo clippy --all-targets

# https://github.com/rustsec/rustsec/issues/1241
[group('rust')]
cargo-audit:
  cargo audit --file <(grep -v 'git+https://github.com/vivienm/' Cargo.lock)

[group('python')]
ruff: ruff-check ruff-format

[group('python')]
ruff-check:
  uv run ruff check

[group('python')]
ruff-format:
  uv run ruff format --check

[group('python')]
mypy:
  uv run mypy .

[group('python')]
pytest *args="":
  uv run pytest {{args}}

[group('python')]
pytest-benchmark:
  uv run pytest --benchmark-only

[group('python')]
sphinx:
  uv run sphinx-build docs docs/_build/html

[group('python')]
pip-audit:
  uv run pip-audit --strict --require-hashes --disable-pip --requirement \
    <(uv export --format requirements-txt --all-extras --no-emit-project)

typos:
  uv run typos