fmdl/flake.nix at master · sotormd/fmdl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
{
  description = "Manage a local library based on LastFM top tracks.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    naersk.url = "github:nix-community/naersk";
  };

  outputs =
    {
      self,
      nixpkgs,
      naersk,
      ...
    }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      ytDlpVersion = "2026.02.04";
      ytDlpHash = "sha256-KXnz/ocHBftenDUkCiFoBRBxi6yWt0fNuRX+vKFWDQw=";

      # function to build yt-dlp for a given pkgs
      mkYtDlp =
        pkgs:
        pkgs.python3Packages.buildPythonApplication rec {
          pname = "yt-dlp";
          version = ytDlpVersion;

          src = pkgs.fetchFromGitHub {
            owner = "yt-dlp";
            repo = "yt-dlp";
            tag = version;
            hash = ytDlpHash;
          };

          pyproject = true;
          buildSystem = [ pkgs.python3Packages.hatchling ];

          nativeBuildInputs = with pkgs; [
            installShellFiles
            pandoc
          ];

          propagatedBuildInputs = with pkgs.python3Packages; [
            brotli
            certifi
            mutagen
            pycryptodomex
            requests
            urllib3
            websockets
            hatchling
          ];

          doCheck = false;

          postBuild = ''
            python devscripts/prepare_manpage.py yt-dlp.1.temp.md
            pandoc -s -f markdown-smart -t man yt-dlp.1.temp.md -o yt-dlp.1
            rm yt-dlp.1.temp.md
          '';

          postInstall = ''
            install -Dm644 README.md -t $out/share/doc/yt_dlp
          '';
        };

      # generic per-system builder
      forSystem =
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          naerskLib = pkgs.callPackage naersk { };
          ytDlp = mkYtDlp pkgs;
        in
        {
          devShells.default = pkgs.mkShell {
            buildInputs =
              with pkgs;
              [
                cargo
                rustc
                rustfmt
                rust-analyzer
                gcc
                openssl
                ffmpeg
              ]
              ++ [ ytDlp ];
            nativeBuildInputs = [ pkgs.pkg-config ];
            env.RUST_SRC_PATH = "${pkgs.rust.packages.stable.rustPlatform.rustLibSrc}";
          };

          packages.default = naerskLib.buildPackage {
            src = ./.;
            CARGO_BUILD_TYPE = "release";

            buildInputs =
              with pkgs;
              [
                gcc
                openssl
                ffmpeg
              ]
              ++ [ ytDlp ];
            nativeBuildInputs = [
              pkgs.pkg-config
              pkgs.makeWrapper
            ];
            postInstall = ''
              wrapProgram $out/bin/fmdl \
                --prefix PATH : "${ytDlp}/bin:${pkgs.ffmpeg}/bin"
            '';
          };

          apps.default = {
            type = "app";
            program = "${self.packages.${system}.default}/bin/fmdl";
          };
        };

    in
    {
      devShells = builtins.listToAttrs (
        map (system: {
          name = system;
          value = (forSystem system).devShells;
        }) systems
      );

      packages = builtins.listToAttrs (
        map (system: {
          name = system;
          value = (forSystem system).packages;
        }) systems
      );

      apps = builtins.listToAttrs (
        map (system: {
          name = system;
          value = (forSystem system).apps;
        }) systems
      );
    };
}