serialize/build.gradle at master · slowcoders/serialize · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.+'
    }
}

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'com.jfrog.bintray'

group 'org.slowcoders'
version '1.0.0'

bintray {
    user = findProperty('maven.username')
    key = findProperty('maven.password')
    publications = ['publication']

    publish = true

    pkg {
        repo = 'slowcoders'
        name = 'serialize'
        vcsUrl = 'https://github.com/slowcoders/serialize.git'
        version {
            name = project.version
        }
    }
}

task sourcesJar(type: Jar) {
    from sourceSets.main.java.srcDirs
    classifier = 'sources'
}

publishing {
    publications {
        publication(MavenPublication) {
            pom.withXml {
                asNode().dependencies.dependency.each { dep ->
                    def _package = dep.groupId.last().value().last() + ':' + dep.artifactId.last().value().last()
                    if(_package in excludeInPublish) {
                        assert dep.parent().remove(dep)
                    }
                }
            }
            from components.java
            groupId project.group
            artifactId = 'serialize'
            version project.version

            artifact sourcesJar
        }
    }
}

repositories {
    jcenter()
}


sourceSets {
    main {
        java {
            srcDirs += 'src/main/java'
        }
    }
}

ext {
    targetPlatform = 'java'
    excludeInPublish = [
            'com.google.guava:guava'
    ]
}

dependencies {
    if (project.targetPlatform == 'android') {
        implementation group: 'com.google.guava', name: 'guava', version: '25.1-android'
    } else {
        implementation group: 'com.google.guava', name: 'guava', version: '25.1-jre'
    }
    implementation group: 'joda-time', name: 'joda-time', version: '2.9.9'
}