wip: stage pg_partman multi-version changes

Author: samrose

nix/ext/pg_partman.nix

@@ -1,38 +1,106 @@
 {
+  pkgs,
   lib,
   stdenv,
   fetchFromGitHub,
   postgresql,
+  makeWrapper,
+  switch-ext-version,
 }:
 
-stdenv.mkDerivation rec {
+let
   pname = "pg_partman";
-  version = "5.2.4";
+  build =
+    version: hash:
+    stdenv.mkDerivation rec {
+      inherit pname version;
 
-  buildInputs = [ postgresql ];
+      buildInputs = [ postgresql ];
+
+      src = fetchFromGitHub {
+        owner = "pgpartman";
+        repo = pname;
+        rev = "refs/tags/v${version}";
+        inherit hash;
+      };
+
+      installPhase = ''
+        mkdir -p $out/{lib,share/postgresql/extension}
+
+        # Install versioned library
+        install -Dm755 src/*${postgresql.dlSuffix} $out/lib/${pname}-${version}${postgresql.dlSuffix}
+
+        # Only install SQL files for the latest version
+        if [[ "${version}" == "${latestVersion}" ]]; then
+          # Install all SQL files from sql/ directory
+          cp -r sql/* $out/share/postgresql/extension/
+
+          # Install upgrade scripts
+          cp updates/* $out/share/postgresql/extension/
+        fi
+
+        # Create versioned control file with modified module path
+        sed -e "/^default_version =/d" \
+            -e "s|^module_pathname = .*|module_pathname = '\$libdir/${pname}'|" \
+          ${pname}.control > $out/share/postgresql/extension/${pname}--${version}.control
+      '';
+
+      meta = with lib; {
+        description = "Partition management extension for PostgreSQL";
+        homepage = "https://github.com/pgpartman/pg_partman";
+        changelog = "https://github.com/pgpartman/pg_partman/blob/v${version}/CHANGELOG.md";
+        platforms = postgresql.meta.platforms;
+        license = licenses.postgresql;
+      };
+    };
+  allVersions = (builtins.fromJSON (builtins.readFile ./versions.json)).pg_partman;
+  supportedVersions = lib.filterAttrs (
+    _: value: builtins.elem (lib.versions.major postgresql.version) value.postgresql
+  ) allVersions;
+  versions = lib.naturalSort (lib.attrNames supportedVersions);
+  latestVersion = lib.last versions;
+  numberOfVersions = builtins.length versions;
+  packages = builtins.attrValues (
+    lib.mapAttrs (name: value: build name value.hash) supportedVersions
+  );
+in
+pkgs.buildEnv {
+  name = pname;
+  paths = packages;
+  nativeBuildInputs = [ makeWrapper ];
+
+  pathsToLink = [
+    "/lib"
+    "/share/postgresql/extension"
+  ];
+
+  postBuild = ''
+    {
+      echo "default_version = '${latestVersion}'"
+      cat $out/share/postgresql/extension/${pname}--${latestVersion}.control
+    } > $out/share/postgresql/extension/${pname}.control
+    ln -sfn ${pname}-${latestVersion}${postgresql.dlSuffix} $out/lib/${pname}${postgresql.dlSuffix}
 
-  src = fetchFromGitHub {
-    owner = "pgpartman";
-    repo = pname;
-    rev = "refs/tags/v${version}";
-    sha256 = "sha256-GrVOJ5ywZMyqyDroYDLdKkXDdIJSDGhDfveO/ZvrmYs=";
-  };
 
-  installPhase = ''
-    mkdir -p $out/{lib,share/postgresql/extension}
+    # checks
+    (set -x
+       test "$(ls -A $out/lib/${pname}*${postgresql.dlSuffix} | wc -l)" = "${
+         toString (numberOfVersions + 1)
+       }"
+    )
 
-    cp src/*${postgresql.dlSuffix} $out/lib
-    cp updates/*     $out/share/postgresql/extension
-    cp -r sql/*      $out/share/postgresql/extension
-    cp *.control     $out/share/postgresql/extension
+    makeWrapper ${lib.getExe switch-ext-version} $out/bin/switch_pg_partman_version \
+      --prefix EXT_WRAPPER : "$out" --prefix EXT_NAME : "${pname}"
   '';
 
-  meta = with lib; {
-    description = "Partition management extension for PostgreSQL";
-    homepage = "https://github.com/pgpartman/pg_partman";
-    changelog = "https://github.com/pgpartman/pg_partman/blob/v${version}/CHANGELOG.md";
-    platforms = postgresql.meta.platforms;
-    license = licenses.postgresql;
-    broken = versionOlder postgresql.version "14";
+  passthru = {
+    inherit versions numberOfVersions switch-ext-version;
+    pname = "${pname}-all";
+    hasBackgroundWorker = true;
+    defaultSettings = {
+      shared_preload_libraries = [ "pg_partman_bgw" ];
+    };
+    version =
+      "multi-" + lib.concatStringsSep "-" (map (v: lib.replaceStrings [ "." ] [ "-" ] v) versions);
   };
 }

nix/ext/versions.json

@@ -320,6 +320,16 @@
       ],
       "hash": "sha256-Cpi2iASi1QJoED0Qs1dANqg/BNZTsz5S+pw8iYyW03Y="
     }
+  },
+  "pg_partman": {
+    "5.2.4": {
+      "postgresql": [
+        "15",
+        "17",
+        "orioledb-17"
+      ],
+      "hash": "sha256-i/o+JZEXnJRO17kfdTw87aca28+I8pvuFZsPMA/kf+w="
+    }
   },
     "pgmq": {
     "1.4.4": {

nix/packages/postgres.nix

@@ -36,6 +36,7 @@
         ../ext/pg_graphql
         ../ext/pg_stat_monitor.nix
         ../ext/pg_jsonschema
+        ../ext/pg_partman.nix
         ../ext/pgvector.nix
         ../ext/vault.nix
         ../ext/hypopg.nix