spark_sidecar/flake.nix at main · lnbits/spark_sidecar · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
{
  description = "Spark L2 sidecar (LNbits sidecar)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };
        pname = "lnbits-spark-sidecar";
        version = "0.0.0";

        package = pkgs.buildNpmPackage {
          inherit pname version;
          src = ./.;
          npmDepsHash = "sha256-DsxMBn3ZiAnTEsv97e6f4NLi+Mw5VDi4aQKIA4k80nQ=";

          dontNpmBuild = true;
          dontBuild = true;

          installPhase = ''
            runHook preInstall
            mkdir -p $out/lib/node_modules/${pname}
            cp -r . $out/lib/node_modules/${pname}
            runHook postInstall
          '';
        };

        runSidecar = pkgs.writeShellApplication {
          name = "spark-sidecar";
          runtimeInputs = [ pkgs.nodejs_20 ];
          text = ''
            export NODE_PATH=${package}/lib/node_modules/${pname}/node_modules
            exec ${pkgs.nodejs_20}/bin/node ${package}/lib/node_modules/${pname}/server.mjs
          '';
        };
      in
      {
        packages.default = package;
        apps.default = flake-utils.lib.mkApp { drv = runSidecar; };
        devShells.default = pkgs.mkShell {
          packages = [ pkgs.nodejs_20 pkgs.nodePackages.npm ];
        };
      });
}