flakelight-treefmt/flakelight-treefmt.nix at main · m15a/flakelight-treefmt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{
  lib,
  config,
  inputs,
  ...
}:

let
  inherit (builtins) attrValues;
  inherit (lib)
    mkForce
    mkIf
    mkMerge
    mkOption
    ;
  inherit (lib.types)
    bool
    deferredModule
    ;
  inherit (inputs.treefmt-nix.lib) evalModule;

  build = pkgs: (evalModule pkgs config.treefmtConfig).config.build;
  wrapper = pkgs: (build pkgs).wrapper;
in

{
  options = {
    treefmtConfig = mkOption {
      description = "Treefmt configuration module.";
      type = deferredModule;
      default = { };
    };

    treefmtWrapperInDevShell = mkOption {
      description = "Whether to add treefmt wrapper to `devShell.packages`.";
      type = bool;
      default = true;
    };

    treefmtProgramsInDevShell = mkOption {
      description = "Whether to add treefmt programs to `devShell.packages`.";
      type = bool;
      default = true;
    };
  };

  config = mkMerge [
    (mkIf config.treefmtWrapperInDevShell {
      devShell.packages = pkgs: [ (wrapper pkgs) ];
    })
    (mkIf config.treefmtProgramsInDevShell {
      devShell.packages = pkgs: attrValues (build pkgs).programs;
    })
    {
      formatter = mkForce wrapper;
      checks.formatting = mkForce (pkgs: (build pkgs).check inputs.self);
    }
  ];
}