hang.live/justfile at main · moq-dev/hang.live · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
#!/usr/bin/env just --justfile

# Using Just: https://github.com/casey/just?tab=readme-ov-file#installation

mod api
mod app
mod dev
mod native
mod infra

# List all of the available commands.
default:
  just --list

# Run the CI checks
check:
	#!/usr/bin/env bash
	set -euo pipefail
	bun install --frozen-lockfile
	if tty -s; then
		bun run --filter='*' check
	else
		bun run --filter='*' check
	fi
	just native check

# Automatically fix some issues.
fix:
	bun install
	bun run --filter='*' fix
	just native fix

# Upgrade any tooling
upgrade:
	# Update the NPM dependencies
	bun update
	bun outdated

# Build the packages
build:
	bun install --frozen-lockfile
	bun run --filter='*' build

prod: build
	bun run --filter='*' prod

deploy env="staging":
	just api deploy "{{env}}"
	just app deploy "{{env}}"

dev:
	bun install
	@just dev auth-token
	bun concurrently --kill-others --names api,app,relay --prefix-colors auto \
		"just api dev" \
		"just app dev" \
		"just dev root"

# Run the native app in development mode
native:
	just native dev

# Run the Android build, using --open to open Android Studio
android *args:
	just native android {{args}}

# Run the iOS build, using --open to open Xcode
ios *args:
	just native ios {{args}}

# Release the app for the given platform
release platform:
	just native release "{{platform}}"