librelane/default.nix at main · martialonso/librelane · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
# Copyright 2025 LibreLane Contributors
#
# Adapted from OpenLane
#
# Copyright 2023 Efabless Corporation
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
{
  flake ? null,
  lib,
  system,
  clangStdenv,
  fetchFromGitHub,
  nix-gitignore,
  # Tools
  klayout,
  libparse,
  magic-vlsi,
  netgen,
  opensta,
  openroad,
  ruby,
  surelog,
  tclFull,
  verilator,
  verilog,
  ciel,
  yosys,
  yosysFull,
  # Python
  buildPythonPackage,
  poetry-core,
  click,
  cloup,
  pyyaml,
  yamlcore,
  rich,
  requests,
  pcpp,
  tkinter,
  lxml,
  deprecated,
  psutil,
  pytestCheckHook,
  pytest-xdist,
  pyfakefs,
  rapidfuzz,
  semver,
}: let
  yosys-env = (yosys.withPythonPackages.override {target = yosysFull;}) (ps:
    with ps; [
      click
    ]);
  openroad-env = openroad.withPythonPackages (ps:
    with ps; [
      click
      rich
      pyyaml
    ]);
  self = buildPythonPackage {
    pname = "librelane";
    version = (builtins.fromTOML (builtins.readFile ./pyproject.toml)).tool.poetry.version;
    format = "pyproject";

    src = if (flake != null) then flake else nix-gitignore.gitignoreSourcePure ./.gitignore ./.;

    nativeBuildInputs = [
      poetry-core
    ];

    includedTools = [
      opensta
      yosys-env
      openroad-env
      klayout
      netgen
      magic-vlsi
      verilog
      verilator
      tclFull
      surelog
      ruby
    ];

    propagatedBuildInputs =
      [
        # Python
        click
        cloup
        pyyaml
        yamlcore
        rich
        requests
        pcpp
        ciel
        tkinter
        lxml
        deprecated
        libparse
        psutil
        klayout.pymod
        rapidfuzz
        semver
      ]
      ++ self.includedTools;

    doCheck = true;
    checkInputs = [pytestCheckHook pytest-xdist pyfakefs];

    computed_PATH = lib.makeBinPath self.propagatedBuildInputs;

    # Make PATH available to LibreLane subprocesses
    makeWrapperArgs = [
      "--prefix PATH : ${self.computed_PATH}"
    ];

    meta = with lib; {
      description = "Hardware design and implementation infrastructure library and ASIC flow";
      homepage = "https://efabless.com/librelane";
      mainProgram = "librelane";
      license = licenses.asl20;
      platforms = platforms.linux ++ platforms.darwin;
    };
  };
in
  self