VPSetupData.iss

; Script generated by the Inno Script Studio Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Vox Populi"
#define MyAppVersion "5.2.3"
#define MyAppPublisher "Community Patch Project Team"
#define MyAppURL "http://forums.civfanatics.com/showthread.php?t=528034"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{97D14FF1-16B3-4F26-AD9D-DF845F5B7766}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultGroupName={#MyAppName}
VersionInfoVersion={#MyAppVersion}
VersionInfoCompany={#MyAppPublisher}
VersionInfoDescription={#MyAppName}
VersionInfoProductName={#MyAppName}
VersionInfoProductVersion={#MyAppVersion}
VersionInfoCopyright=2025
OutputBaseFilename={#MyAppName} ({#MyAppVersion})
DefaultDirName={userdocs}\My Games\Sid Meier's Civilization 5\
LicenseFile=License.rtf
InfoBeforeFile=Opener.rtf
SetupIconFile=installer.ico
WizardImageStretch=False
Compression=lzma
SolidCompression=yes
ShowComponentSizes=False
AllowNoIcons=yes
Uninstallable=no
PrivilegesRequired=admin
DirExistsWarning=no
UsedUserAreasWarning=no

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Files]    
Source: "Build\(1) Community Patch\*"; Excludes: "\LUA,*.civ5proj,*.civ5sln,*.civ5suo,MANUAL INSTALL.txt"; DestDir: "{app}\MODS\(1) Community Patch"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullNoEUI FullEUI Civ43EUI Civ43NoEUI Core Civ43CPOnly
Source: "Build\(2) Vox Populi\*"; Excludes: "\LUA,INSTRUCTIONS.txt,Promotion Icons for VP.txt,*.civ5proj,*.civ5sln,*.civ5suo"; DestDir: "{app}\MODS\(2) Vox Populi"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullEUI FullNoEUI Civ43EUI Civ43NoEUI
Source: "Build\(3a) VP - EUI Compatibility Files\*"; Excludes: "INSTRUCTIONS.txt,*.civ5proj,*.civ5sln,*.civ5suo"; DestDir: "{app}\MODS\(3a) VP - EUI Compatibility Files"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullEUI Civ43EUI
Source: "Build\(3b) 43 Civs Community Patch\(3b) 43 Civs Community Patch (v 1).modinfo"; DestDir: "{app}\MODS\(3b) 43 Civs Community Patch\"; DestName: "(3b) 43 Civs Community Patch (v 1).modinfo"; Flags: ignoreversion; Components: Civ43CPOnly Civ43EUI Civ43NoEUI
Source: "Build\(3b) 43 Civs Community Patch\AdvancedSetup.lua"; DestDir: "{app}\MODS\(3b) 43 Civs Community Patch\"; DestName: "AdvancedSetup.lua"; Flags: ignoreversion; Components: Civ43CPOnly Civ43EUI Civ43NoEUI
Source: "Build\(3b) 43 Civs Community Patch\CvGameCore_Expansion2.dll"; DestDir: "{app}\MODS\(1) Community Patch\"; DestName: "CvGameCore_Expansion2.dll"; Flags: ignoreversion; Components: Civ43CPOnly Civ43EUI Civ43NoEUI
Source: "Build\(4a) Squads for VP\*"; Excludes: "*.civ5proj,*.civ5sln,*.civ5suo"; DestDir: "{app}\MODS\(4a) Squads for VP"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullEUI FullNoEUI Civ43EUI Civ43NoEUI
Source: "Build\(1) Community Patch\LUA\*"; DestDir: "{app}\MODS\(1) Community Patch\LUA"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: Core Civ43CPOnly FullNoEUI Civ43NoEUI
Source: "Build\(2) Vox Populi\LUA\*"; DestDir: "{app}\MODS\(2) Vox Populi\LUA"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullNoEUI Civ43NoEUI
Source: "UI_bc1\*"; DestDir: "{code:GetCIVDir}\Assets\DLC\UI_bc1"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullEUI Civ43EUI
Source: "VPUI\*"; DestDir: "{code:GetCIVDir}\Assets\DLC\VPUI"; Flags: ignoreversion createallsubdirs recursesubdirs; Components: FullEUI FullNoEUI Civ43EUI Civ43NoEUI
Source: "VPUI Text\VPUI_tips_en_us.xml"; DestDir: "{app}\Text"; Flags: ignoreversion; Components: FullEUI FullNoEUI Civ43EUI Civ43NoEUI
; Replacement of the base game Expansion2 files (either MinorCivSounds_Expansion2.xml or the .Civ5Pkg file) is necessary for newly-added City-States to load the correct audio clips on selection.
; The .Civ5Pkg file is modified to add a new MinorCivSounds_VoxPopuli file because this is the least intrusive method. This also corrects a BNW bug with Cape Town's audio clip.
; The added entries don't do anything if the new City-States don't exist, so this doesn't affect the game when not using VP.
Source: "Expansion2_VoxPopuli.Civ5Pkg"; DestDir: "{code:GetCIVDir}\Assets\DLC\Expansion2"; DestName: "Expansion2.Civ5Pkg"; Flags: ignoreversion; Components: Core Civ43CPOnly FullEUI FullNoEUI Civ43EUI Civ43NoEUI
Source: "Expansion2_Base.Civ5Pkg"; DestDir: "{code:GetCIVDir}\Assets\DLC\Expansion2"; DestName: "Expansion2.Civ5Pkg"; Flags: ignoreversion; Components: Uninstall
Source: "MinorCivSounds_CommunityPatch.xml"; DestDir: "{code:GetCIVDir}\Assets\DLC\Expansion2\Sounds\XML"; DestName: "MinorCivSounds_VoxPopuli.xml"; Flags: ignoreversion; Components: Core Civ43CPOnly
Source: "MinorCivSounds_VoxPopuli.xml"; DestDir: "{code:GetCIVDir}\Assets\DLC\Expansion2\Sounds\XML"; DestName: "MinorCivSounds_VoxPopuli.xml"; Flags: ignoreversion; Components: FullEUI FullNoEUI Civ43EUI Civ43NoEUI

[Components]
Name: "FullEUI"; Description: "Vox Populi (with EUI)"; Types: FullEUI; Flags: exclusive disablenouninstallwarning
Name: "FullNoEUI"; Description: "Vox Populi (no EUI)"; Types: FullNoEUI; Flags: exclusive disablenouninstallwarning
Name: "Core"; Description: "Community Patch only"; Types: Core; Flags: exclusive disablenouninstallwarning
Name: "Civ43CPOnly"; Description: "43 Civ Community Patch only"; Types: 43CivCPOnly; Flags: exclusive disablenouninstallwarning
Name: "Civ43NoEUI"; Description: "43 Civ Vox Populi (no EUI)"; Types: 43CivNoEUI; Flags: exclusive disablenouninstallwarning
Name: "Civ43EUI"; Description: "43 Civ Vox Populi (with EUI)"; Types: 43CivEUI; Flags: exclusive disablenouninstallwarning
Name: "Uninstall"; Description: "Uninstall all"; Types: Uninstall; Flags: exclusive disablenouninstallwarning

[Types]
Name: "FullEUI"; Description: "Vox Populi (with EUI)"
Name: "FullNoEUI"; Description: "Vox Populi (no EUI)"
Name: "Core"; Description: "Community Patch only"
Name: "43CivCPOnly"; Description: "43 Civ Community Patch only"
Name: "43CivNoEUI"; Description: "43 Civ Vox Populi (no EUI)"
Name: "43CivEUI"; Description: "43 Civ Vox Populi (with EUI)"
Name: "Uninstall"; Description: "Uninstall all"

[InstallDelete]
Type: filesandordirs; Name: "{code:GetCIVDir}\Assets\DLC\UI_bc1"
Type: filesandordirs; Name: "{code:GetCIVDir}\Assets\DLC\VPUI"
Type: filesandordirs; Name: "{code:GetCIVDir}\Assets\DLC\Expansion2\Expansion2.Civ5Pkg"
Type: filesandordirs; Name: "{code:GetCIVDir}\Assets\DLC\Expansion2\Sounds\XML\MinorCivSounds_VoxPopuli.xml"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\cache"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\Text\VPUI_tips_en_us.xml"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(1) Community Patch"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(2) Vox Populi"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(3a) VP - EUI Compatibility Files"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(3b) 43 Civs Community Patch"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(4a) Squads for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(2) Community Balance Patch"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(2) Community Balance Overhaul"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(3) CSD for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(3) CSD for CBP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(4) Civ IV Diplomatic Features"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(4a) Promotion Icons for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(4a) UI - Promotion Tree for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(4b) UI - Promotion Tree for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(5) More Luxuries"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6a) Vox Populi - Compatibility Files (EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6a) Community Balance Patch - Compatibility Files (EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6a) Community Balance Overhaul - Compatibility Files (EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6b) Vox Populi - Compatibility Files (No-EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6b) Community Balance Patch - Compatibility Files (No-EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6b) Community Balance Overhaul - Compatibility Files (No-EUI)"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6c) 43 Civs Community Patch"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(6c) 43 Civs CP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(7a) Promotion Icons for VP"
Type: filesandordirs; Name: "{userdocs}\My Games\Sid Meier's Civilization 5\MODS\(7b) UI - Promotion Tree for VP"

[Code]

var
  CIVDirPage: TInputDirWizardPage;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpFinished then
  begin
    if WizardIsComponentSelected('Uninstall') then
    begin
      WizardForm.FinishedLabel.Caption := 'Uninstallation complete';
    end
    else
    begin
      WizardForm.FinishedLabel.Caption := 'Setup has finished installing the mod on your computer. To launch it, open Civilization V and enable all installed mods in the MODS menu, then click ''NEXT'' (do not click on ''Back''). Have fun!';
    end;
  end; 
end;

procedure InitializeWizard;
begin
  // Create the DLC path page

  CIVDirPage := CreateInputDirPage(wpSelectComponents,
    'Select the Civilization V folder', '',
    'Select the folder of your Civilization V installation, then click Next. If the installer does not select a folder by default, please click Browse and choose the correct folder. To find it, right-click on Civilization V in Steam and select "Show local files". ',
    False, '');
  CIVDirPage.Add('');

  CIVDirPage.Values[0] := GetPreviousData('CIVDir', '');
end;
(*
procedure RegisterPreviousData(PreviousDataKey: Integer);
begin
  // Store the selected folder for further reinstall/upgrade //balparmak: no need to store this for now
  SetPreviousData(PreviousDataKey, 'CIVDir', CIVDirPage.Values[0]);
end;
 *)
function NextButtonClick(CurPageID: Integer): Boolean;
var
  MissingFolders: TStringList;
  BaseDir: string;
begin
  // Set default folder if empty. Don't select a default folder if the game isn't installed in the default location
  if CIVDirPage.Values[0] = '' then
    if DirExists(ExpandConstant('{commonpf}\Steam\steamapps\common\Sid Meier''s Civilization V\Assets\DLC')) then
      CIVDirPage.Values[0] := ExpandConstant('{reg:HKCU\SOFTWARE\Firaxis\Civilization5,LastKnownPath|{commonpf}\Steam\steamapps\common\Sid Meier''s Civilization V}');
  Result := not (CurPageID = CIVDirPage.ID) or DirExists(CIVDirPage.Values[0] + '\Assets\DLC');
  if Result = False then
    MsgBox('You did not provide the correct path to the Civ 5 folder. To locate the folder, right-click on Civilization V in Steam and select "Show local files".', mbInformation, MB_OK)
  else if CurPageID = CIVDirPage.ID then
  begin
    // check if all required DLC are installed
    MissingFolders := TStringList.Create;
    BaseDir := CIVDirPage.Values[0] + '\Assets\DLC\';
    
    if not DirExists(BaseDir + 'DLC_01') then
      MissingFolders.Add('Civilization and Scenario Pack: Mongols (Genghis Khan)');
    if not DirExists(BaseDir + 'DLC_02') then
      MissingFolders.Add('Civilization and Scenario Double Pack: Spain and Inca');
    if not DirExists(BaseDir + 'DLC_03') then
      MissingFolders.Add('Civilization and Scenario Pack: Polynesia');
    if not DirExists(BaseDir + 'DLC_04') then
      MissingFolders.Add('Civilization and Scenario Pack: Denmark (The Vikings)');
    if not DirExists(BaseDir + 'DLC_05') then
      MissingFolders.Add('Civilization and Scenario Pack: Korea');
    if not DirExists(BaseDir + 'DLC_06') then
      MissingFolders.Add('Scenario Pack: Wonders of the Ancient World');
    if not DirExists(BaseDir + 'DLC_07') then
      MissingFolders.Add('Scenario Pack: Conquest of the New World');
    if not DirExists(BaseDir + 'DLC_Deluxe') then
      MissingFolders.Add('Babylon (Nebuchadnezzar II)');
    if not DirExists(BaseDir + 'Expansion') then
      MissingFolders.Add('Gods & Kings');
    if not DirExists(BaseDir + 'Expansion2') then
      MissingFolders.Add('Brave New World');

    if MissingFolders.Count > 0 then
    begin
      MsgBox('You don''t have all required DLCs installed. The following DLC are missing:' + #13#10 + #13#10 + MissingFolders.Text + #13#10 + #13#10 + 'Vox Populi can''t be installed if DLCs are missing.', mbInformation, MB_OK);
      Result := False;
    end
    else
    begin
      Result := True;
    end;

    MissingFolders.Free;
  end;
end;

function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo,
  MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
var
  S: String;
begin
  // Fill the 'Ready Memo' with the normal settings and the custom settings
  S := '';

  S := S + MemoDirInfo + NewLine + NewLine;
  S := S + 'Civilization V path' + NewLine;
  S := S + Space + CIVDirPage.Values[0] + NewLine + NewLine;

  S := S + MemoComponentsInfo
  Result := S;
end;

function GetCIVDir(Param: String): String;
begin
  { Return the selected CIVDir }
  Result := CIVDirPage.Values[0];
end;