nativefiledialog-java/build.gradle.kts at master · robinmaisch/nativefiledialog-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
plugins {
    alias(libs.plugins.kotlin)
    `maven-publish`
    signing
}

group = "tv.wunderbox"
version = "1.0.3"

repositories {
    mavenCentral()
}

java {
    withJavadocJar()
    withSourcesJar()
}

kotlin {
    explicitApi()
    jvmToolchain(8)
}

dependencies {
    // JNA - https://github.com/java-native-access/jna
    implementation(libs.jna)
}

// See:
// https://www.jetbrains.com/help/space/publish-artifacts-to-maven-central.html
// on how to publish to maven repos.
publishing {
    publications {
        create<MavenPublication>("maven") {
            groupId = project.group.toString()
            artifactId = "nativefiledialog"
            version = project.version.toString()

            from(components["java"])

            pom {
                packaging = "jar"
                name.set("Native File Dialog Java")
                url.set("https://github.com/WonderzGmbH/nativefiledialog-java")
                description.set("A wrapper around the small btzy/nativefiledialog-extended. As a fallback it uses AWT file picker.")

                licenses {
                    license {
                        name.set("zlib License")
                        url.set("https://github.com/WonderzGmbH/nativefiledialog-java/blob/master/LICENSE")
                    }
                }

                scm {
                    connection.set("scm:https://github.com/WonderzGmbH/nativefiledialog-java.git")
                    developerConnection.set("scm:git@github.com:WonderzGmbH/nativefiledialog-java.git")
                    url.set("https://github.com/WonderzGmbH/nativefiledialog-java")
                }

                developers {
                    developer {
                        id.set("AChep")
                        name.set("Artem Chepurnyi")
                        email.set("artemchep@gmail.com")
                    }
                }
            }
        }
    }
    repositories {
        maven {
            val releasesUrl = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
            val snapshotsUrl = uri("https://s01.oss.sonatype.org/content/repositories/snapshots/")
            url = if (version.toString().endsWith("SNAPSHOT")) snapshotsUrl else releasesUrl
            credentials {
                username = project.properties["ossrhUsername"].toString()
                password = project.properties["ossrhPassword"].toString()
            }
        }
    }
}


signing {
    sign(publishing.publications)
}

tasks.withType<Jar>() {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE

    from(configurations.compileClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
}