dot-files/flake.nix at main · throwandgo/dot-files · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-25.05-darwin";
    unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    home-manager = {
      url = "github:nix-community/home-manager/release-25.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { nixpkgs, unstable, home-manager, ... }@inputs:
    let
      system = "aarch64-darwin";
      pkgs = nixpkgs.legacyPackages.${system};

      nixpkgsModule = {
        nixpkgs = {
          config = {
            allowUnfree = true;
            allowUnfreePredicate = (pkgs: true);
          };
          overlays = [
            (final: prev: {
              unstable = import inputs.unstable {
                system = final.system;
                config.allowUnfree = true;
              };
            })
          ];
        };
      };

      mkHome = { username, homeDirectory, machineModule }: home-manager.lib.homeManagerConfiguration {
        inherit pkgs;
        modules = [
          nixpkgsModule
          machineModule
          {
            home.username = username;
            home.homeDirectory = homeDirectory;
            home.stateVersion = "25.05";
          }
        ];
        extraSpecialArgs = { inherit inputs; };
      };
    in
    {
      homeConfigurations = {
        "personal" = mkHome {
          username = "abe";
          homeDirectory = "/Users/abe";
          machineModule = ./home/personal.nix;
        };

        "work" = mkHome {
          username = "ABenavides";
          homeDirectory = "/Users/ABenavides";
          machineModule = ./home/work.nix;
        };
      };
    };
}