spawnlite/build.gradle at master · uebliche/spawnlite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
plugins {
    id 'java'
    id 'net.uebliche.mcmeta'
}

group = 'net.uebliche'
version = new Date().format('yyyy.MM.dd')

ext.baseCoordinates = "${project.name}-${project.version}"

def resolveGameVersions = {
    def override = System.getenv("MODRINTH_GAME_VERSIONS")
    if (override != null && !override.trim().isEmpty()) {
        return override.split(',').collect { it.trim() }.findAll { it }
    }
    def manifestUrl = mcmeta.manifestUrl
    try {
        def parsed = new groovy.json.JsonSlurper().parse(new URL(manifestUrl))
        def versions = parsed.versions
                .findAll { it.type == 'release' }
                .collect { it.id }
                .findAll { it }
        return versions.unique()
    } catch (Exception e) {
        logger.warn("Failed to resolve MC versions from mcmeta manifest: ${e.message}")
        return []
    }
}

mcmeta {
    minecraftVersion = project.findProperty("mcVersion")?.toString() ?: ""
    repositories {
        all()
    }
}

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.20-R0.1-SNAPSHOT"
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }

    // Hier wird der Ausschluss der META-INF-Ordner für Ressourcen durchgeführt
    exclude 'META-INF/**'
}

jar {
    exclude 'META-INF/MANIFEST.MF'
}