Add Nix flake

Author: nilp0inter

README.md

@@ -93,6 +93,20 @@ $ ln -s /path/to/boomer/overlay/ boomer
 $ nix-env -iA nixos.boomer
 ```
 
+## NixOS Flake
+
+### Run
+
+```
+$ nix run github:tsoding/boomer
+```
+
+### Installation
+
+```
+$ nix profile install github:tsoding/boomer
+```
+
 ## References
 
 - https://github.com/nim-lang/x11/blob/bf9dc74dd196a98b7c2a2beea4d92640734f7c60/examples/x11ex.nim

flake.lock

@@ -0,0 +1,63 @@
+{
+  description = "Zoomer application for Linux";
+  inputs = {
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+  }:
+    flake-utils.lib.eachDefaultSystem (
+      system: let
+        pkgs = nixpkgs.legacyPackages.${system};
+      in {
+        formatter = pkgs.alejandra;
+        packages = rec {
+          boomer = let
+            opengl = pkgs.nimPackages.buildNimPackage rec {
+              pname = "opengl";
+              version = "1.2.8";
+              src = pkgs.fetchFromGitHub {
+                owner = "nim-lang";
+                repo = "opengl";
+                rev = version;
+                hash = "sha256-OHdoPJsmCFdyKV7FGd/r+6nh6NRF7TPhuAx7o/VpiDg=";
+              };
+            };
+          in
+            pkgs.nimPackages.buildNimPackage {
+              pname = "boomer";
+              version = "0.0.1";
+              nimBinOnly = true;
+
+              src = ./.;
+
+              buildInputs = with pkgs.nimPackages; [
+                x11
+                opengl
+              ];
+              propagatedBuildInputs = with pkgs; [
+                xorg.libX11
+                xorg.libXrandr
+                xorg.libXext
+                libGL
+                libGLU
+              ];
+              meta = with nixpkgs.lib; {
+                mainProgram = "boomer";
+                description = "Zoomer application for Linux";
+                homepage = "https://github.com/tsoding/boomer";
+                license = licenses.mit;
+              };
+            };
+          default = boomer;
+        };
+        apps = rec {
+          boomer = flake-utils.lib.mkApp {drv = self.packages.${system}.boomer;};
+          default = boomer;
+        };
+      }
+    );
+}