libOpenDRIVE/CMakeLists.txt at main · pageldev/libOpenDRIVE · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
cmake_minimum_required(VERSION 3.14)

project(libOpenDrive VERSION 0.6.0 DESCRIPTION ".xodr library")

include(FetchContent)
include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

option(OPENDRIVE_BUILD_TESTS "Build OpenDrive tests" OFF)

find_package(pugixml QUIET CONFIG)
if(NOT TARGET pugixml::pugixml)
    if(TARGET pugixml)
        add_library(pugixml::pugixml ALIAS pugixml)
    else()
        FetchContent_Declare(
            pugixml
            GIT_REPOSITORY https://github.com/zeux/pugixml.git
            GIT_TAG v1.14
        )
        FetchContent_MakeAvailable(pugixml)
        add_library(pugixml::pugixml ALIAS pugixml)
    endif()
endif()

set(SOURCES
    src/Geometries/Arc.cpp
    src/Geometries/CubicSpline.cpp
    src/Geometries/Line.cpp
    src/Geometries/ParamPoly3.cpp
    src/Geometries/RoadGeometry.cpp
    src/Geometries/Spiral.cpp
    src/Geometries/Spiral/odrSpiral.cpp
    src/Junction.cpp
    src/Lane.cpp
    src/LaneSection.cpp
    src/Mesh.cpp
    src/OpenDriveMap.cpp
    src/RefLine.cpp
    src/Road.cpp
    src/RoadMark.cpp
    src/RoadNetworkMesh.cpp
    src/RoadObject.cpp
    src/RoadSignal.cpp
    src/RoutingGraph.cpp
)

add_library(OpenDrive ${SOURCES})
add_library(OpenDrive::OpenDrive ALIAS OpenDrive)
set_target_properties(OpenDrive PROPERTIES
    CXX_STANDARD 17
    CXX_STANDARD_REQUIRED ON
    POSITION_INDEPENDENT_CODE ON
)
if(MSVC)
    target_compile_options(OpenDrive PRIVATE /W3 /EHsc)
    target_compile_definitions(OpenDrive PRIVATE _USE_MATH_DEFINES)
else()
    target_compile_options(OpenDrive PRIVATE -Wall -Wextra)
endif()

target_link_libraries(OpenDrive PUBLIC pugixml::pugixml)

target_include_directories(
    OpenDrive PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)

if(OPENDRIVE_BUILD_TESTS)
    include(CTest)
    FetchContent_Declare(
        Catch2
        GIT_REPOSITORY https://github.com/catchorg/Catch2.git
        GIT_TAG v3.4.0
    )
    FetchContent_MakeAvailable(Catch2)
    include(Catch)

    add_executable(tests tests/test.cpp)
    set_target_properties(tests PROPERTIES
        CXX_STANDARD 17
        CXX_STANDARD_REQUIRED ON
    )
    target_link_libraries(tests PRIVATE OpenDrive Catch2::Catch2WithMain)
    catch_discover_tests(tests WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/tests)
endif()

install(
    TARGETS OpenDrive
    EXPORT OpenDriveTargets
    INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/include/ DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

install(
    EXPORT OpenDriveTargets
    NAMESPACE OpenDrive::
    FILE OpenDriveTargets.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenDrive
)

write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/OpenDriveConfigVersion.cmake"
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY ExactVersion
)

configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/OpenDriveConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/OpenDriveConfig.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenDrive
)

install(FILES
    "${CMAKE_CURRENT_BINARY_DIR}/OpenDriveConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/OpenDriveConfigVersion.cmake"
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenDrive
)