modeled-java/build.gradle at main · modeled/modeled-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
plugins {
    id 'groovy'
    id 'java'
    id 'java-library'
    id 'maven-publish'

    alias libs.plugins.versions
}

wrapper {
    gradleVersion = '8.7'
}


group 'me.modeled'
version '0.1.0-SNAPSHOT'

java {
    sourceCompatibility = 17
    targetCompatibility = 17
}


repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    gradleApi()
    localGroovy()

    api libs.streamex

    implementation libs.handlebars
    implementation libs.javapoet
    implementation libs.throwing.function

    annotationProcessor libs.auto.service
    implementation libs.auto.service

    annotationProcessor libs.lombok
    compileOnly libs.lombok
}


import com.github.benmanes.gradle.versions.reporter.PlainTextReporter

dependencyUpdates {
    outputFormatter { /** Combining custom with default output was adapted from:
            https://github.com/ben-manes/gradle-versions-plugin/issues/566#issuecomment-961929993
        */
        new PlainTextReporter(project, revision, gradleReleaseChannel).write System.out, it

        final outdated = it.outdated.dependencies.findAll { !(it.name.startsWith 'spock-') }
        if (outdated != it.outdated.dependencies) {
            println "\nIgnoring outdated Spock dependencies."
        }

        if (outdated) {
            throw new RuntimeException("Outdated dependencies: ${outdated.collect { it.name }}")
        }
    }
}


publishing {
    publications {
        maven MavenPublication, {
            from components.java
        }
    }
}