Colloid/CMakeLists.txt at develop · mattparks/Colloid · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
cmake_minimum_required(VERSION 3.11.0 FATAL_ERROR)
project(colloid VERSION 0.1.0 LANGUAGES CXX C)

include(CMakeDependentOption)

option(BUILD_SHARED_LIBS "Build shared libraries" OFF)
set(COLLOID_LIBRARY_TYPE "SHARED" CACHE STRING "Colloid library linking type")
set_property(CACHE COLLOID_LIBRARY_TYPE PROPERTY STRINGS STATIC SHARED)

option(PHYSFS_BUILD "Build PhysFS" ON)
if(EMSCRIPTEN OR IOS OR ANDROID)
    option(GLFM_BUILD "Build GLFM" ON)
    option(GLFW_BUILD "Build GLFW" OFF)
else()
    option(GLFM_BUILD "Build GLFM" OFF)
    option(GLFW_BUILD "Build GLFW" ON)
endif()
option(BX_BUILD "Build BX" ON)
cmake_dependent_option(BIMG_BUILD "Build BIMG" ON "BX_BUILD" OFF)
cmake_dependent_option(BGFX_BUILD "Build BGFX" ON "BX_BUILD;BIMG_BUILD" OFF)
cmake_dependent_option(VG_RENDERER_BUILD "Build vg-renderer" ON "BGFX_BUILD" OFF)
cmake_dependent_option(SIMPLE_SVG_BUILD "Build simple-svg" ON "BX_BUILD" OFF)
option(CANVAS_ITY_BUILD "Build canvas_ity" ON)
option(GOOGLETEST_BUILD "Build Google Test" OFF)

option(COLLOID_BUILD_PDF "Build Colloid PDF" ON)
cmake_dependent_option(COLLOID_BUILD_TESTS "Build Colloid tests" OFF "GOOGLETEST_BUILD" OFF)

# Used to include CMake modules
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_LIST_DIR}/cmake CACHE STRING "")

# Sets the install directories defined by GNU
include(GNUInstallDirs)
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR} CACHE STRING "")
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR} CACHE STRING "")
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR} CACHE STRING "")
# Visual Studio will default to Build/x64-Debug/bin/Debug, this removed the Debug postfix folder
# https://stackoverflow.com/questions/7229571/cmake-visual-studio-debug-folder
foreach(OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
    string(TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG)
    set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_BINARY_DIR}/lib CACHE STRING "")
    set(CMAKE_LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_BINARY_DIR}/lib CACHE STRING "")
    set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${CMAKE_BINARY_DIR}/bin CACHE STRING "")
endforeach()

# Add property to allow making project folders in IDEs
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
# Under some compilers CMAKE_DEBUG_POSTFIX is set to "d", removed to clean dll names
set(CMAKE_DEBUG_POSTFIX "" CACHE STRING "")
set(CMAKE_RELEASE_POSTFIX "" CACHE STRING "")
set(CMAKE_RELWITHDEBINFO_POSTFIX "" CACHE STRING "")
set(CMAKE_MINSIZEREL_POSTFIX "" CACHE STRING "")
if(EMSCRIPTEN)
    set(CMAKE_EXECUTABLE_SUFFIX ".html" CACHE STRING "")
elseif(IOS)
    set(CMAKE_MACOSX_BUNDLE ON CACHE BOOL "")
elseif(WIN32)
    set(CMAKE_SHARED_LIBRARY_PREFIX "" CACHE STRING "")
    set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS ON CACHE BOOL "")
endif()
if(CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows" OR CMAKE_HOST_SYSTEM_NAME MATCHES "MING.*" OR CMAKE_HOST_SYSTEM_NAME MATCHES "MSYS.*")
    set(CMAKE_HOST_EXECUTABLE_SUFFIX .exe)
endif()
set(CMAKE_POSITION_INDEPENDENT_CODE ON CACHE BOOL "")
set(CMAKE_DISABLE_SOURCE_CHANGES ON CACHE BOOL "")
set(CMAKE_DISABLE_IN_SOURCE_BUILD ON CACHE BOOL "")

# Multithreaded MSVC builds
if(MSVC_VERSION GREATER 1500 AND ${CMAKE_VERSION} VERSION_GREATER "2.8.6")
    include(ProcessorCount)
    ProcessorCount(N)
    if(NOT N EQUAL 0)
        set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /MP${N}" CACHE STRING "")
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj /MP${N}" CACHE STRING "")
    endif()
endif()

# Force all compilers to use the correct C and C++ standard versions
# Needed to allow for CheckCXXSourceCompiles to work correctly
#set(CMAKE_REQUIRED_FLAGS "-std=c++17 -std=c11")
set(CMAKE_CXX_STANDARD 17)
#set(CMAKE_CXX_STANDARD_REQUIRED ON)
#set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_C_STANDARD 11)
#set(CMAKE_C_STANDARD_REQUIRED ON)
#set(CMAKE_C_EXTENSIONS OFF)

find_package(Git QUIET)
execute_process(
        COMMAND ${GIT_EXECUTABLE} rev-parse --abbrev-ref HEAD
        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
        OUTPUT_VARIABLE colloid_GIT_BRANCH
        OUTPUT_STRIP_TRAILING_WHITESPACE
        )
execute_process(
        COMMAND ${GIT_EXECUTABLE} log -1 --format=%h
        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
        OUTPUT_VARIABLE colloid_GIT_COMMIT_HASH
        OUTPUT_STRIP_TRAILING_WHITESPACE
        )

add_subdirectory(lib ${CMAKE_CURRENT_BINARY_DIR}/_deps)
add_subdirectory(src)
if(COLLOID_BUILD_TESTS)
    add_subdirectory(test)
endif()