ShapeType.idl

/*****************************************************************************/
/*         (c) Copyright, Real-Time Innovations, All rights reserved.        */
/*                                                                           */
/*         Permission to modify and use for internal purposes granted.       */
/* This software is provided "as is", without warranty, express or implied.  */
/*                                                                           */
/*****************************************************************************/

module rti {

    module picture {
        const short WIDTH  = 640;
        const short HEIGHT = 480; 

        @nested 
        struct PictureType {
            short dim;                             // dimension: width or height
            sequence<octet, WIDTH * HEIGHT> pixel; // pixels
        }; 
    };

    module shapes {
        struct ShapeType {
            @key // identifies the instance (a.k.a data-object)
            string<128> color; 
          
            long x;
            long y;
            long shapesize; 
        };

        enum ShapeFillKind {
            SOLID_FILL,
            TRANSPARENT_FILL,
            HORIZONTAL_HATCH_FILL,
            VERTICAL_HATCH_FILL
        };

        struct ShapeTypeExtended : ShapeType {
            ShapeFillKind fillKind;
            float angle;
        };

        struct PictureShapeType : ShapeTypeExtended {
            picture::PictureType picture;
        };
    };
};

// Names defined the DDS-XML file
module My {
    module If { 
        const string PUB            = "ShapesIfLib::Shapes_Pub";
        const string SUB            = "ShapesIfLib::Shapes_Sub";
    };
    module Topic {
        module Shape {
            const string TYPE       = "ShapeType";
            const string WRITER     = "_pub::Shape_writer";
            const string READER     = "_sub::Shape_reader";
        };
    };
};