init

#!/bin/zsh

setopt EXTENDED_GLOB
setopt +o nomatch

git submodule update --init --recursive

# Create local bin sym links
function() {
    local BINDIR=$HOME/.local/bin
    mkdir -p $BINDIR

    for xfile in ${PWD}/bin/*; do
        ln -s "$xfile" "$BINDIR/${xfile:t}"
    done
}

#############################

is_mac() {
    [[ "$OSTYPE" == "darwin"* ]]
}

is_linux() {
    [[ "$OSTYPE" == 'linux-gnu'* ]]
}

command_exists() {
    (( $+commands[$1] ));
}

standard_install() {
    if ! (command_exists $1); then
    echo "\nInstalling $1..."
        if is_mac; then
            brew install $1
        elif is_linux; then
            sudo apt-get install $1
        fi
    fi
}

#############################

# Create sym links for dot configs
echo "\nCreating dot configs..."
for dotfile in ${PWD}/dotconf/*; do
    ln -s "$dotfile" "$HOME/.${dotfile:t}"
done

#############################

rm $HOME/.zshrc

# Create zsh config sym links
echo "\nCreating zsh configs..."
for rcfile in "${PWD}"/zsh/configs/*; do
    ln -s "$rcfile" "$HOME/.${rcfile:t}"
done

# Create .zshrc.local
function () {
    local RCLOCAL=$HOME/.zshrc.local
    touch $RCLOCAL
    if ! grep -q "export ZSH_THEME_COLOR=" $RCLOCAL; then
    cat <<EOF >>$RCLOCAL
export ZSH_THEME_COLOR=66
source ~/.p10k.zsh

alias mount-projects='sudo mount -t nfs \${POISSON_IP}:/srv/nfs/projects ~/projects & sudo mount -t nfs \${POISSON_IP}:/srv/nfs/store ~/store'

if [ -d ~/projects ] && [ ! "\$(ls -A ~/projects)" ]; then
    mount-projects
fi

ulimit -n unlimited
restore_tmux "main"
EOF
    fi
}

source $HOME/.zshrc
proxy-on

#############################

# Intall homebrew
if is_mac && ! (command_exists brew); then
    echo "\nInstalling homebrew..."
    /bin/bash -c "$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/master/install.sh)"
    PATH=$PATH:/opt/homebrew/bin
fi

# Install build-essential
if is_linux; then
    sudo apt update
    sudo apt install build-essential libfuse2 iftop nfs-common python3-venv
fi

# Create python3 venv
python3 -m venv --system-site-packages $HOME/.venv
source $HOME/.zshrc

# Install pip
if ! (command_exists pip3); then
    echo "\nInstalling pip..."
    if is_linux; then
        sudo apt-get install python3 python3-distutils python3-apt
    fi
    curl https://bootstrap.pypa.io/get-pip.py -o get-pip.py
    sudo python3 get-pip.py
    rm get-pip.py
fi

#############################

# Install tmux
echo "\nConfiguring tmux..."
standard_install tmux
git clone git@github.com:tmux-plugins/tpm $HOME/.tmux/plugins/tpm
tmux source $HOME/.tmux.conf
$HOME/.tmux/plugins/tpm/scripts/install_plugins.sh
$HOME/.tmux/plugins/tpm/scripts/source_plugins.sh

pip3 install neovim

# Install node
if ! (command_exists node); then
    echo "\nInstalling node..."
    curl -sfLS https://install-node.vercel.app | sudo -E bash
fi

npm config set prefix ~/.local
npm install -g neovim

# Install nvim
if ! (command_exists nvim); then
    echo "\nInstalling nvim..."
    if is_linux; then
        sudo apt install libfuse2
    fi
    ${PWD}/scripts/install_neovim
fi

function() {
    echo "\nConfiguring vim..."
    # Create vim config sym links
    local DOT_VIM_DIR=${PWD}/vim

    # Create nvim config sym links
    if (command_exists nvim); then
        mkdir -p $HOME/.config
        rm -r $HOME/.config/nvim
        ln -sf ${DOT_VIM_DIR}/nvim $HOME/.config/nvim

        nvim +UpdateRemotePlugins +qa!
        alias vi='nvim'
    fi

    vi --headless -c 'lua require("lazy").install()' -c 'qa'
}

# Install ag
if ! (command_exists ag); then
    echo "\nInstalling ag..."
    if is_linux; then
        sudo apt-get install silversearcher-ag
    elif is_mac; then
        brew install the_silver_searcher
    fi
fi

# Install tree
standard_install tree

# Install fzf
if [ ! -s $HOME/.fzf ]; then
    echo "\nInstalling fzf..."
    git clone --depth 1 git@github.com:junegunn/fzf.git $HOME/.fzf
    $HOME/.fzf/install --bin
fi

# Install autojump
standard_install autojump

# Install thefuck
if ! (command_exists fuck); then
    echo "\nInstalling thefuck..."
    pip3 install thefuck
fi

# Install Kitty
if ! (command_exists kitty); then
    echo "\nInstalling kitty..."
    read "REPLY?Install kitty? [Y/n] "
    echo
    if [[ $REPLY =~ ^[Yy]$ ]]; then
        ${PWD}/scripts/install_kitty
        if is_linux; then
            ln -s ~/.local/kitty.app/bin/kitty ~/.local/bin/
            cp ~/.local/kitty.app/share/applications/kitty.desktop ~/.local/share/applications/
            cp ~/.local/kitty.app/share/applications/kitty-open.desktop ~/.local/share/applications/
            wget https://raw.githubusercontent.com/igrmk/whiskers/main/whiskers_256x256.png -O $HOME/.local/kitty.app/share/icons/hicolor/256x256/apps/kitty.png
            sed -i "s|Icon=kitty|Icon=/home/$USER/.local/kitty.app/share/icons/hicolor/256x256/apps/kitty.png|g" ~/.local/share/applications/kitty*.desktop
            sed -i "s|Exec=kitty|Exec=/home/$USER/.local/kitty.app/bin/kitty|g" ~/.local/share/applications/kitty*.desktop
        fi
        mkdir -p $HOME/.config/kitty
        ln -s ${PWD}/kitty/* "$HOME/.config/kitty"
    fi
fi

#############################
proxy-off

# Install Julia
if ! (command_exists julia); then
    curl -fsSL https://install.julialang.org | sh
fi