[Event Request] - codeunit 9200 "Matrix Management" - Add integration events for custom rounding

[michalone]

Why do you need this change?

Many of our customers wonder why, when they select the "1,000" rounding option in analyses and financial reports, the amounts still include a decimal place. They want the amounts to be rounded to whole numbers.

Describe the request

Add integration event in procedure RoundAmount in Matrix Management codeunit after amount rounding:

procedure RoundAmount(Amount: Decimal; RoundingFactor: Enum "Analysis Rounding Factor"): Decimal
begin
    if Amount = 0 then
        exit(0);

    case RoundingFactor of
        RoundingFactor::"1":
            exit(Round(Amount, 1));
        RoundingFactor::"1000":
            exit(Round(Amount / 1000, 0.1));
        RoundingFactor::"1000000":
            exit(Round(Amount / 1000000, 0.1));
        else
            OnRoundAmountOnElse(Amount, RoundingFactor);
    end;

    // add event here to allow changing Amount based on RoundingFactor - begin
    OnRoundAmountAfterRound(Amount, RoundingFactor);
    // add event here to allow changing Amount based on RoundingFactor - end

    exit(Amount);
end;

Add integration event in procedure FormatRoundingFactor in Matrix Management codeunit after set AmountDecimal:

procedure FormatRoundingFactor(RoundingFactor: Enum "Analysis Rounding Factor"; AddCurrency: Boolean; NegativeAmountFormat: Enum "Analysis Negative Format") Result: Text
var
    AmountDecimal: Text;
begin
    case RoundingFactor of
        RoundingFactor::None:
            AmountDecimal := ReadNormalDecimalFormat(AddCurrency);
        RoundingFactor::"1":
            AmountDecimal := Format(0);
        RoundingFactor::"1000", RoundingFactor::"1000000":
            AmountDecimal := Format(1);
        else
            OnFormatRoundingFactorOnElse(AmountDecimal, RoundingFactor);
    end;

    // add event here to allow changing AmountDecimal based on RoundingFactor - begin
    OnFormatRoundingFactorAfterSetAmountDecimal(RoundingFactor, AmountDecimal);
    // add event here to allow changing AmountDecimal based on RoundingFactor - end

    case NegativeAmountFormat of
        NegativeAmountFormat::"Minus Sign":
            Result := StrSubstNo(RoundingFormatTxt, AmountDecimal, '');
        NegativeAmountFormat::"Parentheses":
            Result := StrSubstNo(RoundingFormatTxt, AmountDecimal, NegativeInParenthesesFormatTxt);
        else
            OnFormatRoundingFactorNegativeFormatOnElse(AmountDecimal, NegativeAmountFormat, Result);
    end;
end;

Events could be like this:

[IntegrationEvent(false, false)]
local procedure OnFormatRoundingFactorAfterSetAmountDecimal(RoundingFactor: Enum "Analysis Rounding Factor"; var AmountDecimal: Text)
begin
end;

[IntegrationEvent(false, false)]
local procedure OnRoundAmountAfterRound(var Amount: Decimal; RoundingFactor: Enum "Analysis Rounding Factor")
begin
end;

[github-actions]

✅ Analysis complete - ready for further processing

---

Implementation:

Add two new integration events in Codeunit 9200 "Matrix Management": one in RoundAmount after the standard rounding result is assigned, and one in FormatRoundingFactor after AmountDecimal is assigned.

Location in RoundAmount() and FormatRoundingFactor() procedures:

procedure RoundAmount(Amount: Decimal; RoundingFactor: Enum "Analysis Rounding Factor"): Decimal
begin
    if Amount = 0 then
        exit(0);

    case RoundingFactor of
        RoundingFactor::"1":
            begin
                Amount := Round(Amount, 1);
                OnRoundAmountOnAfterRound(Amount, RoundingFactor);
            end;
        RoundingFactor::"1000":
            begin
                Amount := Round(Amount / 1000, 0.1);
                OnRoundAmountOnAfterRound(Amount, RoundingFactor);
            end;
        RoundingFactor::"1000000":
            begin
                Amount := Round(Amount / 1000000, 0.1);
                OnRoundAmountOnAfterRound(Amount, RoundingFactor);
            end;
        else
            OnRoundAmountOnElse(Amount, RoundingFactor);
    end;

    exit(Amount);
end;

procedure FormatRoundingFactor(RoundingFactor: Enum "Analysis Rounding Factor"; AddCurrency: Boolean; NegativeAmountFormat: Enum "Analysis Negative Format") Result: Text
var
    AmountDecimal: Text;
begin
    case RoundingFactor of
        RoundingFactor::None:
            begin
                AmountDecimal := ReadNormalDecimalFormat(AddCurrency);
                OnFormatRoundingFactorOnAfterSetAmountDecimal(RoundingFactor, AmountDecimal);
            end;
        RoundingFactor::"1":
            begin
                AmountDecimal := Format(0);
                OnFormatRoundingFactorOnAfterSetAmountDecimal(RoundingFactor, AmountDecimal);
            end;
        RoundingFactor::"1000", RoundingFactor::"1000000":
            begin
                AmountDecimal := Format(1);
                OnFormatRoundingFactorOnAfterSetAmountDecimal(RoundingFactor, AmountDecimal);
            end;
        else
            OnFormatRoundingFactorOnElse(AmountDecimal, RoundingFactor);
    end;

    case NegativeAmountFormat of
        NegativeAmountFormat::"Minus Sign":
            Result := StrSubstNo(RoundingFormatTxt, AmountDecimal, '');
        NegativeAmountFormat::"Parentheses":
            Result := StrSubstNo(RoundingFormatTxt, AmountDecimal, NegativeInParenthesesFormatTxt);
        else
            OnFormatRoundingFactorNegativeFormatOnElse(AmountDecimal, NegativeAmountFormat, Result);
    end;
end;

Event Publisher (add at the end of the codeunit with other events):

[IntegrationEvent(false, false)]
local procedure OnFormatRoundingFactorOnAfterSetAmountDecimal(RoundingFactor: Enum "Analysis Rounding Factor"; var AmountDecimal: Text)
begin
end;

[IntegrationEvent(false, false)]
local procedure OnRoundAmountOnAfterRound(var Amount: Decimal; RoundingFactor: Enum "Analysis Rounding Factor")
begin
end;

---

File: MatrixManagement.Codeunit.al

Note

Automatically generated by the Triage Agent — advisory only. An engineer will review before any action is taken.

Tip

Not accurate? Reply with /not-accurate (optional: add a short explanation). Your feedback improves future responses.