main.tf

resource "openstack_networking_floatingip_v2" "external" {
  count = var.total_servers
  pool  = "external"
}

resource "openstack_blockstorage_volume_v3" "storage" {
  count       = var.total_servers
  name        = "storage-plesk-${count.index}"
  volume_type = var.additional_volume_type
  size        = var.additional_volume_size
}

resource "openstack_compute_instance_v2" "plesk" {
  # The amount of instances you want to start
  count = var.total_servers

  name        = "plesk_${count.index}"
  flavor_name = var.vm_flavor
  key_pair    = data.openstack_compute_keypair_v2.keypair.name
  security_groups = [
    openstack_compute_secgroup_v2.ssh.name,
    openstack_compute_secgroup_v2.https.name,
    openstack_compute_secgroup_v2.plesk.name
  ]

  block_device {
    boot_index            = 0
    uuid                  = data.openstack_images_image_v2.ubuntu.id
    source_type           = "image"
    destination_type      = "volume"
    volume_type           = var.boot_volume_type
    volume_size           = var.boot_volume_size
    delete_on_termination = true
  }

  user_data = templatefile("templates/user_data.yaml.tpl", {
    additional_disk_name = "vdb"
  })

  network {
    name = openstack_networking_network_v2.private.name
    # Here we get the value of the count and add 10, 
    # so that each instance gets it's own unique IP
    fixed_ip_v4 = cidrhost(var.default_subnet, 10 + count.index)
  }

  lifecycle {
    # Ignore some changes the will trigger a forced replacement
    ignore_changes = [user_data]
  }
}

resource "openstack_compute_floatingip_associate_v2" "fip" {
  count       = var.total_servers
  floating_ip = openstack_networking_floatingip_v2.external[count.index].address
  instance_id = openstack_compute_instance_v2.plesk[count.index].id
}

resource "openstack_compute_volume_attach_v2" "attached" {
  count       = var.total_servers
  instance_id = openstack_compute_instance_v2.plesk[count.index].id
  volume_id   = openstack_blockstorage_volume_v3.storage[count.index].id
}