addresses/build.gradle at development · onstructive/addresses · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
plugins {
    id "groovy"
    id "com.github.johnrengelman.shadow" version "6.1.0" apply false
    id "io.micronaut.library" version "1.4.2" apply false
    id "io.micronaut.application" version "1.4.2" apply false
    id "com.diffplug.spotless" version "5.12.4" apply false
}

subprojects { subproject ->

    version "0.1"
    group "ch.onstructive.candidates"

    if (subproject.name.endsWith("server")) {
        apply plugin: "io.micronaut.application"
    }
    else {
        apply plugin: "io.micronaut.library"
    }
    apply plugin: 'groovy'
    apply plugin: "com.diffplug.spotless"

    micronaut {
        runtime("netty")
        testRuntime("spock2")
        processing {
            incremental(true)
            annotations("com.example.*")
        }
    }

    dependencies {
        annotationProcessor("io.micronaut.data:micronaut-data-processor")
        implementation("io.micronaut:micronaut-http-client")
        implementation("io.micronaut:micronaut-runtime")
        implementation("io.micronaut.data:micronaut-data-hibernate-jpa")
        implementation("io.micronaut.flyway:micronaut-flyway")
        implementation("io.micronaut.sql:micronaut-jdbc-hikari")
        implementation("javax.annotation:javax.annotation-api")
        implementation("io.micronaut:micronaut-validation")
        runtimeOnly("ch.qos.logback:logback-classic")
        runtimeOnly("com.h2database:h2")

        implementation "org.mapstruct:mapstruct:${mapstructVersion}"
        annotationProcessor "org.mapstruct:mapstruct-processor:${mapstructVersion}"
    }

    java {
        sourceCompatibility = JavaVersion.toVersion('15')
        targetCompatibility = JavaVersion.toVersion('15')
    }

    spotless {
        java {
            googleJavaFormat()
            licenseHeader '/* Licensed under Apache-2.0 */'

            importOrder 'ch', 'java', 'javax', 'org', 'com', 'com.diffplug', ''    // A sequence of package names
            removeUnusedImports() // removes any unused imports
        }
        groovy {
            licenseHeader '/* Licensed under Apache-2.0 */'
            excludeJava()
            greclipse()
        }
    }
}