Compilation errors

[neurolabusc]

I tried to build this on a macOS. I installed the dependencies specified by CMake:

brew install libzip
brew install eigen
brew install nlohmann-json
brew install spdlog

At that stage, the CMake felt the dependencies were met, but the make command failed, because of a dependency on mio. Since that header-only library seems mature, it might be worth just including the files, as there is no generic installer. Once I met that dependcy, the code still fails to compile:

In file included from /Users/chris/src/trx-cpp/src/trx.h:294:
/Users/chris/src/trx-cpp/src/trx.tpp:1097:39: error: use of undeclared identifier 'canonicalize_file_name'
 1097 |         std::string directory = (std::string)canonicalize_file_name(path.c_str());
      |          

The error means is because canonicalize_file_name() is not available on your platform — it's a GNU extension, available on Linux, but not on macOS or standard C++. For cross-platform support, if you want to require C++17 (-std=c++17) you could use:

#include <filesystem>
std::string directory = std::filesystem::canonical(path).string();

Alternatively:

#include <limits.h>
#include <stdlib.h>

char resolved_path[PATH_MAX];
realpath(path.c_str(), resolved_path);
std::string directory = resolved_path;

[arokem]

I think this is probably addressed by recent #9 and #11.

@neurolabusc : do you want to confirm?

[mattcieslak]

I think I agree with @neurolabusc about mio. It is consistently very painful to add it to compilation processes, especially when including this as a 3rd party library in other packages. Are you ok with vendoring mio in trx-cpp?

[arokem]

Yeah, MIT license and <100kb to include, so as long as it makes it easier I see vendoring as a good solution.

[neurolabusc]

@arokem I was able to get the library to compile on MacOS after manually installing Mio. However, I needed to use AI to modify the CMakeLists.txt to detect boost. It seems a combination of the CMake version being updated (I am on cmake version 4.0.2) and major changes to the boost library (I have boost 1.90.0). I am not sure if this is portable or backward compatible, but here is what I ended up with:

cmake_minimum_required(VERSION 3.10)
cmake_policy(SET CMP0074 NEW)
cmake_policy(SET CMP0079 NEW)
cmake_policy(SET CMP0167 NEW) # Suppresses the "FindBoost is removed" warning

project(trx VERSION 0.1.0)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

set(CMAKE_CXX_STANDARD 11)
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
    set(CMAKE_BUILD_TYPE Debug)
endif()

option(TRX_USE_CONAN "Should Conan package manager be used?" ON)
option(TRX_USE_BOOST_FILESYSTEM "Use Boost filesystem if available" ON)
option(TRX_BUILD_TESTS "Build trx tests" ON)

# -----------------------------------------------------------------------------
# Dependencies
# -----------------------------------------------------------------------------

find_package(libzip REQUIRED)
set(TRX_LIBZIP_TARGET "")
if(TARGET libzip::libzip)
    set(TRX_LIBZIP_TARGET libzip::libzip)
elseif(TARGET libzip::zip)
    set(TRX_LIBZIP_TARGET libzip::zip)
elseif(TARGET zip::zip)
    set(TRX_LIBZIP_TARGET zip::zip)
else()
    message(FATAL_ERROR "No suitable libzip target (expected libzip::libzip or zip::zip)")
endif()

find_package(Eigen3 CONFIG QUIET)
if (NOT Eigen3_FOUND)
    find_package(Eigen3 REQUIRED)
endif()

if (NOT TARGET Eigen3::Eigen AND EXISTS "${EIGEN3_INCLUDE_DIR}")
    add_library(Eigen3::Eigen INTERFACE IMPORTED)
    set_target_properties(Eigen3::Eigen PROPERTIES
        INTERFACE_INCLUDE_DIRECTORIES "${EIGEN3_INCLUDE_DIR}"
    )
endif()

find_package(nlohmann_json CONFIG REQUIRED)
find_package(spdlog CONFIG REQUIRED)

# FIXED: Modern Boost Handling for 1.89+
if(TRX_USE_BOOST_FILESYSTEM)
    # On Boost 1.90, 'system' is header-only. Asking for it as a component 
    # can trigger the "Could not find boost_systemConfig.cmake" error.
    # We ask for filesystem (which still has a binary) and keep system optional.
    find_package(Boost REQUIRED COMPONENTS filesystem)
    find_package(Boost QUIET COMPONENTS system) 
endif()

# Manual MIO detection (since it's not in brew)
find_package(mio CONFIG QUIET)
if(NOT TARGET mio::mio)
    find_path(MIO_INCLUDE_DIR mio/mmap.hpp PATH_SUFFIXES include)
    if (NOT MIO_INCLUDE_DIR)
        message(FATAL_ERROR "mio headers not found. Set MIO_INCLUDE_DIR to the folder containing mio/mmap.hpp.")
    endif()
endif()

# -----------------------------------------------------------------------------
# Main Library Target
# -----------------------------------------------------------------------------

add_library(trx src/trx.cpp include/trx/trx.h include/trx/trx.tpp)
add_library(trx-cpp::trx ALIAS trx)

# Handle Conan if present
if(TRX_USE_CONAN AND EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/cmake/ConanSetup.cmake")
    include(cmake/ConanSetup.cmake)
elseif(TRX_USE_CONAN)
    message(STATUS "TRX_USE_CONAN enabled but cmake/ConanSetup.cmake not found; skipping Conan.")
endif()

# Resolve libzip include path for target_include_directories
get_target_property(_trx_libzip_includes ${TRX_LIBZIP_TARGET} INTERFACE_INCLUDE_DIRECTORIES)
if(NOT _trx_libzip_includes)
    find_path(TRX_LIBZIP_INCLUDE_DIR zip.h)
endif()

target_link_libraries(trx
    PUBLIC
        nlohmann_json::nlohmann_json
        ${TRX_LIBZIP_TARGET}
        Eigen3::Eigen
        spdlog::spdlog
        $<$<TARGET_EXISTS:mio::mio>:mio::mio>
)

# FIXED: Linking Boost Logic
if(TRX_USE_BOOST_FILESYSTEM AND Boost_FOUND)
    target_compile_definitions(trx PUBLIC TRX_USE_BOOST_FILESYSTEM)
    
    # Link filesystem (required binary)
    if(TARGET Boost::filesystem)
        target_link_libraries(trx PUBLIC Boost::filesystem)
    else()
        target_link_libraries(trx PUBLIC ${Boost_FILESYSTEM_LIBRARIES})
    endif()

    # Link system (Handle header-only version for Boost 1.90+)
    if(TARGET Boost::system)
        target_link_libraries(trx PUBLIC Boost::system)
    else()
        # If no target exists, just ensure headers are present
        target_include_directories(trx PUBLIC ${Boost_INCLUDE_DIRS})
    endif()
endif()

target_include_directories(trx
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
        $<$<NOT:$<TARGET_EXISTS:mio::mio>>:$<BUILD_INTERFACE:${MIO_INCLUDE_DIR}>>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src
)

if(TRX_LIBZIP_INCLUDE_DIR)
    target_include_directories(trx PUBLIC
        $<BUILD_INTERFACE:${TRX_LIBZIP_INCLUDE_DIR}>
        $<INSTALL_INTERFACE:${TRX_LIBZIP_INCLUDE_DIR}>
    )
endif()

# -----------------------------------------------------------------------------
# Tests & Installation
# -----------------------------------------------------------------------------

if(TRX_BUILD_TESTS)
    find_package(GTest QUIET)
    if(GTest_FOUND)
        enable_testing()
        add_subdirectory(tests)
    endif()
endif()

set(TRX_INSTALL_CONFIGDIR "${CMAKE_INSTALL_LIBDIR}/cmake/trx-cpp")

install(TARGETS trx
    EXPORT trx-cppTargets
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

install(DIRECTORY include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(EXPORT trx-cppTargets
    FILE trx-cppTargets.cmake
    NAMESPACE trx-cpp::
    DESTINATION ${TRX_INSTALL_CONFIGDIR}
)

configure_package_config_file(
    cmake/trx-cppConfig.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/trx-cppConfig.cmake
    INSTALL_DESTINATION ${TRX_INSTALL_CONFIGDIR}
)

write_basic_package_version_file(
    ${CMAKE_CURRENT_BINARY_DIR}/trx-cppConfigVersion.cmake
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMinorVersion
)

install(FILES
    ${CMAKE_CURRENT_BINARY_DIR}/trx-cppConfig.cmake
    ${CMAKE_CURRENT_BINARY_DIR}/trx-cppConfigVersion.cmake
    DESTINATION ${TRX_INSTALL_CONFIGDIR}
)

include(CPack)

[neurolabusc]

Echoing issue #15, this project currently pulls in several very large dependencies. In the context of this issue, the stated rationale for mio is to provide memory-mapped file I/O without requiring Boost. However, the project currently depends on both mio and Boost, which undermines that goal.

Ideally, mio would be used to eliminate the need for Boost entirely. If Boost is truly required, then using mio no longer provides its intended benefit and should be reconsidered.

[mattcieslak]

This was a bad idea, but I added boost when moving back to c++11 because I didn't want to add code to the library that does file system traversing. I added a shim that handles file system traversing if boost isn't available (and it expanded dramatically to handle multiple OSes #16), but honestly I'm way out of my depth here. We could remove boost entirely, but I would really appreciate another set of eyes on the filesystem stuff