|
| 1 | +#Использовать logos |
| 2 | +#Использовать tempfiles |
| 3 | +#Использовать fs |
| 4 | + |
| 5 | +Перем ВерсияПлагина; |
| 6 | +Перем Лог; |
| 7 | +Перем Обработчик; |
| 8 | +Перем КомандыПлагина; |
| 9 | + |
| 10 | +Перем ИмяПроекта; |
| 11 | +Перем РабочееПространство; |
| 12 | +Перем ИмяРасширения; |
| 13 | +Перем ИмяБазовогоПроекта; |
| 14 | + |
| 15 | +#Область Интерфейс_плагина |
| 16 | + |
| 17 | +// Возвращает версию плагина |
| 18 | +// |
| 19 | +// Возвращаемое значение: |
| 20 | +// Строка - текущая версия плагина |
| 21 | +// |
| 22 | +Функция Версия() Экспорт |
| 23 | + Возврат ВерсияПлагина; |
| 24 | +КонецФункции |
| 25 | + |
| 26 | +// Возвращает приоритет выполнения плагина |
| 27 | +// |
| 28 | +// Возвращаемое значение: |
| 29 | +// Число - приоритет выполнения плагина |
| 30 | +// |
| 31 | +Функция Приоритет() Экспорт |
| 32 | + Возврат 0; |
| 33 | +КонецФункции |
| 34 | + |
| 35 | +// Возвращает описание плагина |
| 36 | +// |
| 37 | +// Возвращаемое значение: |
| 38 | +// Строка - описание функциональности плагина |
| 39 | +// |
| 40 | +Функция Описание() Экспорт |
| 41 | + Возврат "Плагин добавляет возможность выгрузки в формате EDT." |
| 42 | + + " Важно: Для работы плагина необходимы установленные EDT и Ring"; |
| 43 | +КонецФункции |
| 44 | + |
| 45 | +// Возвращает подробную справку к плагину |
| 46 | +// |
| 47 | +// Возвращаемое значение: |
| 48 | +// Строка - подробная справка для плагина |
| 49 | +// |
| 50 | +Функция Справка() Экспорт |
| 51 | + Возврат "Справка плагина"; |
| 52 | +КонецФункции |
| 53 | + |
| 54 | +// Возвращает имя плагина |
| 55 | +// |
| 56 | +// Возвращаемое значение: |
| 57 | +// Строка - имя плагина при подключении |
| 58 | +// |
| 59 | +Функция Имя() Экспорт |
| 60 | + Возврат "edtExport"; |
| 61 | +КонецФункции |
| 62 | + |
| 63 | +// Возвращает имя лога плагина |
| 64 | +// |
| 65 | +// Возвращаемое значение: |
| 66 | +// Строка - имя лога плагина |
| 67 | +// |
| 68 | +Функция ИмяЛога() Экспорт |
| 69 | + Возврат "oscript.lib.gitsync.plugins.edtExport"; |
| 70 | +КонецФункции |
| 71 | + |
| 72 | +#КонецОбласти |
| 73 | + |
| 74 | +#Область Подписки_на_события |
| 75 | + |
| 76 | +Процедура ПриАктивизации(СтандартныйОбработчик) Экспорт |
| 77 | + |
| 78 | + Обработчик = СтандартныйОбработчик; |
| 79 | + |
| 80 | +КонецПроцедуры |
| 81 | + |
| 82 | +// BSLLS:UnusedParameters-off |
| 83 | +Процедура ПередНачаломВыполнения(ПутьКХранилищу, КаталогРабочейКопии) Экспорт |
| 84 | +// BSLLS:UnusedParameters-on |
| 85 | + |
| 86 | + ИмяРасширения = Обработчик.ПолучитьИмяРасширения(); |
| 87 | + |
| 88 | +КонецПроцедуры |
| 89 | + |
| 90 | +Процедура ПриРегистрацииКомандыПриложения(ИмяКоманды, КлассРеализации) Экспорт |
| 91 | + |
| 92 | + Лог.Отладка("Ищу команду <%1> в списке поддерживаемых", ИмяКоманды); |
| 93 | + Если КомандыПлагина.Найти(ИмяКоманды) = Неопределено Тогда |
| 94 | + Возврат; |
| 95 | + КонецЕсли; |
| 96 | + |
| 97 | + Лог.Отладка("Устанавливаю дополнительные параметры для команды %1", ИмяКоманды); |
| 98 | + |
| 99 | + КлассРеализации.Опция("P project-name", "", "[*edtExport] Имя проекта") |
| 100 | + .ТСтрока() |
| 101 | + .ВОкружении("GITSYNC_PROJECT_NAME"); |
| 102 | + |
| 103 | + КлассРеализации.Опция("W workspace-location", "", "[*edtExport] расположение рабочей области") |
| 104 | + .ТСтрока() |
| 105 | + .ВОкружении("GITSYNC_WORKSPACE_LOCATION"); |
| 106 | + |
| 107 | + КлассРеализации.Опция( |
| 108 | + "B base-project-name", |
| 109 | + "", |
| 110 | + "[*edtExport] имя базового проекта в рабочей области (для расширений))") |
| 111 | + .ТСтрока() |
| 112 | + .ВОкружении("GITSYNC_BASE_PROJECT_NAME"); |
| 113 | + |
| 114 | +КонецПроцедуры |
| 115 | + |
| 116 | +Процедура ПриПолученииПараметров(ПараметрыКоманды) Экспорт |
| 117 | + |
| 118 | + ИмяПроекта = ПараметрыКоманды.Параметр("project-name"); |
| 119 | + РабочееПространство = ПараметрыКоманды.Параметр("workspace-location"); |
| 120 | + ИмяБазовогоПроекта = ПараметрыКоманды.Параметр("base-project-name"); |
| 121 | + |
| 122 | + Если Не ПустаяСтрока(ИмяРасширения) |
| 123 | + И Не ПустаяСтрока(ИмяБазовогоПроекта) |
| 124 | + И ПустаяСтрока(РабочееПространство) Тогда |
| 125 | + |
| 126 | + ВызватьИсключение "При конвертации расширений с указанием базового проекта, |
| 127 | + |параметр workspace-location обязателен"; |
| 128 | + |
| 129 | + КонецЕсли; |
| 130 | + |
| 131 | + Если ПустаяСтрока(ИмяПроекта) Тогда |
| 132 | + ВызватьИсключение "Не заполнено имя проекта"; |
| 133 | + КонецЕсли; |
| 134 | + |
| 135 | +КонецПроцедуры |
| 136 | + |
| 137 | +// BSLLS:UnusedParameters-off |
| 138 | +Процедура ПередПеремещениемВКаталогРабочейКопии( |
| 139 | + Конфигуратор, |
| 140 | + КаталогРабочейКопии, |
| 141 | + КаталогВыгрузки, |
| 142 | + ПутьКХранилищу, |
| 143 | + НомерВерсии) Экспорт |
| 144 | +// BSLLS:UnusedParameters-on |
| 145 | + |
| 146 | + Лог.Отладка("Начинаю выгрузку EDT"); |
| 147 | + Лог.Отладка("Имя проекта: %1", ИмяПроекта); |
| 148 | + |
| 149 | + ВременноеРабочееПространство = ВременныеФайлы.СоздатьКаталог(); |
| 150 | + Если Не ПустаяСтрока(РабочееПространство) Тогда |
| 151 | + ФС.КопироватьСодержимоеКаталога(РабочееПространство, ВременноеРабочееПространство); |
| 152 | + КонецЕсли; |
| 153 | + |
| 154 | + Лог.Отладка("Рабочее пространство EDT: %1", ВременноеРабочееПространство); |
| 155 | + |
| 156 | + КаталогПроекта = ОбъединитьПути(ВременноеРабочееПространство, ИмяПроекта); |
| 157 | + |
| 158 | + Лог.Отладка("Каталог проекта EDT: %1", КаталогПроекта); |
| 159 | + ФС.ОбеспечитьПустойКаталог(КаталогПроекта); |
| 160 | + |
| 161 | + Команда = Новый Команда; |
| 162 | + |
| 163 | + Параметры = Новый Массив(); |
| 164 | + Параметры.Добавить(СтрШаблон("--configuration-files ""%1""", КаталогВыгрузки)); |
| 165 | + Параметры.Добавить(СтрШаблон("--workspace-location ""%1""", ВременноеРабочееПространство)); |
| 166 | + Параметры.Добавить(СтрШаблон("--project ""%1""", КаталогПроекта)); |
| 167 | + |
| 168 | + Если Не ПустаяСтрока(ИмяРасширения) И Не ПустаяСтрока(ИмяБазовогоПроекта) Тогда |
| 169 | + Параметры.Добавить(СтрШаблон("--base-project-name ""%1""", ИмяБазовогоПроекта)); |
| 170 | + КонецЕсли; |
| 171 | + |
| 172 | + Команда.УстановитьСтрокуЗапуска("ring edt workspace import"); |
| 173 | + Команда.УстановитьКодировкуВывода(КодировкаТекста.ANSI); |
| 174 | + Команда.ДобавитьЛогВыводаКоманды("oscript.lib.gitsync.plugins.edtExport"); |
| 175 | + Команда.ДобавитьПараметры(Параметры); |
| 176 | + Команда.УстановитьИсполнениеЧерезКомандыСистемы(Истина); |
| 177 | + Команда.ПоказыватьВыводНемедленно(Ложь); |
| 178 | + Команда.УстановитьПравильныйКодВозврата(0); |
| 179 | + КодВозврата = Команда.Исполнить(); |
| 180 | + |
| 181 | + Лог.Отладка("Код возврата EDT: %1", КодВозврата); |
| 182 | + |
| 183 | + Лог.Отладка("Очищаю каталог выгрузки"); |
| 184 | + УдалитьФайлы(КаталогВыгрузки, "*"); |
| 185 | + |
| 186 | + Лог.Отладка("Копирую каталог проекта EDT в каталог выгрузки"); |
| 187 | + ФС.КопироватьСодержимоеКаталога(КаталогПроекта, КаталогВыгрузки); |
| 188 | + |
| 189 | +КонецПроцедуры |
| 190 | + |
| 191 | +#КонецОбласти |
| 192 | + |
| 193 | +Процедура Инициализация() |
| 194 | + |
| 195 | + ВерсияПлагина = "1.1.1"; |
| 196 | + Лог = Логирование.ПолучитьЛог(ИмяЛога()); |
| 197 | + КомандыПлагина = Новый Массив; |
| 198 | + КомандыПлагина.Добавить("sync"); |
| 199 | + |
| 200 | + ИмяРасширения = ""; |
| 201 | + РабочееПространство = ""; |
| 202 | + ИмяБазовогоПроекта = ""; |
| 203 | + |
| 204 | +КонецПроцедуры |
| 205 | + |
| 206 | +Инициализация(); |
0 commit comments