Update build system for failed images

 - Ensure that tests requiring GCC 7 are only built when it is available
 - Add a default option (set to ON) to enable failed images support when
   the required experimental/proposed fault tolerant MPI features are
   detected.

Author: zbeekman

CMakeLists.txt

@@ -465,7 +465,7 @@ function(add_mpi_test name num_mpi_proc path)
    set_property(TEST ${name} PROPERTY PASS_REGULAR_EXPRESSION "Test passed.")
 endfunction(add_mpi_test)
 
-function(add_mpi_failable_test name num_mpi_proc path)
+function(add_fault_tolerant_mpi_test name num_mpi_proc path)
    if ( ((N LESS num_mpi_proc) OR (N EQUAL 0)) )
      message(STATUS "Test ${name} is oversubscribed: ${num_mpi_proc} ranks requested with ${N} system processor available.")
      if ( openmpi )
@@ -481,7 +481,7 @@ function(add_mpi_failable_test name num_mpi_proc path)
    set(test_parameters ${test_parameters} ${MPIEXEC_NUMPROC_FLAG} ${num_mpi_proc} -disable-auto-cleanup )
    add_test(NAME ${name} COMMAND ${MPIEXEC} ${test_parameters} "${path}")
    set_property(TEST ${name} PROPERTY PASS_REGULAR_EXPRESSION "Test passed.")
-endfunction(add_mpi_failable_test)
+endfunction(add_fault_tolerant_mpi_test)
 
 set(tests_root ${CMAKE_CURRENT_BINARY_DIR}/src/tests)
 
@@ -551,20 +551,22 @@ if(opencoarrays_aware_compiler)
   add_mpi_test(co_reduce_string 4 ${tests_root}/unit/collectives/co_reduce_string)
 
   # IMAGE FAIL tests
-  add_mpi_test(image_status_test_1 4 ${tests_root}/unit/fail_images/image_status_test_1)
-#ifdef WITH_FAIL_IMAGES
-# No other way to check that image_fail_test_1 passes.
-  add_mpi_failable_test(image_fail_test_1 4 ${tests_root}/unit/fail_images/image_fail_test_1)
-  set_property(TEST image_fail_test_1 PROPERTY FAIL_REGULAR_EXPRESSION "Test failed")
-  set_property(TEST image_fail_test_1 PROPERTY PASS_REGULAR_EXPRESSION "Test passed")
-  add_mpi_failable_test(image_fail_and_sync_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_1)
-  add_mpi_failable_test(image_fail_and_sync_test_2 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_2)
-  add_mpi_failable_test(image_fail_and_sync_test_3 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_3)
-  add_mpi_failable_test(image_fail_and_status_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_status_test_1)
-  add_mpi_failable_test(image_fail_and_failed_images_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_failed_images_test_1)
-  add_mpi_failable_test(image_fail_and_stopped_images_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_stopped_images_test_1)
-  add_mpi_failable_test(image_fail_and_get_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_get_test_1)
-#endif
+  if(NOT CMAKE_Fortran_COMPILER_VERSION VERSION_LESS 7)
+    add_mpi_test(image_status_test_1 4 ${tests_root}/unit/fail_images/image_status_test_1)
+    if(CAF_ENABLE_FAILED_IMAGES)
+      # No other way to check that image_fail_test_1 passes.
+      add_fault_tolerant_mpi_test(image_fail_test_1 4 ${tests_root}/unit/fail_images/image_fail_test_1)
+      set_property(TEST image_fail_test_1 PROPERTY FAIL_REGULAR_EXPRESSION "Test failed")
+      set_property(TEST image_fail_test_1 PROPERTY PASS_REGULAR_EXPRESSION "Test passed")
+      add_fault_tolerant_mpi_test(image_fail_and_sync_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_1)
+      add_fault_tolerant_mpi_test(image_fail_and_sync_test_2 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_2)
+      add_fault_tolerant_mpi_test(image_fail_and_sync_test_3 4 ${tests_root}/unit/fail_images/image_fail_and_sync_test_3)
+      add_fault_tolerant_mpi_test(image_fail_and_status_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_status_test_1)
+      add_fault_tolerant_mpi_test(image_fail_and_failed_images_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_failed_images_test_1)
+      add_fault_tolerant_mpi_test(image_fail_and_stopped_images_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_stopped_images_test_1)
+      add_fault_tolerant_mpi_test(image_fail_and_get_test_1 4 ${tests_root}/unit/fail_images/image_fail_and_get_test_1)
+    endif()
+  endif()
 else()
   add_test(co_sum_extension ${tests_root}/unit/extensions/test-co_sum-extension.sh)
   set_property(TEST co_sum_extension PROPERTY PASS_REGULAR_EXPRESSION "Test passed.")

src/mpi/CMakeLists.txt

@@ -28,6 +28,60 @@ if(CAF_EXPOSE_INIT_FINALIZE)
   add_definitions(-DEXPOSE_INIT_FINALIZE)
 endif()
 
+#----------------------------------------------------------------------
+# Test if MPI implementation provides features needed for failed images
+#----------------------------------------------------------------------
+set(NEEDED_SYMBOLS MPIX_ERR_PROC_FAILED;MPIX_ERR_REVOKED;MPIX_Comm_failure_ack;MPIX_Comm_failure_get_acked;MPIX_Comm_shrink;MPIX_Comm_agree)
+set(MPI_HAS_FAULT_TOL_EXT YES)
+set(old_cmake_required_includes "${CMAKE_REQUIRED_INCLUDES}")
+if(CMAKE_REQUIRED_INCLUDES)
+  set(CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES};${MPI_C_INCLUDE_PATH})
+else()
+  set(CMAKE_REQUIRED_INCLUDES ${MPI_C_INCLUDE_PATH})
+endif()
+set(old_cmake_required_flags "${CMAKE_REQUIRED_FLAGS}")
+if(CMAKE_REQUIRED_FLAGS)
+  set(CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS};${MPI_C_COMPILE_FLAGS};${MPI_C_LINK_FLAGS})
+else()
+  set(CMAKE_REQUIRED_FLAGS ${MPI_C_COMPILE_FLAGS};${MPI_C_LINK_FLAGS})
+endif()
+set(old_cmake_required_libraries "${CMAKE_REQUIRED_LIBRARIES}")
+if(CMAKE_REQUIRED_LIBRARIES)
+  set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES};${MPI_C_LIBRARIES})
+else()
+  set(CMAKE_REQUIRED_LIBRARIES ${MPI_C_LIBRARIES})
+endif()
+
+set(MPI_HEADERS mpi.h)
+CHECK_INCLUDE_FILE("mpi-ext.h" HAVE_MPI_EXT)
+if(HAVE_MPI_EXT)
+  add_definitions(-DHAVE_MPI_EXT_H)
+  set(MPI_HEADERS ${MPI_HEADERS};mpi-ext.h)
+endif()
+include(CheckSymbolExists)
+foreach(symbol ${NEEDED_SYMBOLS})
+  CHECK_SYMBOL_EXISTS(${symbol} ${MPI_HEADERS} HAVE_${symbol})
+  if(NOT HAVE_${symbol})
+    message( STATUS "\${HAVE_${symbol}} = ${HAVE_${symbol}}")
+    message( WARNING "Disabling Failed Image support due to lack of support in the current MPI implementation.")
+    set(MPI_HAS_FAULT_TOL_EXT NO)
+    break() # no need to keep looking
+  endif()
+endforeach(symbol)
+set(CMAKE_REQUIRED_INCLUDES ${old_cmake_required_includes})
+set(CMAKE_REQUIRED_FLAGS ${old_cmake_required_flags})
+set(CMAKE_REQUIRED_LIBRARIES ${old_cmake_required_libraries})
+
+if(MPI_HAS_FAULT_TOL_EXT)
+  option(CAF_ENABLE_FAILED_IMAGES "Enable failed images support" TRUE)
+else()
+  set(CAF_ENABLE_FAILED_IMAGES FALSE CACHE BOOL "Enable failed images support" FORCE)
+endif()
+
+if(CAF_ENABLE_FAILED_IMAGES)
+  add_definitions(-DUSE_FAILED_IMAGES)
+endif()
+
 # Determine whether and how to include OpenCoarrays module based on if the Fortran MPI compiler:
 #   - workds
 #   - is compatible with the fortran compiler used to build the MPI implementation

src/mpi/mpi_caf.c

@@ -43,7 +43,7 @@ SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.  */
 #include <pthread.h>
 #include <signal.h>        /* For raise */
 
-#ifdef MPI_NEEDS_MPI_EXT
+#ifdef HAVE_MPI_EXT_H
 #include <mpi-ext.h>
 #endif
 #ifdef USE_FAILED_IMAGES

src/tests/unit/CMakeLists.txt

@@ -4,7 +4,9 @@ if (${opencoarrays_aware_compiler})
   add_subdirectory(init_register)
   add_subdirectory(collectives)
   add_subdirectory(sync)
-  add_subdirectory(fail_images)
+  if(NOT CMAKE_Fortran_COMPILER_VERSION VERSION_LESS 7)
+    add_subdirectory(fail_images)
+  endif()
 else()
   add_subdirectory(extensions)
 endif()