git-resource-model/build.gradle at master · rundeck-plugins/git-resource-model · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'pl.allegro.tech.build.axion-release' version '1.18.18'
    id 'java'
}

group 'com.rundeck'

ext.rundeckPluginVersion = '1.2'
ext.pluginClassNames='com.rundeck.plugin.GitResourceModelFactory'
ext.pluginName = 'Git Resource Model'
ext.pluginDescription = 'Writable Git Resource Model'

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

scmVersion {
    ignoreUncommittedChanges = true
    tag {
        prefix = ''
        versionSeparator = ''
    }
    versionCreator("simple")
}
project.version = scmVersion.version

apply plugin: 'groovy'
apply plugin: 'java'

repositories {
    mavenCentral()
}

configurations {
    pluginLibs

    implementation {
        extendsFrom pluginLibs
    }
}


dependencies {
    implementation 'org.codehaus.groovy:groovy-all:3.0.22'
    testImplementation group: 'junit', name: 'junit', version: '4.13.2'

    implementation group: 'org.rundeck', name: 'rundeck-core', version: '5.10.0-20250312'
    implementation 'org.slf4j:slf4j-api:1.7.30'

    pluginLibs( 'org.eclipse.jgit:org.eclipse.jgit.ssh.jsch:5.13.3.202401111512-r') {
        exclude module: 'slf4j-api'
        exclude group: 'org.bouncycastle'
    }

    pluginLibs('org.eclipse.jgit:org.eclipse.jgit:6.6.1.202309021850-r') {
        exclude module: 'slf4j-api'
        exclude module: 'jsch'
        exclude module: 'commons-logging'
    }

    testImplementation "org.codehaus.groovy:groovy-all:3.0.22"
    testImplementation "org.spockframework:spock-core:2.0-groovy-3.0"
    testImplementation "cglib:cglib-nodep:3.3.0"
    testImplementation 'org.objenesis:objenesis:1.4'
}


task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}

jar {
    from "$buildDir/output"
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/' + it.name}.join(' ')
        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': project.version
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion
        attributes 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
    }
    dependsOn(copyToLib)
}