cv/flake.nix at main · midzdotdev/cv · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
{
  description = "James Middleton's CV";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { nixpkgs, ... }:
  let
    forAllSystems = f: nixpkgs.lib.genAttrs [
      "aarch64-darwin"
      "x86_64-linux"
      "aarch64-linux"
    ] (system: f nixpkgs.legacyPackages.${system});

    texlive = pkgs: pkgs.texlive.combine {
      inherit (pkgs.texlive)
        scheme-basic
        latexmk
        charter
        enumitem
        titlesec
        needspace
        changepage
        fancyhdr
        bookmark
        xcolor
        iftex
        ;
    };
  in
  {
    apps = forAllSystems (pkgs: {
      format = {
        type = "app";
        program = toString (pkgs.writeShellScript "format-tex" ''
          ${pkgs.findutils}/bin/find . -name '*.tex' -not -path './.git/*' -exec ${pkgs.tex-fmt}/bin/tex-fmt {} +
        '');
      };
    });

    devShells = forAllSystems (pkgs: {
      default = pkgs.mkShell {
        packages = [
          (texlive pkgs)
          pkgs.tex-fmt
        ];
        shellHook = ''
          if [ -d .git ]; then
            mkdir -p .git/hooks
            cat > .git/hooks/pre-commit << 'HOOK'
          #!/usr/bin/env bash
          staged_tex=$(git diff --cached --name-only --diff-filter=ACM | grep '\.tex$')
          if [ -z "$staged_tex" ]; then
            exit 0
          fi
          for file in $staged_tex; do
            tex-fmt "$file"
            git add "$file"
          done
          HOOK
            chmod +x .git/hooks/pre-commit
          fi
        '';
      };
    });
  };
}