windowsWindowTilingManager/windowFilter.ahk at master · jpginc/windowsWindowTilingManager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
class WindowFilterClass
{
	doManageWindowUserOverride := {}
	dontManageWindowUserOverride := {}

	__new()
	{
		this.readSettings()
		return this
	}

	readSettings()
	{
		FileRead, settings, settings/donottrack.txt
		this.doNotTrack := stringToArray(settings)
		return this
	}

	shouldWindowBeManaged(windowObject)
	{
		if(this.dontManageWindowUserOverride[windowObject.hwnd])
		{
			return false
		}
		if(this.doManageWindowUserOverride[windowObject.hwnd])
		{
			return true
		}
		;todo
		return this.checkSettings(windowObject)
	}

	checkSettings(windowObj)
	{
		for key, settingsWindowObj in this.doNotTrack
		{
			if(windowObj.class == settingsWindowObj.class || windowObj.processName == settingsWindowObj.processName)
			{
				return false
			}
		}
		return true
	}

	toggleUserOverride(windowObject)
	{
		if(this.currentlyManagingWindow(windowObject))
		{
			this.stopManagingWindow(windowObject)
		} else
		{
			this.startManagingWindow(windowObject)
		}
		return this
	}

	currentlyManagingWindow(windowObject)
	{
		return this.doManageWindowUserOverride[windowObject.hwnd]
	}

	stopManagingWindow(windowObject)
	{
		this.doManageWindowUserOverride.delete(windowObject.hwnd)
		this.dontManageWindowUserOverride[windowObject.hwnd] := windowObject
		return this
	}

	startManagingWindow(windowObject)
	{
		this.dontManageWindowUserOverride.delete(windowObject.hwnd)
		this.doManageWindowUserOverride[windowObject.hwnd] := windowObject
		return this
	}
}