build.gradle

plugins {
    id 'pl.allegro.tech.build.axion-release' version '1.17.2'
    id 'java'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    withSourcesJar()
    withJavadocJar()
}
ext.rundeckPluginVersion = '1.2'
ext.pluginClassNames='edu.ohio.ais.rundeck.HttpWorkflowStepPlugin,edu.ohio.ais.rundeck.HttpWorkflowNodeStepPlugin'
ext.pluginName = 'Rundeck Http Step'
ext.pluginDescription = 'A workflow plugin that makes HTTP requests'
group = 'org.rundeck.plugins'

ext.publishName = "Rundeck Http Step ${project.version}"
ext.githubSlug = 'rundeck-plugins/http-step'
ext.developers = [
        [id: 'gschueler', name: 'Greg Schueler', email: 'greg@rundeck.com']
]

scmVersion {
    ignoreUncommittedChanges = false
    tag {
        prefix = ''           // NO "v" prefix - see PLUGIN_TAGGING_ARCHITECTURE.md
        versionSeparator = ''
    }
}

version = scmVersion.version  // Dynamic version from git tag

repositories {
    mavenLocal()
    maven {
        name = 'Central Portal Snapshots'
        url = 'https://central.sonatype.com/repository/maven-snapshots/'
        content {
            includeGroup('org.rundeck')
        }
    }
    maven {
        name = 'Central Portal Snapshots'
        url = 'https://central.sonatype.com/repository/maven-snapshots/'
        
        // Only search this repository for org.rundeck snapshots
        content {
            includeGroup('org.rundeck')
        }
    }
    mavenCentral()
}

configurations{
    //declare custom pluginLibs configuration to include only libs for this plugin
    pluginLibs

    //declare compile to extend from pluginLibs so it inherits the dependencies
    implementation {
        extendsFrom pluginLibs
    }
}

dependencies {
    compileOnly 'org.rundeck:rundeck-core:6.0.0-alpha1-20260407'
    testImplementation 'org.rundeck:rundeck-core:6.0.0-alpha1-20260407'
    
    // Add secure commons-lang3 to provide alternative to vulnerable commons-lang 2.6
    // Version 3.20.0 fixes CVE-2025-48924 (StackOverflowError in ClassUtils)
    pluginLibs 'org.apache.commons:commons-lang3:3.20.0'

    pluginLibs group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.14'
    pluginLibs group: 'com.google.code.gson', name: 'gson', version:'2.10.1'

    testImplementation group: 'com.github.tomakehurst', name: 'wiremock-standalone', version:'2.23.2'
    testImplementation group: 'junit', name: 'junit', version:'4.13.2'

    testImplementation (
            'org.mockito:mockito-all:1.9.5',
            'org.powermock:powermock-module-junit4:1.5',
            'org.powermock:powermock-api-mockito:1.5'
    )
}

configurations.all {
    resolutionStrategy {
        // Replace vulnerable commons-lang with secure commons-lang3
        // Version 3.18.0 fixes CVE-2025-48924 (StackOverflowError in ClassUtils)
        dependencySubstitution {
            substitute module('commons-lang:commons-lang') using module('org.apache.commons:commons-lang3:3.18.0')
        }
    }
}


test {
    useJUnit()
    
    // Java 17+ module access for reflection/mocking
    jvmArgs = [
        '--add-opens=java.base/java.lang=ALL-UNNAMED',
        '--add-opens=java.base/java.util=ALL-UNNAMED',
        '--add-opens=java.base/java.lang.reflect=ALL-UNNAMED',
        '--add-opens=java.base/java.net=ALL-UNNAMED'
    ]
}

jar {
    // Include plugin dependencies in lib/ directory
    into('lib') {
        from configurations.pluginLibs
    }
    
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/'+it.name}.join(' ')

        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': version
        attributes 'Rundeck-Plugin-Name': pluginName
        attributes 'Rundeck-Plugin-Description': pluginDescription
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '3.x'
        attributes 'Rundeck-Plugin-Tags': 'java,WorkflowStep'
        attributes 'Rundeck-Plugin-License': 'Apache 2.0'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/http-step'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion
        attributes 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
    }
}

nexusPublishing {
    packageGroup = 'org.rundeck.plugins'
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}

apply from: "${rootDir}/gradle/publishing.gradle"