invalid image specification error during isearch

[dasoju]

Description
Seeing invalid image specification error during isearch

Steps to Reproduce the behaviour
Steps to reproduce the behaviour:

1. open a pdf
2. search for a string, keep repeating search util it reaches end of pdf
3. at end of pdf, it throws "Invalid image specification"
4. after that any search gives [(error invalid image specification)]
5. after this isearch doest work any more, i get error as shown below
   

What is the expected behaviour?
i search should not fail

Desktop
Please complete the following information:

• OS: macos sequoia
• Emacs Version: 30.2
• Poppler Version: stable 25.12.0

Your pdf-tools install
Please complete the following information:

• pdf-tools Version: 20260102.1101

[aikrahguzar]

Is this with or without new pdf-view-roll-minor-mode enabled? Invalid image specification is only likely with pdf-view-roll-minor-mode enabled. Please do the following,

1. Post your pdf-tools configuration.
2. Do M-x toggle-debug-on-error RET, reproduce the bug and post the backtrace that pops up.
3. I can't reproduce the bug with or without pdf-view-roll-minor-mode on the default branch (child-frame-preview) of my fork. Can you try it and see if the error goes away.

[dasoju]

i debugged my pdf-tools configuration, looks like its due to following
(add-hook 'pdf-view-after-change-page-hook #'pdf-view-auto-slice-minor-mode)

it used to work before on emacs29
i made two moves, i moved to emacs30 and also move to new pdf-tools, not sure which move broke the above.

[aikrahguzar]

i debugged my pdf-tools configuration, looks like its due to following (add-hook 'pdf-view-after-change-page-hook #'pdf-view-auto-slice-minor-mode)

it used to work before on emacs29 i made two moves, i moved to emacs30 and also move to new pdf-tools, not sure which move broke the above.

It is enough to enable pdf-view-auto-slice-minor-mode once per buffer. Why do you need to re-enable after every page change? Does isearch result in the same error if enable do M-x pdf-view-auto-slice-minor-mode RET and the use isearch? For me that doesn't happen.

[dasoju]

i commented out that line and restarted emacs , i used isearch everything works as expected then i did M-x pdf-view-auto-slice-minor-mode , i get back to same problem i disabled the pdf-view-auto-slide-minor-mode and isearch works again

…

On Mon, Jan 5, 2026 at 5:07 AM aikrahguzar ***@***.***> wrote: *aikrahguzar* left a comment (vedang/pdf-tools#339) <#339 (comment)> i debugged my pdf-tools configuration, looks like its due to following (add-hook 'pdf-view-after-change-page-hook #'pdf-view-auto-slice-minor-mode) it used to work before on emacs29 i made two moves, i moved to emacs30 and also move to new pdf-tools, not sure which move broke the above. It is enough to enable pdf-view-auto-slice-minor-mode once per buffer. Why do you need to re-enable after every page change? Does isearch result in the same error if enable do M-x pdf-view-auto-slice-minor-mode RET and the use isearch? For me that doesn't happen. — Reply to this email directly, view it on GitHub <#339 (comment)>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/ANBRMCNCIV7AVHNFKBVVTGD4FJO23AVCNFSM6AAAAACQV4FR5CVHI2DSMVQWIX3LMV43OSLTON2WKQ3PNVWWK3TUHMZTOMJQGM2TANRTGQ> . You are receiving this because you authored the thread.Message ID: ***@***.***>

[averter]

I'm experiencing the same issue. pdf-view-roll-minor-mode is quite experimental atm and is known to conflict with pdf-view-auto-slice-minor-mode on several accounts, e.g., this is another reported issue which has not been fixed yet.

[aikrahguzar]

I'm experiencing the same issue. pdf-view-roll-minor-mode is quite experimental atm and is known to conflict with pdf-view-auto-slice-minor-mode on several accounts, e.g., this is another reported issue which has not been fixed yet.

I think this issue is due to a bug in pdf-view-image-size. This issue has already been fixed on my fork and should land here when (at least part of) #338 lands.

pdf-view-roll-minor-mode in the pdf-tools has evolved a lot and doesn't have much in common with image-roll.el (where it started) anymore.

[aikrahguzar]

I think (haven't tested it), but I think this should fix the issue:

(defun +fix-pdf-view-image-size (&optional displayed-p window page)
  "Return the size in pixel of the current image in WINDOW.

If DISPLAYED-P is non-nil, return the size of the displayed
image.  These values may be different, if slicing is used.

If PAGE is non-nil return its size instead of current page."
  (let ((display-prop (if pdf-view-roll-minor-mode
                          (progn (setq window (if (windowp window) window (selected-window)))
                                 (setq page (or page (pdf-view-current-page window)))
                                 (unless (memq page (image-mode-window-get 'displayed-pages window))
                                   (pdf-view-display-page page window))
                                 (overlay-get (pdf-roll-page-overlay page window) 'display))
                        (image-get-display-property))))
    (if (eq (car display-prop) 'image)
        (image-size display-prop t)
      (if displayed-p
          (image-display-size display-prop t)
        (image-size (nth 1 display-prop) t)))))

(advice-add 'pdf-view-image-size :override #'+fix-pdf-view-image-size)

If it doesn't please toggle debug on error and show a stacktrace.

[averter]

Thanks @aikrahguzar Your fix worked like a charm. I've subscribed to your commit so that I know when it's safe to remove it :-). Incidentally, I've noticed that the same error also shows up when opening a pdf via an org-link, i.e. this doesn't affects only isearch. Thanks again.

[aikrahguzar]

Thanks @aikrahguzar Your fix worked like a charm. I've subscribed to your commit so that I know when it's safe to remove it :-). Incidentally, I've noticed that the same error also shows up when opening a pdf via an org-link, i.e. this doesn't affects only isearch. Thanks again.

The bug is general and affect a lot of places when slicing is involved since pdf-view-image-size is used in a lot of places. There are a few other bugs fixed in my fork but most of them won't bite you if pdf-view-roll-mode is not turned on.

[BenedictHW]

Hey, I've also ran into this issue trying to left-click and drag to select text after having called pdf-view-set-slice-from-bounding-box', and I also get a "Invalid image specification" error. This was the root cause analysis and fix proposed by claude that worked:

Root cause: pdf-view-image-size in pdf-tools has a bug in its displayed-p=nil path. It calls (image-size display-prop t) where display-prop comes from image-get-display-property. After pdf-view-set-slice-from-bounding-box sets a slice, the overlay's display property changes from (image ...) to ((slice X Y W H) (image ...)). The C primitive image-size only accepts (image ...) — it crashes on the compound sliced form with "Invalid image specification".

The displayed-p=t path uses image-display-size (Elisp), which already handles the compound form correctly. But callers like pdf-util-scale-pixel-to-relative (called from pdf-view-mouse-set-region during text selection) pass displayed-p=nil, hitting the broken path.

Fix: An :around advice on pdf-view-image-size that:

• Passes through to the original when displayed-p is non-nil (the image-display-size path works fine)
• When displayed-p is nil, retrieves the display property and unwraps ((slice ...) (image ...)) → (image ...) before calling image-size

The fix is live in your Emacs. You can test by: opening a PDF via org-noter → pressing f for pdf-view-set-slice-from-bounding-box → then click-drag to select text.

;; Fix: `pdf-view-image-size' passes the raw display property to the C
;; primitive `image-size' when DISPLAYED-P is nil.  After slicing
;; (`pdf-view-set-slice-from-bounding-box'), the display property
;; becomes ((slice X Y W H) (image …)) — a compound form that the C
;; primitive `image-size' cannot handle (it expects (image …)).  This
;; advice unwraps the image spec from the sliced form so `image-size'
;; receives a bare (image …) descriptor.
(defadvice! bhw/pdf-view-image-size-handle-slice-a (fn &optional displayed-p window page)
  :around #'pdf-view-image-size
  (if displayed-p
      ;; `image-display-size' already handles the sliced compound form.
      (funcall fn displayed-p window page)
    ;; Replicate the display-prop lookup that `pdf-view-image-size' does
    ;; internally, but unwrap any slice wrapper before calling `image-size'.
    (let ((display-prop (if pdf-view-roll-minor-mode
                            (let ((w (if (windowp window) window (selected-window))))
                              (overlay-get (pdf-roll-page-overlay
                                            (or page (pdf-view-current-page w)) w)
                                           'display))
                          (image-get-display-property))))
      (image-size (if (eq (car-safe (car display-prop)) 'slice)
                      (cadr display-prop)   ; ((slice …) (image …)) → (image …)
                    display-prop)           ; already (image …)
                  t))))

@aikrahguzar is right on the money (Edit: of course. I see @aikrahguzar's contributions to pdf-roll-mode and etc now. Thanks for your work and the work of all others!). Emacs MCP server also came in clutch.