CommonFunctions.au3

#include-once
;===============================================================================
; Common functions used in my scripts
; https://github.com/jmclaren7/autoit-scripts/blob/master/CommonFunctions.au3
;===============================================================================
; If these files have already been included using a custom path, you may need to remove them here
#include <Array.au3>
#include <AutoItConstants.au3>
#include <Date.au3>
#include <File.au3>
#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiListBox.au3>
#include <GuiListView.au3>
#include <String.au3>
#include <WinAPIFiles.au3>
#include <WinAPIProc.au3>
#include <WinAPIShPath.au3>
#include <WinAPISysWin.au3>
#include <WindowsConstants.au3>
;===============================================================================
; Function Name:    _GUICtrlListView_GetCheckedText
; Description:		Gets the text of all checked items in a ListView control
; Call With:		_GUICtrlListView_GetCheckedText($hListView)
; Parameter(s): 	$hListView - Handle of the ListView control
; Return Value(s):  On Success - Array of checked item texts (first element is the count)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		03/8/2026  --  v1.0
;===============================================================================
Func _GUICtrlListView_GetCheckedText($hListView)
	Local $aSelected[1] = [0]

	For $i = 0 To _GUICtrlListView_GetItemCount($hListView) - 1
		If _GUICtrlListView_GetItemChecked($hListView, $i) Then
			Local $pkgName = _GUICtrlListView_GetItemText($hListView, $i)
			_ArrayAdd($aSelected, $pkgName)
			$aSelected[0] += 1
		EndIf
	Next

	Return $aSelected
EndFunc   ;==>_GUICtrlListView_GetCheckedText

;===============================================================================
; Function Name:    _ControlGetFocus
; Description:		Gets the control ID of the focused control in a GUI
; Call With:		_ControlGetFocus($hGUI)
; Parameter(s): 	$hGUI - title/hWnd/class  of the GUI to check
; Return Value(s):  On Success - Control ID of the focused control
; 					On Failure - 0, @error set:
;						2 - No control has focus
;						3 - Could not get control handle
;						4 - Could not get control ID
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		03/7/2026  --  v1.0
;===============================================================================
Func _ControlGetFocus($hGUI)
	Local $sFocus = ControlGetFocus($hGUI)
	If $sFocus = "" Then Return SetError(2, 0, 0)

	Local $hFocus = ControlGetHandle($hGUI, "", $sFocus)
	If Not IsHWnd($hFocus) Then Return SetError(3, 0, 0)

	Local $iCtrlID = _WinAPI_GetDlgCtrlID($hFocus)
	If $iCtrlID = 0 Then Return SetError(4, 0, 0)

	Return $iCtrlID
EndFunc   ;==>_ControlGetFocus

;===============================================================================
; Function Name:    _FileGetVersion
; Description:		Gets a version segment from a file's version string
; Call With:		_FileGetVersion([$File = Default[, $Segment = Default]])
; Parameter(s): 	$File - [optional] Path to the file (default is the script's path)
;					$Segment - [optional] Segment of the version to return (1 = Major, 2 = Minor, etc. - default is last segment)
; Return Value(s):  On Success - Version segment as a string
; 					On Failure - "" (Error code in @error)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		02/24/2026  --  v1.1
;===============================================================================
Func _FileGetVersion($File = Default, $Segment = Default)
	If $File = Default Then $File = @ScriptFullPath

	Local $Version = FileGetVersion($File)
	If @error Then Return SetError(1, 0, "")

	Local $aVersion = StringSplit($Version, ".")
	If @error Then Return SetError(2, 0, $Version)

	If $Segment = Default Then $Segment = $aVersion[0]
	If $Segment < 1 Or $Segment > $aVersion[0] Then Return SetError(3, 0, "")

	Return $aVersion[$Segment]

EndFunc   ;==>_FileGetVersion
;===============================================================================
; Function Name:    _FileSigned
; Description:		Verifies a file's digital signature
; Call With:		_FileSigned($File)
; Parameter(s): 	$File - Path to the file to verify
; Return Value(s):  On Success - Array containing the status, subject, and thumbprint
; 					On Failure - 0 (Error code in @error)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		11/02/2025  --  v1.0
;===============================================================================
Func _FileSigned($File = Default)
	If IsObj($File) And IsInt($File.scriptline) Then
		Return SetError(1, $File.scriptline, 0)
	ElseIf $File = Default Or $File = "" Then
		Return SetError(2, 0, 0)
	ElseIf Not FileExists($File) Then
		Return SetError(3, 0, 0)
	EndIf

	Local $Run = "powershell.exe -nologo -noprofile -command (Get-AuthenticodeSignature -FilePath '" & $File & "') | Select Status,{$_.SignerCertificate.Subject},{$_.SignerCertificate.Thumbprint} | ConvertTo-XML -As String -NoTypeInformation"
	Local $Result = _RunWait($Run)
	;_Log($Result)

	Local $oErrorHandler = ObjEvent("AutoIt.Error", "_FileSigned")

	Local $oXML = ObjCreate("Microsoft.XMLDOM")
	If @error Then
		Return SetError(4, 0, 0)
	EndIf

	$oXML.loadXML($Result)
	If $oXML.parseError.errorCode <> 0 Then
		;"XML Parse Error? Check this: $oXML.parseError.reason
		Return SetError(5, 0, 0)
	EndIf
	;_Log($oXML.xml)

	Local $aResult[3]
	$aResult[0] = $oXML.selectSingleNode("/Objects/Object/Property[@Name='Status']").text
	$aResult[1] = $oXML.selectSingleNode("/Objects/Object/Property[@Name='$_.SignerCertificate.Subject']").text
	$aResult[2] = $oXML.selectSingleNode("/Objects/Object/Property[@Name='$_.SignerCertificate.Thumbprint']").text


	If $aResult[0] = "Valid" Then
		Return SetError(0, 0, $aResult)
	Else
		Return SetError(6, 0, 0)
	EndIf
EndFunc   ;==>_FileSigned
;===============================================================================
; Function Name:    _HideDrive
; Description:		Hide or show a drive from file explorer
; Call With:		_HideDrive($DriveLetter, $Hide = True)
; Parameter(s): 	$DriveLetter - Drive letter to hide or show
;					$Hide - [optional] True to hide, False to show
; Return Value(s):  None
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		11/02/2025  --  v1.0
;===============================================================================
Func _HideDrive($DriveLetter, $Hide = Default)
	If $Hide = Default Then $Hide = True

	Local $DriveNumber = Asc(StringUpper($DriveLetter)) - Asc("A")
	Local $DriveBit = BitShift(1, -$DriveNumber)

	; Get the current value of the NoDrives registry key
	Local $CurrentMask = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer", "NoDrives")
	If @error Then $CurrentMask = 0

	; Check if the drive is already in the desired state
	Local $IsHidden = BitAND($CurrentMask, $DriveBit) <> 0
	If ($Hide And $IsHidden) Or (Not $Hide And Not $IsHidden) Then
		_Log("Drive " & $DriveLetter & ": is already " & ($Hide ? "hidden" : "visible") & ".")
		Return
	EndIf

	; Calculate the new value based on if we should hide or show the drive
	Local $NewMask
	If $Hide Then
		$NewMask = BitOR($CurrentMask, $DriveBit)
	Else
		$NewMask = BitAND($CurrentMask, BitNOT($DriveBit))
	EndIf

	; Write the new value to the registry
	Local $RegWrite = RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer", "NoDrives", "REG_DWORD", $NewMask)
	If @error Then
		_Log("Error: Could not hide drive " & $DriveLetter & ": in Explorer. Mask: " & $NewMask & " Error: " & @error & " Result: " & $RegWrite)
	Else
		_Log("Success: " & ($Hide ? "Hid" : "Unhid") & " drive " & $DriveLetter & ": in Explorer.")
	EndIf
EndFunc   ;==>_HideDrive
;===============================================================================
; Function Name:    _TextBox
; Description:		Creates a text box with a label and OK/Cancel buttons
; Call With:		_TextBox($Title, $Label, $Text = "", $Width = Default, $Height = Default, $Left = Default, $Top = Default, $Timeout = 0, $HWND = Default)
; Parameter(s): 	$Title - Title of the GUI
;					$Label - Label of the text box
;					$Text - Text to display in the text box
;					$Width - Width of the GUI
;					$Height - Height of the GUI
;					$Left - Left position of the GUI
;					$Top - Top position of the GUI
;					$Timeout - Timeout in seconds
;					$HWND - Handle of the parent window
; Return Value(s):  On Success - Text from the text box
; 					On Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		11/01/2025  --  v1.0
;===============================================================================
Func _TextBox($Title, $Label, $Text = "", $Width = Default, $Height = Default, $Left = Default, $Top = Default, $Timeout = 0, $HWND = Default)
	If $Width = Default Then $Width = 300
	If $Height = Default Then $Height = 200
	If $Left = Default Then $Left = -1
	If $Top = Default Then $Top = -1
	If $Timeout = Default Then $Timeout = 0

	Local $hGUI = GUICreate($Title, $Width, $Height, $Left, $Top, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX, $WS_THICKFRAME), Default, $HWND)
	Local $hLabel = GUICtrlCreateLabel($Label, 10, 10)
	GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP + $GUI_DOCKSIZE)
	Local $hEdit = GUICtrlCreateEdit($Text, 10, 30, $Width - 20, $Height - 70, BitOR($ES_MULTILINE, $ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL))
	GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
	Local $hOK = GUICtrlCreateButton("OK", $Width - 170, $Height - 32, 75, 25)
	GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM + $GUI_DOCKSIZE)
	Local $hCancel = GUICtrlCreateButton("Cancel", $Width - 85, $Height - 32, 75, 25)
	GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKBOTTOM + $GUI_DOCKSIZE)
	GUICtrlSetCursor($hEdit, -1)
	GUISetState(@SW_SHOW)
	ControlSend($hGUI, "", $hEdit, "{LEFT}")
	While 1
		Local $GUIEvent = GUIGetMsg()
		Switch $GUIEvent
			Case $GUI_EVENT_CLOSE, $hCancel
				GUIDelete($hGUI)
				Return SetError(1, 0, 0)
			Case $hOK
				Local $ReturnText = GUICtrlRead($hEdit)
				GUIDelete($hGUI)
				Return SetError(0, 0, $ReturnText)
		EndSwitch
		Sleep(10)
	WEnd
EndFunc   ;==>_TextBox
;===============================================================================
; Function Name:    _Error
; Description:		Call _log and MsgBox in one command
; Call With:			_Error($Title, $Message[, $iLevel = Default[, $MessageEx = ""]])
; Parameter(s):		$Title - Window title
;					$Message - Message for MsgBox and _Log.
;					$iLevel - [optional]
;					$MessageEx - [optional] an extra message that will only show in the log.
; Return Value(s):  MsgBox return value
; Author(s):        JohnMC - JohnsCS.com
;===============================================================================
Func _Error($Title, $Message, $iLevel = Default, $MessageEx = "")
	If $MessageEx <> "" Then $MessageEx = " - " & $MessageEx
	_Log($Message & $MessageEx, $iLevel)
	Return MsgBox(16, $Title, $Message)
EndFunc   ;==>_Error

;===============================================================================
; Function Name:    _RandomString
; Description:		Generates a random string of characters (numbers and letters by default)
; Call With:			_RandomString($Min, $Max[, $Chars = Default])
; Parameter(s):		$Min - Minimum string length
;					$Max - Maximum string length
;					$Chars - [optional] String of characters to choose from. Default is all numbers and letters (upper and lower)
; Return Value(s):  A random string of characters
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		5/11/2024  --  v1.0
;===============================================================================
Func _RandomString($iMin, $iMax, $sChars = Default)
	If $sChars = Default Then $sChars = '0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ'
	Local $sReturn, $aChars = StringSplit($sChars, '')

	For $i = 1 To Random($iMin, $iMax, 1)
		$sReturn &= $aChars[Random(1, $aChars[0], 1)]
	Next

	Return $sReturn
EndFunc   ;==>_RandomString

;===============================================================================
; Function Name:    _ListSelect
; Description:		Creates a list select box
; Call With:			_ListSelect($aList[, $sTitle[, $sMessage[, $iDefaultIndex[, $sIcon[, $iWidth[, $iHeight]]]]]])
; Parameter(s):		$aList - Array of items to display
;					$sTitle - [optional] Window title
;					$sMessage - [optional] Label text
;					$iDefaultIndex - [optional] Default selected index (default 1)
;					$sIcon - [optional] Icon file and ID (e.g. "shell32.dll,1")
;					$iWidth - [optional] Window width (default 400)
;					$iHeight - [optional] Window height (default 175)
; Return Value(s):  The text of the selected item, @extended contains the index of the selected item
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		04/24/2024
;===============================================================================
Func _ListSelect($aList, $sTitle = "", $sMessage = "", $iDefaultIndex = 1, $sIcon = "", $iWidth = 400, $iHieght = 175)
	Local $IconFile = StringLeft($sIcon, StringInStr($sIcon, ",", 0, -1) - 1)
	Local $IconID = Number(StringTrimLeft($sIcon, StringInStr($sIcon, ",", 0, -1)))

	Local $ListSelectGUI = GUICreate($sTitle, $iWidth, $iHieght, -1, -1)
	Local $ListSelectList1 = GUICtrlCreateList("", 70, 48, $iWidth - 90, $iHieght - 90, -1, 0)
	Local $ListSelectIcon1 = GUICtrlCreateIcon($IconFile, $IconID, 20, 64, 32, 32)
	Local $ListSelectLabel1 = GUICtrlCreateLabel($sMessage, 20, 10, $iWidth - 50, 30)
	Local $ListSelectCancel = GUICtrlCreateButton("Cancel", 304, 140, 75, 25)
	Local $ListSelectOK = GUICtrlCreateButton("OK", 216, 140, 75, 25)
	GUISetIcon($IconFile, $IconID)
	GUISetState(@SW_SHOW)

	For $i = UBound($aList) - 1 To 1 Step -1
		GUICtrlSetData($ListSelectList1, $aList[$i])
	Next
	_GUICtrlListBox_SelectString($ListSelectList1, $aList[$iDefaultIndex])

	Local $ListSelectGUIMsg
	While 1
		$ListSelectGUIMsg = GUIGetMsg()
		Switch $ListSelectGUIMsg
			Case $GUI_EVENT_CLOSE, $ListSelectCancel
				GUIDelete($ListSelectGUI)
				Return SetError(1, 0, 0)

			Case $ListSelectOK
				Local $ReturnIndex = _GUICtrlListBox_GetCurSel($ListSelectList1)
				Local $ReturnText = _GUICtrlListBox_GetText($ListSelectList1, $ReturnIndex)
				GUIDelete($ListSelectGUI)

				Return SetError(0, $ReturnIndex, $ReturnText)
		EndSwitch
		Sleep(10)
	WEnd
EndFunc   ;==>_ListSelect

;===============================================================================
; Function Name:    _Timer
; Description:		Creates a quick to use timer
; Call With:			_Timer([$Reset = True])
; Parameter(s):		$Reset - [optional] If True, time will reset
; Return Value(s):  The time in miliseconds since last reset or init
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		03/14/2024  --  v1.0
;===============================================================================
Func _Timer($Reset = True)
	If Not IsDeclared("_Timer_Handle") Then
		Global $_Timer_Handle
		$_Timer_Handle = TimerInit()
		Return True
	EndIf
	Local $Return = Round(TimerDiff($_Timer_Handle), 1)
	If $Reset Then $_Timer_Handle = TimerInit()
	Return $Return
EndFunc   ;==>_Timer

;===============================================================================
; Function Name:    _GetVisibleWindows
; Description:		Get an array of information for visible windows
; Call With:			_GetVisibleWindows([$GetText = False])
; Parameter(s):		$GetText - [optional] True/False - Get window text (slow)
; Return Value(s):  2D Array of windows and window information
;					[0][0] contains the number of windows
; Author(s):        JohnMC - JohnsCS.com, based on AdamUL's _GetVisibleWindows
; Date/Version:		03/29/2024  --  v2.1
;===============================================================================
Func _GetVisibleWindows($GetText = False)
	Local $NewCol, $TotalTime, $Timer

	Local $TotalTime = TimerInit()

	; 0,1 Retrieve a list of windows
	Local $aWinList = WinList()
	If Not IsArray($aWinList) Then Return SetError(0, 0, 0)
	$aWinList[0][1] = "WinHandle"

	; Resize Array
	ReDim $aWinList[UBound($aWinList) + 1][14 + 1]

	; 2 Add window states
	$NewCol = 2
	$aWinList[0][$NewCol] = "State"
	For $i = 1 To $aWinList[0][0]
		$aWinList[$i][$NewCol] = WinGetState($aWinList[$i][1])
	Next

	; 3 Add state descriptions
	Local $WindowStateIndex = 2
	$NewCol = 3
	$aWinList[0][$NewCol] = "StateDesc"
	For $i = 1 To $aWinList[0][0]
		Local $Desc = ""
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_EXISTS) Then $Desc &= "Exists"
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_VISIBLE) Then $Desc &= "Visible"
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_ENABLED) Then $Desc &= "Enabled"
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_ACTIVE) Then $Desc &= "Active"
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_MINIMIZED) Then $Desc &= "Minimized"
		If BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_MAXIMIZED) Then $Desc &= "Maximized"

		$aWinList[$i][$NewCol] = $Desc
	Next

	; Delete undesirable windows
	Local $WindowStateIndex = 2
	Local $aNewWinList[0][UBound($aWinList, 2)]
	Local $NewIndex = 0
	For $i = 0 To $aWinList[0][0]
		If $i <> 0 And ($aWinList[$i][0] = "" Or Not BitAND($aWinList[$i][$WindowStateIndex], $WIN_STATE_VISIBLE)) Then ContinueLoop
		ReDim $aNewWinList[$NewIndex + 1][UBound($aWinList, 2)]
		For $b = 0 To UBound($aWinList, 2) - 1
			$aNewWinList[$NewIndex][$b] = $aWinList[$i][$b]
		Next
		$NewIndex += 1
	Next
	$aNewWinList[0][0] = UBound($aNewWinList) - 1
	$aWinList = $aNewWinList

	; 4 Get Process ID (PID) and add to the array.
	$NewCol = 4
	$aWinList[0][$NewCol] = "PID"
	For $i = 1 To $aWinList[0][0]
		$aWinList[$i][$NewCol] = WinGetProcess($aWinList[$i][1])
	Next

	; 5 Add process name
	Local $PIDIndex = 4
	$NewCol = 5
	$aWinList[0][$NewCol] = "Name"
	Local $aProcessList = ProcessList()
	For $i = 1 To $aWinList[0][0]
		For $b = 1 To UBound($aProcessList) - 1
			If $aProcessList[$b][1] = $aWinList[$i][$PIDIndex] Then
				$aWinList[$i][$NewCol] = $aProcessList[$b][0]
			EndIf
		Next
	Next

	; 6 Add path using winapi method
	$NewCol = 6
	$aWinList[0][$NewCol] = "Path"
	For $i = 1 To $aWinList[0][0]
		Local $Path = _WinAPI_GetProcessFileName($aWinList[$i][4])
		; No path might mean the process is elevated so let's try some other things...
		If $Path = "" Then
			; Might only help if the stars align
			Local $aEnum = _WinAPI_EnumProcessModules($aWinList[$i][4])
			If Not @error And UBound($aEnum) >= 2 Then
				$TestPath = $aEnum[1]
				; The exe might be in the system folder (elevated cmd or task manager)
			Else
				$TestPath = @SystemDir & "\" & $aWinList[$i][5]
			EndIf

			$TestFileAttrib = FileGetAttrib($TestPath)
			If Not @error And Not StringInStr($TestFileAttrib, "D") Then $Path = $TestPath
		EndIf
		$aWinList[$i][$NewCol] = $Path

	Next

	; 7 Add command line string
	$NewCol = 7
	$aWinList[0][$NewCol] = "Command"
	For $i = 1 To $aWinList[0][0]
		$aWinList[$i][$NewCol] = _WinAPI_GetProcessCommandLine($aWinList[$i][4])
	Next

	; 8 Add window position and size
	;   -3200,-3200 is minimized window
	;   -8,-8 is maximized window on 1st display, and x,-8 is maximized window on the nth display were x is the nth display width plus -8 (W + -8).
	$NewCol = 8
	$aWinList[0][$NewCol] = "Position"
	For $i = 1 To $aWinList[0][0]
		Local $aWinPosSize = WinGetPos($aWinList[$i][1])
		If Not @error Then
			$aWinList[$i][$NewCol] = $aWinPosSize[0] & "," & $aWinPosSize[1] & "," & $aWinPosSize[2] & "," & $aWinPosSize[3]
		EndIf
	Next

	; 9,10 Add window style and exstyle
	$NewCol = 9
	$aWinList[0][$NewCol] = "Style"
	$NewCol2 = 10
	$aWinList[0][$NewCol2] = "ExStyle"

	For $i = 1 To $aWinList[0][0]
		Local $tWINDOWINFO = _WinAPI_GetWindowInfo($aWinList[$i][1])
		$aWinList[$i][$NewCol] = DllStructGetData($tWINDOWINFO, 'Style', 1)
		$aWinList[$i][$NewCol2] = DllStructGetData($tWINDOWINFO, 'ExStyle', 1)
	Next

	; 11 Add style descriptions
	Local $StyleIndex = 9
	$NewCol = 11
	$aWinList[0][$NewCol] = "StyleDesc"
	For $i = 1 To $aWinList[0][0]
		Local $Desc = ""
		If BitAND($aWinList[$i][$StyleIndex], $WS_BORDER) Then $Desc &= "Border"
		If BitAND($aWinList[$i][$StyleIndex], $WS_POPUP) Then $Desc &= "Popup"
		If BitAND($aWinList[$i][$StyleIndex], $WS_SYSMENU) Then $Desc &= "Sysmenu"
		If BitAND($aWinList[$i][$StyleIndex], $WS_GROUP) Then $Desc &= "Group"
		If BitAND($aWinList[$i][$StyleIndex], $WS_SIZEBOX) Then $Desc &= "Sizebox"
		If BitAND($aWinList[$i][$StyleIndex], $WS_CHILD) Then $Desc &= "Child"
		If BitAND($aWinList[$i][$StyleIndex], $WS_DLGFRAME) Then $Desc &= "Dialog"
		If BitAND($aWinList[$i][$StyleIndex], $WS_MINIMIZEBOX) Then $Desc &= "Minbox"
		If BitAND($aWinList[$i][$StyleIndex], $WS_MAXIMIZEBOX) Then $Desc &= "Maxbox"
		If BitAND($aWinList[$i][$StyleIndex], $WS_CAPTION) Then $Desc &= "Caption"
		If BitAND($aWinList[$i][$StyleIndex], $WS_CLIPCHILDREN) Then $Desc &= "Clipchildren"
		If BitAND($aWinList[$i][$StyleIndex], $WS_CLIPSIBLINGS) Then $Desc &= "Clipsiblings"
		If BitAND($aWinList[$i][$StyleIndex], $WS_DISABLED) Then $Desc &= "Disabled"
		If BitAND($aWinList[$i][$StyleIndex], $WS_HSCROLL) Then $Desc &= "Hscroll"
		If BitAND($aWinList[$i][$StyleIndex], $WS_MAXIMIZE) Then $Desc &= "Maximize"
		If BitAND($aWinList[$i][$StyleIndex], $WS_OVERLAPPEDWINDOW) Then $Desc &= "Overlappedwindow"
		If BitAND($aWinList[$i][$StyleIndex], $WS_POPUPWINDOW) Then $Desc &= "Popupwindow"
		If BitAND($aWinList[$i][$StyleIndex], $DS_MODALFRAME) Then $Desc &= "Modalframe"
		If BitAND($aWinList[$i][$StyleIndex], $DS_SETFOREGROUND) Then $Desc &= "Setforeground"
		If BitAND($aWinList[$i][$StyleIndex], $WS_TABSTOP) Then $Desc &= "Tabstop"
		$aWinList[$i][$NewCol] = $Desc
	Next

	; 12 Add ExStyle descriptions
	Local $ExStyleIndex = 10
	$NewCol = 12
	$aWinList[0][$NewCol] = "ExStyleDesc"
	For $i = 1 To $aWinList[0][0]
		Local $Desc = ""
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_TOOLWINDOW) Then $Desc &= "Tool"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_TOPMOST) Then $Desc &= "Top"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_CONTROLPARENT) Then $Desc &= "Parent"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_APPWINDOW) Then $Desc &= "App"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_MDICHILD) Then $Desc &= "Child"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_DLGMODALFRAME) Then $Desc &= "Dialogframe"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_ACCEPTFILES) Then $Desc &= "Acceptfiles"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_CLIENTEDGE) Then $Desc &= "Clientedge"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_COMPOSITED) Then $Desc &= "Composited"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_LAYERED) Then $Desc &= "Layered"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_WINDOWEDGE) Then $Desc &= "Windowedge"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_STATICEDGE) Then $Desc &= "Staticedge"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_PALETTEWINDOW) Then $Desc &= "Palettewindow"
		If BitAND($aWinList[$i][$ExStyleIndex], $WS_EX_NOACTIVATE) Then $Desc &= "Noactivate"
		$aWinList[$i][$NewCol] = $Desc
	Next

	; 13 Get Arch
	$NewCol = 13
	$aWinList[0][$NewCol] = "Arch"
	For $i = 1 To $aWinList[0][0]
		Local $sArch
		If _WinAPI_GetBinaryType($aWinList[$i][6]) = 1 Then
			Switch @extended
				Case $SCS_32BIT_BINARY
					$sArch = "32-bit"
				Case $SCS_64BIT_BINARY
					$sArch = "64-bit"
				Case $SCS_DOS_BINARY
					$sArch = "DOS"
				Case $SCS_WOW_BINARY
					$sArch = "16-bit"
			EndSwitch
		EndIf
		$aWinList[$i][$NewCol] = $sArch
	Next

	; 14 Get Window's text and add to the array.
	$NewCol = 14
	$aWinList[0][$NewCol] = "Text"
	If $GetText Then
		Local $WinDetectHiddenText = Opt("WinDetectHiddenText")
		Opt("WinDetectHiddenText", 1)
		For $i = 1 To $aWinList[0][0]
			$aWinList[$i][$NewCol] = WinGetText($aWinList[$i][1])
		Next
		Opt("WinDetectHiddenText", $WinDetectHiddenText)
	EndIf


	Return SetError(0, TimerDiff($TotalTime), $aWinList)
EndFunc   ;==>_GetVisibleWindows

;===============================================================================
; Function Name:    IsActivated
; Description:		Check Windows activation status
; Call With:			IsActivated()
; Parameter(s):		None
; Return Value(s):  A string with the activation status
;					@error will be true if activation status could not be retrieved
;					@extended will be 0 for activated and >0 for not activated
; Author(s):        AutoIT Forum, modified by JohnMC - JohnsCS.com
; Date/Version:		03/02/2024  --  v1.1
;===============================================================================
Func IsActivated()
	$oWMIService = ObjGet("winmgmts:\\.\root\cimv2")
	If Not IsObj($oWMIService) Then Return SetError(1, 0, "WMI Object Error")

	$oCollection = $oWMIService.ExecQuery("SELECT Description, LicenseStatus, GracePeriodRemaining FROM SoftwareLicensingProduct WHERE PartialProductKey <> null")
	If Not IsObj($oCollection) Then Return SetError(2, 0, "WMI Query Error")

	For $oItem In $oCollection
		Switch $oItem.LicenseStatus
			Case 0
				Return SetError(0, 1, "Unlicensed")

			Case 1
				If $oItem.GracePeriodRemaining Then
					If StringInStr($oItem.Description, "TIMEBASED_") Then
						Return SetError(0, 0, "Timebased activation will expire in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

					Else
						Return SetError(0, 0, "Volume activation will expire in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

					EndIf
				Else
					Return SetError(0, 0, "The machine is permanently activated.")

				EndIf

			Case 2
				Return SetError(0, 2, "Initial grace period ends in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

			Case 3
				Return SetError(0, 3, "Additional grace period ends in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

			Case 4
				Return SetError(0, 4, "Non-genuine grace period ends in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

			Case 5
				Return SetError(0, 5, "Windows is in Notification mode")

			Case 6
				Return SetError(0, 6, "Extended grace period ends in " & Round($oItem.GracePeriodRemaining / 60 / 24, 1) & " days")

			Case Else
				Return SetError(4, 7, "Unknown Status Code")

		EndSwitch
	Next

	Return SetError(3, 0, "Unknown Error")
EndFunc   ;==>IsActivated

;===============================================================================
; Function Name:    _FileModifiedAge
; Description:		Get the age of a file based on its last modified time
; Call With:			_FileModifiedAge($sFile)
; Parameter(s):		$sFile - Path to a file
; Return Value(s):  File age in miliseconds
; Author(s):        AutoIT Forum, modified by JohnMC - JohnsCS.com
; Date/Version:		11/15/2023  --  v1.1
;===============================================================================
Func _FileModifiedAge($sFile)
	Local $hFile = _WinAPI_CreateFile($sFile, 2, 2)
	If $hFile = 0 Then
		Return SetError(1, 0, -1)
	Else
		Local $tFileTime = _Date_Time_GetFileTime($hFile)
		Local $aFileTime = _Date_Time_FileTimeToArray($tFileTime[2])
		Local $sFileTime = _Date_Time_FileTimeToStr($tFileTime[2], 1)

		_WinAPI_CloseHandle($hFile)

		Local $tSystemTime = _Date_Time_GetSystemTime()
		Local $sSystemTime = _Date_Time_SystemTimeToDateTimeStr($tSystemTime, 1)
		Local $aSystemTime = _Date_Time_SystemTimeToArray($tSystemTime)

		Local $iFileAge = _DateDiff('s', $sFileTime, $sSystemTime) * 1000 + $aSystemTime[6] - $aFileTime[6]

		Return $iFileAge
	EndIf
EndFunc   ;==>_FileModifiedAge

;===============================================================================
; Function Name:    _WMI
; Description:		Run a WMI query with the option of returning the first object (default) or all objects
; Call With:			_WMI($Query[, $Single = True])
; Parameter(s):		$Query - WMI query string
;					$Single - [optional] Return the first object, Default is True.
; Return Value(s):  Object(s)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		11/15/2023  --  v1.1
;===============================================================================
Func _WMI($Query, $Single = True)
	If Not IsDeclared("_objWMIService") Then
		Local $Object = ObjGet("winmgmts:\\.\root\CIMV2")
		If @error Or Not IsObj($Object) Then Return SetError(1, 0, 0)
		Global $_objWMIService = $Object
	EndIf

	Local $colItems = $_objWMIService.ExecQuery($Query)
	If @error Or Not IsObj($colItems) Then Return SetError(2, 0, 0)

	If $Single Then
		Local $objItem

		For $objItem In $colItems
			Return $objItem
		Next

	Else
		Return $colItems

	EndIf

EndFunc   ;==>_WMI

;===============================================================================
; Function Name:    _INetSmtpMailCom
; Description:		Send an email using a Windows API with authentication and encryption
; Call With:			_INetSmtpMailCom($sSMTPServer, $sFromName, $sFromAddress, $sToAddress[, ...])
; Parameter(s):		$sSMTPServer - SMTP server address
;					$sFromName - Sender display name
;					$sFromAddress - Sender email address
;					$sToAddress - Recipient email address
;					$sSubject - [optional] Email subject
;					$sBody - [optional] Email body
;					$sUsername - [optional] SMTP username
;					$sPassword - [optional] SMTP password
;					$sCCAddress - [optional] CC address
;					$sBCCAddress - [optional] BCC address
;					$iPort - [optional] Port, default 587
;					$bSSL - [optional] Use SSL, default False
;					$bTLS - [optional] Use TLS, default True
; Return Value(s):  None
; Author(s):        AutoIT Forum, modified by JohnMC - JohnsCS.com
; Date/Version:		11/15/2023  --  v1.1
;===============================================================================
Func _INetSmtpMailCom($sSMTPServer, $sFromName, $sFromAddress, $sToAddress, $sSubject = "", $sBody = "", $sUsername = "", $sPassword = "", $sCCAddress = "", $sBCCAddress = "", $iPort = 587, $bSSL = False, $bTLS = True)
	Local $oMail = ObjCreate("CDO.Message")

	$oMail.From = '"' & $sFromName & '" <' & $sFromAddress & '>'
	$oMail.To = $sToAddress
	$oMail.Subject = $sSubject

	If $sCCAddress Then $oMail.Cc = $sCCAddress
	If $sBCCAddress Then $oMail.Bcc = $sBCCAddress

	If StringInStr($sBody, "<") And StringInStr($sBody, ">") Then
		$oMail.HTMLBody = $sBody
	Else
		$oMail.Textbody = $sBody & @CRLF
	EndIf

	$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
	$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $sSMTPServer
	$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $iPort

	; Authenticated SMTP
	If $sUsername <> "" Then
		$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
		$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $sUsername
		$oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $sPassword
	EndIf

	; Set security parameters
	If $bSSL Then $oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
	If $bTLS Then $oMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendtls") = True

	; Update settings
	$oMail.Configuration.Fields.Update
	$oMail.Fields.Update

	; Send the Message
	$oMail.Send
	If @error Then Return SetError(2, 0, 0)

	$oMail = ""

EndFunc   ;==>_INetSmtpMailCom

;===============================================================================
; Function Name:    _StringExtract
; Description:		Extract a string between two search strings
; Call With:			_StringExtract($sString, $sStartSearch, $sEndSearch[, $iStartTrim[, $iEndTrim]])
; Parameter(s):		$sString - String to extract from
;					$sStartSearch - Start search string
;					$sEndSearch - End search string
;					$iStartTrim - [optional] Start trim characters
;					$iEndTrim - [optional] End trim characters
; Return Value(s):  Extracted string
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		Unknown  --  v1.0
;					11/01/2025  --  v1.1 Refactor, local variables
;===============================================================================
Func _StringExtract($sString, $sStartSearch, $sEndSearch, $iStartTrim = 0, $iEndTrim = 0)
	Local $iStartPos = StringInStr($sString, $sStartSearch)
	If Not $iStartPos Then Return SetError(1, 0, 0)
	$iStartPos = $iStartPos + StringLen($sStartSearch)

	Local $iCount = StringInStr($sString, $sEndSearch, 0, 1, $iStartPos)
	If Not $iCount Then Return SetError(2, 0, 0)
	$iCount = $iCount - $iStartPos

	Return StringMid($sString, $iStartPos + $iStartTrim, $iCount + $iEndTrim - $iStartTrim)

EndFunc   ;==>_StringExtract

;===============================================================================
; Function Name:    __StringProper
; Description:		Modified version of _StringProper to lowercase after common contractions
; Call With:		__StringProper($sString)
; Parameter(s): 	$sString - String to properly capitalize
; Return Value(s):  On Success - Properly capitalized string
; 					On Failure - Empty string
; Author(s):        Jos van der Zande <jdeb at autoitscript dot com>
; 					JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.0
;					11/01/2025  --  v1.1 Refactor, match on next two characters
;===============================================================================
Func __StringProper($sString)
	Local $bCapNext = True, $sChr = "", $sReturn = ""
	Local $sPattern = '[a-zA-ZÀ-ÿšœžŸ]'
	Local $iStringLength = StringLen($sString)
	For $i = 1 To $iStringLength
		$sChr = StringMid($sString, $i, 1)
		$sNextTwo = StringMid($sString, $i + 1, 2)
		Select
			Case $bCapNext = True
				If StringRegExp($sChr, $sPattern) Then
					$sChr = StringUpper($sChr)
					$bCapNext = False
				EndIf
			Case $sChr = "'"
				Switch $sNextTwo
					Case "s ", "t ", "m ", "d ", "re ", "ve", "ll"
						$sChr = StringUpper($sChr)
						$bCapNext = False
					Case Else
						$bCapNext = True
				EndSwitch
			Case Not StringRegExp($sChr, $sPattern)
				$bCapNext = True
			Case Else
				$sChr = StringLower($sChr)
		EndSelect
		$sReturn &= $sChr
	Next
	Return $sReturn
EndFunc   ;==>__StringProper

;===============================================================================
; Function Name:    _FileInUse()
; Description:      Checks if file is in use
; Call With:        _FileInUse($sFilename, $iAccess = 0)
; Parameter(s):     $sFilename = File name
;                   $iAccess = 0 = GENERIC_READ - other apps can have file open in readonly mode
;                   $iAccess = 1 = GENERIC_READ|GENERIC_WRITE - exclusive access to file,
;                   fails if file open in readonly mode by app
; Return Value(s):  1 - file in use (@error contains system error code)
;                   0 - file not in use
;                   -1 dllcall error (@error contains dllcall error code)
; Author(s):        Siao, rover
; Date/Version:		10/15/2014  --  v1.0
;===============================================================================
Func _FileInUse($sFilename, $iAccess = 0)
	Local $aRet, $hFile, $iError, $iDA
	Local Const $GENERIC_WRITE = 0x40000000
	Local Const $GENERIC_READ = 0x80000000
	Local Const $FILE_ATTRIBUTE_NORMAL = 0x80
	Local Const $OPEN_EXISTING = 3
	$iDA = $GENERIC_READ
	If BitAND($iAccess, 1) <> 0 Then $iDA = BitOR($GENERIC_READ, $GENERIC_WRITE)
	$aRet = DllCall("Kernel32.dll", "hwnd", "CreateFile", _
			"str", $sFilename, _ ;lpFileName
			"dword", $iDA, _ ;dwDesiredAccess
			"dword", 0x00000000, _ ;dwShareMode = DO NOT SHARE
			"dword", 0x00000000, _ ;lpSecurityAttributes = NULL
			"dword", $OPEN_EXISTING, _ ;dwCreationDisposition = OPEN_EXISTING
			"dword", $FILE_ATTRIBUTE_NORMAL, _ ;dwFlagsAndAttributes = FILE_ATTRIBUTE_NORMAL
			"hwnd", 0) ;hTemplateFile = NULL
	$iError = @error
	If @error Or IsArray($aRet) = 0 Then Return SetError($iError, 0, -1)
	$hFile = $aRet[0]
	If $hFile = -1 Then ;INVALID_HANDLE_VALUE = -1
		$aRet = DllCall("Kernel32.dll", "int", "GetLastError")
		;ERROR_SHARING_VIOLATION = 32 0x20
		;The process cannot access the file because it is being used by another process.
		If @error Or IsArray($aRet) = 0 Then Return SetError($iError, 0, 1)
		Return SetError($aRet[0], 0, 1)
	Else
		;close file handle
		DllCall("Kernel32.dll", "int", "CloseHandle", "hwnd", $hFile)
		Return SetError(@error, 0, 0)
	EndIf
EndFunc   ;==>_FileInUse

;===============================================================================
; Function Name:    _FileInUseWait
; Description:		Waits for a file to be released (no open handles)
; Call With:		_FileInUseWait($sFilePath[, $Timeout = 0[, $Sleep = 2000]])
; Parameter(s):		$sFilePath - Path to the file to check
;					$Timeout - [optional] Seconds before giving up (0 = wait forever)
;					$Sleep - [optional] Milliseconds between checks (default 2000)
; Return Value(s):  On Success - 1 (file is available)
; 					On Failure - 0 (timeout)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.0
;===============================================================================
Func _FileInUseWait($sFilePath, $Timeout = 0, $Sleep = 2000)
	$Timeout = $Timeout * 1000
	$Time = TimerInit()
	While 1
		If _FileInUse($sFilePath) Then
			_Log("  File locked")
		Else
			Return 1
		EndIf
		If $Timeout > 0 And $Timeout < TimerDiff($Time) Then
			_Log("  Timeout, file locked")
			Return 0
		EndIf
		Sleep($Sleep)
	WEnd
EndFunc   ;==>_FileInUseWait

;===============================================================================
; Function Name:    _RunWait
; Description:		Run a program and wait for it to finish, capturing stdout/stderr
; Call With:		_RunWait($sProgram[, $Working[, $Show[, $Opt[, $Live[, $Diag]]]]])
; Parameter(s):		$sProgram - Command line to run
;					$Working - [optional] Working directory
;					$Show - [optional] Window show flag (default @SW_HIDE)
;					$Opt - [optional] Stdout/stderr option (default $STDERR_MERGED)
;					$Live - [optional] Log output in real-time (default False)
;					$Diag - [optional] Diagnostic mode for line endings (default False)
; Return Value(s):  On Success - Captured stdout/stderr data, @extended = PID
; 					On Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/16/2016  --  v1.1
;===============================================================================
Func _RunWait($sProgram, $Working = "", $Show = Default, $Opt = Default, $Live = False, $Diag = False)
	Local $sData, $iPid

	If $Show = Default Then $Show = @SW_HIDE
	If $Opt = Default Then $Opt = $STDERR_MERGED

	$iPid = Run($sProgram, $Working, $Show, $Opt)
	If @error Then
		_Log("_RunWait: Couldn't Run " & $sProgram)
		Return SetError(1, 0, 0)
	EndIf

	$sData = _ProcessWaitClose($iPid, $Live, $Diag)

	Return SetError(0, $iPid, $sData)
EndFunc   ;==>_RunWait

;===============================================================================
; Function Name:    _ProcessWaitClose
; Description:		Wait for a process to close while capturing its stdout/stderr output
; Call With:		_ProcessWaitClose($iPid[, $Live = False[, $Diag = False]])
; Parameter(s):		$iPid - PID of the process (must have been started with stdout/stderr flags)
;					$Live - [optional] Log output lines in real-time (default False)
;					$Diag - [optional] Show line ending diagnostics (default False)
; Return Value(s):  Captured stdout/stderr data as a string
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		09/8/2023  --  v1.3
;===============================================================================
Func _ProcessWaitClose($iPid, $Live = Default, $Diag = Default)
	Local $sData, $sStdRead

	If $Live = Default Then $Live = False
	If $Diag = Default Then $Diag = False

	While 1
		$sStdRead = StdoutRead($iPid)
		If @error Or $sStdRead = "" Then StderrRead($iPid)
		If @error And Not ProcessExists($iPid) Then ExitLoop
		$sStdRead = StringReplace($sStdRead, @CR & @LF & @CR & @LF, @CR & @LF)

		If $Diag Then
			$sStdRead = StringReplace($sStdRead, @CRLF, "_@CRLF")
			$sStdRead = StringReplace($sStdRead, @CR, "@CR" & @CR)
			$sStdRead = StringReplace($sStdRead, @LF, "@LF" & @LF)
			$sStdRead = StringReplace($sStdRead, "_@CRLF", "@CRLF" & @CRLF)
		EndIf

		If $sStdRead <> @CRLF Then
			$sData &= $sStdRead
			If $Live And $sStdRead <> "" Then
				If StringRight($sStdRead, 2) = @CRLF Then $sStdRead = StringTrimRight($sStdRead, 2)
				If StringRight($sStdRead, 1) = @LF Then $sStdRead = StringTrimRight($sStdRead, 1)
				_Log($sStdRead)
			EndIf
		EndIf

		Sleep(5)
	WEnd

	Return $sData
EndFunc   ;==>_ProcessWaitClose

;===============================================================================
; Function Name:    _StringStripWS()
; Description:		Strips all white space chars, excluding char(32) (the regular space)
; Call With:		_StringStripWS($String)
; Parameter(s): 	$String - String To Strip
; Return Value(s):  On Success - Striped String
; 					On Failure - Full String
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _StringStripWS($String)
	Return StringRegExpReplace($String, "[" & Chr(0) & Chr(9) & Chr(10) & Chr(11) & Chr(12) & Chr(13) & "]", "")
EndFunc   ;==>_StringStripWS

;===============================================================================
; Function Name:    _MouseCheck()
; Description:		Checks for mouse movement
; Call With:		_MouseCheck([$Sleep = 300])
; Parameter(s): 	$Sleep - [optional] Milliseconds between mouse checks, 0=Compare At Next Call (default 300)
; Return Value(s):  On Success - 1 (Mouse Moved)
; 					On Failure - 0 (Mouse Didnt Move)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _MouseCheck($Sleep = Default)
	If $Sleep = Default Then $Sleep = 300

	Static Local $sPrevPos = Null

	If $Sleep = 0 Then
		; Deferred mode: capture position now, compare on next call
		Local $aCurrentPos = MouseGetPos()
		If Not IsArray($sPrevPos) Then
			$sPrevPos = $aCurrentPos
			Return 0
		EndIf
		Local $bMoved = (Abs($sPrevPos[0] - $aCurrentPos[0]) > 2 Or Abs($sPrevPos[1] - $aCurrentPos[1]) > 2)
		$sPrevPos = $aCurrentPos
		Return $bMoved ? 1 : 0
	EndIf

	; Immediate mode: capture, sleep, compare
	Local $aPos1 = MouseGetPos()
	Sleep($Sleep)
	Local $aPos2 = MouseGetPos()
	If Abs($aPos1[0] - $aPos2[0]) > 2 Or Abs($aPos1[1] - $aPos2[1]) > 2 Then Return 1

	Return 0
EndFunc   ;==>_MouseCheck

;===============================================================================
; Function Name:    _FieldValue()
; Description:		Get the value of a field from text in "field(value)" format
; Call With:		_FieldValue($Text, $Field, $NewValue = Default)
; Parameter(s): 	$Text - Text to search
;					$Field - Field to search for
;					$NewValue - New value to set (optional)
; Return Value(s):  On Success - The value found or set
;					On Failure - "" and sets @error to 1
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/31/2025  --  v1.0
;===============================================================================
Func _FieldValue($Text, $Field, $NewValue = -1)
	Local $Value = -1

	; Get the current value of the field
	Local $Result = StringRegExp($Text, "(?i)" & $Field & "\((.*?)\)", 3)
	If Not @error And UBound($Result) > 0 Then
		$Value = $Result[0]
	EndIf

	;_Log("Field: " & $Field & "   Text=" & $Text)
	;_Log("   Current Value: " & $Value)
	;_Log("   New Value: " & $NewValue)

	If $NewValue <> -1 Then ; If a new value is provided, update or add the field
		; Update the existing text with the new value
		Local $Replacement = StringRegExpReplace($Text, "(?i)(" & $Field & ")\((.*?)\)", "\1(" & $NewValue & ")")
		Local $Error = @error
		Local $Count = @extended
		;_Log("   Temp: " & $Replacement & "   Error: " & $Error & "   Extended: " & $Count)
		If $Error = 0 And $Count > 0 Then
			$Text = $Replacement
			If $Count > 1 Then
				; Remove all but one instance of the field
				$Text = StringRegExpReplace($Text, "(?i)(_?)(" & $Field & "\(.*?\))", "", 1)
			EndIf
		Else
			$Text = $Field & "(" & $NewValue & ")_" & $Text

		EndIf

		Return $Text

	Else ; If no new value is provided, return the current value
		If $Value <> -1 Then
			Return $Value
		Else
			_Log("   Error: Could not find field: " & $Field)
			Return SetError(1, 0, "")
		EndIf
	EndIf

EndFunc   ;==>_FieldValue

;===============================================================================
; Function Name:    _KeyValue()
; Description:		Work with 2d arrays treated as key value pairs such as the ones produced by INIReadSection()
; Call With:		_KeyValue(ByRef $Array, $Key[, $Value[, $Delete]])
; Parameter(s): 	$Array - A previously declared array, if not array, it will be made as one
;					$Key - The value to look for in the first column/dimension or the "Key" in an INI section
;		(Optional)	$Value - The value to write to the array
;		(Optional)	$Delete - If True, delete the specified key
;
; Return Value(s):  On Success - The value found or set or true if a value was deleted
; 					On Failure - "" and sets @error to 1
;
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/05/2023  --  v1.0
; Notes:            $Array[0][0] Contains the number of stored parameters
; Example:			_KeyValue($Settings, "trayicon", "1")
;===============================================================================
Func _KeyValue(ByRef $aArray, $Key, $Value = Default, $Delete = Default)
	If $Delete = Default Then $Delete = False
	If Not IsArray($aArray) Then Dim $aArray[1][2]

	For $i = 1 To UBound($aArray) - 1
		If $aArray[$i][0] <> $Key Then ContinueLoop

		; Delete existing key
		If $Delete Then
			Local $aNew[1][2]
			For $j = 1 To UBound($aArray) - 1
				If $aArray[$j][0] = $Key Then ContinueLoop
				ReDim $aNew[UBound($aNew) + 1][2]
				$aNew[UBound($aNew) - 1][0] = $aArray[$j][0]
				$aNew[UBound($aNew) - 1][1] = $aArray[$j][1]
			Next
			$aNew[0][0] = UBound($aNew) - 1
			$aArray = $aNew
			Return True
		EndIf

		; Read existing value
		If $Value = Default Then Return $aArray[$i][1]

		; Update existing value
		$aArray[$i][1] = $Value
		$aArray[0][0] = UBound($aArray) - 1
		Return $Value
	Next

	; Key not found — add new key/value if specified
	If $Value <> Default And Not $Delete Then
		ReDim $aArray[UBound($aArray) + 1][2]
		$aArray[UBound($aArray) - 1][0] = $Key
		$aArray[UBound($aArray) - 1][1] = $Value
		$aArray[0][0] = UBound($aArray) - 1
		Return $Value
	EndIf

	Return SetError(1, 0, "")
EndFunc   ;==>_KeyValue

;===============================================================================
; Function Name:   	_Log()
; Description:		Console log, file log, custom GUI log
; Call With:		_Log($sMessage[, $iLevel[, $bOverWriteLast[, $iCallingLine]]])
; Parameter(s): 	$sMessage - Text to print
;					$iLevel - [optional] The level *this* message, 1 for critical/always shown (default), 2+ for debugging
;					$bOverWriteLast - [optional] Overwrite the last line in the log (default False)
;					$iCallingLine - [optional] Script line number (default @ScriptLineNumber)
; Return Value(s):  The original message, if $iLevel is greater than $LogLevel returns an empty string
; Notes:			Some options are configured with global variables
; Author(s):        JohnMC - JohnsCS.com
; Date/Last Change:	4/26/2024 -- Fixed global handling, added minimize window on start
;					5/6/2024 -- Added $bOverWriteLast, changed the way line returns work on consolewrite
;					7/21/2024 -- Added script line number
;===============================================================================
Func _Log($sMessage, $iLevel = Default, $bOverWriteLast = Default, $iCallingLine = @ScriptLineNumber)
	Static Local $_hLogFile

	; Defaults
	If $iLevel = Default Then $iLevel = 1
	If $bOverWriteLast = Default Then $bOverWriteLast = False

	; Global options
	Global $LogLevel, $LogTitle, $LogWindowStart, $LogWindowSize, $LogFullPath, $LogFileMaxSize, $LogFlushAlways

	;If $LogTitle = ""  Then $LogTitle = "" ; If empty, skip the GUI
	If $LogLevel = "" Then $LogLevel = 1 ; Only show messages this level or below
	If $LogWindowStart = "" Then $LogWindowStart = -1 ; -1 for center, -# for minimized with position being the absolute value
	If $LogWindowSize = "" Then $LogWindowSize = 750 ; Starting width, height will be .6 of this value
	If $LogFullPath = "" Then $LogFullPath = "" ; The path of the log file, empty value will not log to file
	If $LogFileMaxSize = "" Then $LogFileMaxSize = 512 ; Size limit for log in KB
	If $LogFlushAlways = "" Then $LogFlushAlways = False ; Flush log to disk after each update

	Local $LogFileMaxSize_Bytes = $LogFileMaxSize * 1024
	Local $sTime = @YEAR & "-" & @MON & "-" & @MDAY & " " & @HOUR & ":" & @MIN & ":" & @SEC

	If @Compiled Then
		Local $sLogLine = $sTime & "> " & $sMessage
	Else
		Local $sLogLine = $sTime & " " & $iCallingLine & "> " & $sMessage
	EndIf

	Local $Minimize = False

	; Do not log this message if $iLevel is greater than global $LogLevel
	If $iLevel > $LogLevel Then Return ""

	; Send to console
	; _Console_Write is from Console.au3
	#ignorefunc _Console_Write

	If $bOverWriteLast And Not @Compiled Then
		; Do Nothing
	ElseIf $bOverWriteLast Then
		ConsoleWrite(@CR & $sLogLine)
		Call("_Console_Write", @CR & $sLogLine)
	Else
		ConsoleWrite(@CRLF & $sLogLine)
		Call("_Console_Write", @CRLF & $sLogLine)
	EndIf

	; Append message to custom GUI if $LogTitle is set
	If $LogTitle <> "" Then
		Local $sLogLineGUI = StringReplace($sLogLine, @LF, @CRLF)

		; If the GUI doesn't exist, create it
		If Eval("_hLogWindow") = "" Then
			If $LogWindowStart < -1 Then
				$LogWindowStart = Abs($LogWindowStart)
				$Minimize = True
			EndIf
			Global $_hLogWindow = GUICreate($LogTitle, $LogWindowSize, Round($LogWindowSize * 0.6), $LogWindowStart, $LogWindowStart, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))
			Global $_hLogEdit = GUICtrlCreateEdit("", 0, 0, $LogWindowSize, Round($LogWindowSize * 0.6), BitOR($ES_MULTILINE, $ES_WANTRETURN, $WS_VSCROLL, $WS_HSCROLL))
			GUICtrlSetFont(-1, 10, 400, 0, "Consolas")
			GUICtrlSetColor(-1, 0xFFFFFF)
			GUICtrlSetBkColor(-1, 0x000000)
			GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKRIGHT + $GUI_DOCKTOP + $GUI_DOCKBOTTOM)
			_GUICtrlEdit_SetReadOnly($_hLogEdit, True)
			GUISetState(@SW_SHOW, $_hLogWindow)
			If $Minimize Then GUISetState(@SW_MINIMIZE, $_hLogWindow)
		EndIf

		; Update GUI
		_GUICtrlEdit_BeginUpdate($_hLogEdit)
		If $bOverWriteLast Then
			Local $sFullText = _GUICtrlEdit_GetText($_hLogEdit)
			$sFullText = StringLeft($sFullText, StringInStr($sFullText, @CRLF, 0, -1) - 1)
			_GUICtrlEdit_SetText($_hLogEdit, $sFullText)

		EndIf
		_GUICtrlEdit_AppendText($_hLogEdit, @CRLF & $sLogLineGUI)
		_GUICtrlEdit_LineScroll($_hLogEdit, -StringLen($sLogLineGUI), _GUICtrlEdit_GetLineCount($_hLogEdit))
		_GUICtrlEdit_EndUpdate($_hLogEdit)
	EndIf

	; If $LogTitle is empty, delete the GUI
	If $LogTitle = "" And Eval("_hLogWindow") <> "" Then
		GUIDelete(Eval("_hLogWindow"))
		Global $_hLogWindow = ""
	EndIf

	; Log to file if enabled
	If $LogFullPath <> "" And Not $bOverWriteLast Then
		; Limit log size, if over size, rename and open new one
		If $LogFileMaxSize > 0 Then
			Local $iCurrentSize = FileGetPos($_hLogFile)
			If $iCurrentSize > $LogFileMaxSize_Bytes Then
				FileClose($_hLogFile)
				FileMove($LogFullPath, $LogFullPath & ".old", 1)
			EndIf
		EndIf

		; If log file not open, open it for appending
		If Not FileGetPos($_hLogFile) Then $_hLogFile = FileOpen($LogFullPath, $FO_APPEND)

		; Write to file
		FileWrite($_hLogFile, $sLogLine & @CRLF)
		If $LogFlushAlways Then FileFlush($_hLogFile)
	EndIf

	Return $sMessage
EndFunc   ;==>_Log

;===============================================================================
; Function Name:    _ConsoleWrite() - Alias For _Log()
;===============================================================================
Func _ConsoleWrite($sMessage, $iLevel = 1, $iSameLine = 0)
	Return _Log($sMessage, $iLevel)
EndFunc   ;==>_ConsoleWrite

;===============================================================================
; Function Name:    _TimeStamp()
; Description:		Returns time since epoch 0, default is total seconds (Unix timestamp)
; Call With:		_TimeStamp([$Option = 2])
; Parameter(s): 	$Option - [optional] Default is 2 (Seconds)
;						1 = Return Total Milliseconds
;						2 = Return Total Seconds
;						3 = Return Total Minutes
; Return Value(s):  On Success - Time
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;					11/01/2025  --  v1.1 Refactor
;===============================================================================
Func _TimeStamp($Option = 2)
	Local $aResult = DllCall("msvcrt.dll", "int:cdecl", "time", "int", 0)
	If @error Then Return SetError(1, 0, 0)

	If $Option = 1 Then $aResult[0] = $aResult[0] * 1000 + @MSEC
	If $Option = 3 Then $aResult[0] = Floor($aResult[0] / 60)

	Return $aResult[0]
EndFunc   ;==>_TimeStamp

;===============================================================================
; Function Name:    _ProcessWaitNew()
; Description:		Wait for a new proccess to be created before continuing
; Call With:		_ProcessWaitNew($Process[, $Timeout = 0])
; Parameter(s): 	$Process - PID or process name
;					$Timeout - [optional] Seconds before giving up (0 = wait forever)
; Return Value(s):  On Success - 1
; 					On Failure - 0 (Timeout)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _ProcessWaitNew($Process, $Timeout = 0)
	Local $Count1 = _ProcessCount(), $Count2
	Local $StartTime = _TimeStamp()

	While 1
		$Count2 = _ProcessCount()
		If $Count2 > $Count1 Then Return 1
		If $Count2 < $Count1 Then $Count1 = $Count2

		If $Timeout > 0 And $StartTime < _TimeStamp() - $Timeout Then ExitLoop
		Sleep(100)
	WEnd

	Return 0
EndFunc   ;==>_ProcessWaitNew

;===============================================================================
; Function Name:    _ProcessCount()
; Description:		Returns the number of processes with the same name
; Call With:		_ProcessCount([$Process[,$OnlyUser]])
; Parameter(s): 	$Process - PID or process name
;					$OnlyUser - Only evaluate processes from this user
; Return Value(s):  On Success - Count
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _ProcessCount($Process = @AutoItPID, $OnlyUser = "")
	Local $Count = 0, $Array = ProcessList($Process)

	For $i = 1 To $Array[0][0]
		If $Array[$i][1] = $Process Then
			If $OnlyUser <> "" And $OnlyUser <> _ProcessOwner($Array[$i][1]) Then ContinueLoop
			$Count = $Count + 1
		EndIf
	Next

	Return $Count
EndFunc   ;==>_ProcessCount

;===============================================================================
; Function Name:    _ProcessOwner()
; Description:		Gets username of the owner of a PID
; Call With:		_ProcessOwner($PID[,$Hostname])
; Parameter(s): 	$PID - PID of proccess
;					$Hostname - (Optional) The computers name to check on
; Return Value(s):  On Success - Username of owner
; 					On Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _ProcessOwner($PID, $Hostname = ".")
	Local $User, $objWMIService, $colProcess, $objProcess

	$objWMIService = ObjGet("winmgmts://" & $Hostname & "/root/cimv2")
	$colProcess = $objWMIService.ExecQuery("Select * from Win32_Process Where ProcessID ='" & $PID & "'")

	For $objProcess In $colProcess
		If $objProcess.ProcessID = $PID Then
			$User = 0
			$objProcess.GetOwner($User)
			Return $User
		EndIf
	Next

	Return SetError(1, 0, 0)
EndFunc   ;==>_ProcessOwner

;===============================================================================
; Function Name:    _ProcessCloseOthers()
; Description:		Closes other proccess of the same name
; Call With:		_ProcessCloseOthers([$Process[,$ExcludingUser[,$OnlyUser]]])
; Parameter(s): 	$Process - (Optional) Name or PID
;					$ExcludingUser - (Optional) Username of owner to exclude
;					$OnlyUser - (Optional) Username of proccesses owner to close
; Return Value(s):  On Success - 1
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _ProcessCloseOthers($Process = @ScriptName, $ExcludingUser = "", $OnlyUser = "")
	Local $Array = ProcessList($Process)

	For $i = 1 To $Array[0][0]
		If ($Array[$i][1] <> @AutoItPID) Then
			If $ExcludingUser <> "" And _ProcessOwner($Array[$i][1]) <> $ExcludingUser Then
				ProcessClose($Array[$i][1])
			ElseIf $OnlyUser <> "" And _ProcessOwner($Array[$i][1]) = $OnlyUser Then
				ProcessClose($Array[$i][1])
			ElseIf $OnlyUser = "" And $ExcludingUser = "" Then
				ProcessClose($Array[$i][1])
			EndIf
		EndIf
	Next
EndFunc   ;==>_ProcessCloseOthers

;===============================================================================
; Function Name:    _OnlyInstance()
; Description:		Checks to see if we are the only instance running
; Call With:		_OnlyInstance($iFlag)
; Parameter(s): 	$iFlag
;						0 = Continue Anyway
;						1 = Exit Without Notification
;						2 = Exit After Notifying
;						3 = Exit or Continue Prompt
;						4 = Exit or Close Other Proccesses Prompt
; Return Value(s):  On Success - 1 (Found Another Instance)
; 					On Failure - 0 (Didnt Find Another Instance)
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.1
;===============================================================================
Func _OnlyInstance($iFlag)
	Local $ERROR_ALREADY_EXISTS = 183

	If @Compiled = 0 Then Return 0

	Local $Handle = DllCall("kernel32.dll", "int", "CreateMutex", "int", 0, "long", 1, "str", @ScriptName)
	Local $LastError = DllCall("kernel32.dll", "int", "GetLastError")
	If $LastError[0] = $ERROR_ALREADY_EXISTS Then
		SetError($LastError[0], $LastError[0], 0)
		Switch $iFlag
			Case 0
				Return 1
			Case 1
				ProcessClose(@AutoItPID)
			Case 2
				MsgBox(262144 + 48, @ScriptName, "The Program Is Already Running")
				ProcessClose(@AutoItPID)
			Case 3
				Local $Msg = MsgBox(262144 + 256 + 48 + 4, @ScriptName, "The Program (" & @ScriptName & ") Is Already Running, Continue Anyway?")
				If $Msg <> $IDYES Then ProcessClose(@AutoItPID)
			Case 4
				Local $Msg = MsgBox(262144 + 256 + 48 + 4, @ScriptName, "The Program (" & @ScriptName & ") Is Already Running, Close The Other Proccesses?")
				If $Msg = $IDYES Then _ProcessCloseOthers()
		EndSwitch
		Return 1
	EndIf
	Return 0
EndFunc   ;==>_OnlyInstance

;===============================================================================
; Function Name:    _MsgBox()
; Description:		Displays a msgbox without halting script by using /AutoIt3ExecuteLine
; Call With:		_MsgBox([$Flag = Default[, $Title = Default[, $Text = Default[, $Timeout = Default]]]])
; Parameter(s): 	$Flag - [optional] MsgBox flag (default 0)
;					$Title - [optional] Window title (default @ScriptName)
;					$Text - [optional] Message text (default "")
;					$Timeout - [optional] Timeout in seconds (default 0)
; Return Value(s):  On Success - PID of new process
; 					On Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.1
;===============================================================================
Func _MsgBox($Flag = Default, $Title = Default, $Text = Default, $Timeout = Default)
	If $Flag = Default Or IsInt($Flag) = 0 Then $Flag = 0
	If $Title = Default Then $Title = @ScriptName
	If $Text = Default Then $Text = ""
	If $Timeout = Default Then $Timeout = 0

	$Title = StringReplace($Title, "'", "")
	$Text = StringReplace($Text, "'", "")

	Return Run('"' & @AutoItExe & '"' & ' /AutoIt3ExecuteLine "msgbox(' & $Flag & ',''' & $Title & ''',''' & $Text & ''',''' & $Timeout & ''')"')
EndFunc   ;==>_MsgBox

;===============================================================================
; Function Name:    _GetDriveFromSerial()
; Description:		Find a drives letter based on the drives serial
; Call With:		_GetDriveFromSerial($Serial)
; Parameter(s): 	$Serial - Serial of the drive
; Return Value(s):  On Success - Drive letter with ":"
; 					On Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		01/29/2010  --  v1.0
;===============================================================================
Func _GetDriveFromSerial($Serial)
	Local $Drivelist
	$Drivelist = StringSplit("c:,d:,e:,f:,g:,h:,i:,j:,k:,l:,m:,n:,o:,p:,q:,r:,s:,t:,u:,v:,w:,x:,y:,z:", ",")
	For $i = 1 To $Drivelist[0]
		If (DriveGetSerial($Drivelist[$i]) = $Serial And DriveStatus($Drivelist[$i]) = "READY") Then Return $Drivelist[$i]
	Next
	Return 0
EndFunc   ;==>_GetDriveFromSerial

;===============================================================================
; Function Name:    _Sleep()
; Description:		Simple modification to sleep to allow for adlib functions to run
; Call With:		_Sleep($iTime)
; Parameter(s): 	$iTime - Time in MS
; Return Value(s):  none
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.0
;===============================================================================
Func _Sleep($iTime)
	$iTime = Round($iTime / 10)
	For $i = 1 To $iTime
		Sleep(10)
	Next
EndFunc   ;==>_Sleep

;===============================================================================
; Function Name:    _IsInternet()
; Description:		Gets internet connection state as determined by Windows
; Call With:		_IsInternet()
; Parameter(s): 	none
; Return Value(s):  Success - 1
;					Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.0
;===============================================================================
Func _IsInternet()
	Local $Ret = DllCall("wininet.dll", 'int', 'InternetGetConnectedState', 'dword*', 0x20, 'dword', 0)

	If (@error) Then
		Return SetError(1, 0, 0)
	EndIf

	Local $wError = _WinAPI_GetLastError()

	Return SetError((Not ($wError = 0)), $wError, $Ret[0])
EndFunc   ;==>_IsInternet

;===============================================================================
; Function Name:    _WinGetClientPos
; Description:		Retrieves the position and size of the client area of given window
; Call With:		_WinGetClientPos($HWND[, $Absolute = 1])
; Parameter(s): 	$HWND - Handle to window
;					$Absolute - [optional] 1 = Get coordinates relative to the screen (default)
;								0 = Get coordinates relative to the window
; Return Value(s):	On Success - Returns an array containing location values for client area of the specified window
;									$Array[0] = X position
;									$Array[1] = Y position
;									$Array[2] = Width
;									$Array[3] = Height
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		11/21/2012  --  v1.2
;===============================================================================
Func _WinGetClientPos($HWND, $Absolute = 1)
	Local $aPos[4], $aSize[4], $aWinPos[4]

	Local $tpoint = DllStructCreate("int X;int Y")
	DllStructSetData($tpoint, "X", 0)
	DllStructSetData($tpoint, "Y", 0)
	DllCall("user32.dll", "bool", "ClientToScreen", "hwnd", $HWND, "struct*", $tpoint)

	$aSize = WinGetClientSize($HWND)

	$aPos[0] = DllStructGetData($tpoint, "X")
	$aPos[1] = DllStructGetData($tpoint, "Y")
	$aPos[2] = $aSize[0]
	$aPos[3] = $aSize[1]

	If $Absolute = 0 Then
		$aWinPos = WinGetPos($HWND)
		$aPos[0] = $aPos[0] - $aWinPos[0]
		$aPos[1] = $aPos[1] - $aWinPos[1]
	EndIf

	Return $aPos
EndFunc   ;==>_WinGetClientPos

;===============================================================================
; Function Name:    _WinMoveClient
; Description:		Position and size the client area of a given window
; Call With:		_WinMoveClient($sTitle, $sText, $X, $Y[, $Width[, $Height[, $Speed]]])
; Parameter(s):		$sTitle - Window title
;					$sText - Window text
;					$X - X position
;					$Y - Y position
;					$Width - [optional] Client area width
;					$Height - [optional] Client area height
;					$Speed - [optional] Move speed
; Return Value(s):	Success - 1
;					Failure - 0
; Author(s):        JohnMC - JohnsCS.com
; Date/Version:		10/15/2014  --  v1.0
;===============================================================================
Func _WinMoveClient($sTitle, $sText, $X, $Y, $Width = Default, $Height = Default, $Speed = Default)

	Local $WinPos = WinGetPos($sTitle, $sText)
	Local $ClientSize = WinGetClientSize($sTitle, $sText)

	If $Width <> Default Then $Width = $Width + $WinPos[2] - $ClientSize[0]
	If $Height <> Default Then $Height = $Height + $WinPos[3] - $ClientSize[1]

	Return WinMove($sTitle, $sText, $X, $Y, $Width, $Height, $Speed)
EndFunc   ;==>_WinMoveClient

;=============================================================================================
; Name:				 _HighPrecisionSleep()
; Description:		Sleeps down to 0.1 microseconds
; Syntax:			_HighPrecisionSleep( $iMicroSeconds, $hDll=False)
; Parameter(s):		$iMicroSeconds        - Amount of microseconds to sleep
;					$hDll  - Can be supplied so the UDF doesn't have to re-open the dll all the time.
; Return value(s):	None
; Author:			Andreas Karlsson (monoceres)
; Remarks:			Even though this has high precision you need to take into consideration that it will take some time for autoit to call the function.
;=============================================================================================
Func _HighPrecisionSleep($iMicroSeconds, $dll = "")
	Local $hStruct, $bLoaded
	If $dll <> "" Then $HPS_hDll = $dll
	If Not IsDeclared("HPS_hDll") Then
		Global $HPS_hDll
		$HPS_hDll = DllOpen("ntdll.dll")
		$bLoaded = True
	EndIf
	$hStruct = DllStructCreate("int64 time;")
	DllStructSetData($hStruct, "time", -1 * ($iMicroSeconds * 10))
	DllCall($HPS_hDll, "dword", "ZwDelayExecution", "int", 0, "ptr", DllStructGetPtr($hStruct))
EndFunc   ;==>_HighPrecisionSleep

;===============================================================================
; Function:		_ProcessGetWin
; Purpose:		Return information on the Window owned by a process (if any)
; Syntax:		_ProcessGetWin($iPID)
; Parameters:	$iPID = integer process ID
; Returns:  	On success returns an array:
; 					[0] = Window Title (if any)
;					[1] = Window handle
;				If $iPID does not exist, returns empty array and @error = 1
; Notes:		Not every process has a window, indicated by an empty array and
;   			@error = 0, and not every window has a title, so test [1] for the handle
;   			to see if a window existed for the process.
; Author:		PsaltyDS at www.autoitscript.com/forum
;===============================================================================
Func _ProcessGetWin($iPid)
	Local $avWinList = WinList(), $avRET[2]
	For $n = 1 To $avWinList[0][0]
		If WinGetProcess($avWinList[$n][1]) = $iPid Then
			$avRET[0] = $avWinList[$n][0] ; Title
			$avRET[1] = $avWinList[$n][1] ; HWND
			ExitLoop
		EndIf
	Next
	If $avRET[1] = "" Then SetError(1)
	Return $avRET
EndFunc   ;==>_ProcessGetWin

;===============================================================================
; Function Name:    _ProcessListProperties()
; Description:   Get various properties of a process, or all processes
; Call With:       _ProcessListProperties( [$Process [, $sComputer]] )
; Parameter(s):  (optional) $Process - PID or name of a process, default is "" (all)
;          (optional) $sComputer - remote computer to get list from, default is local
; Requirement(s):   AutoIt v3.2.4.9+
; Return Value(s):  On Success - Returns a 2D array of processes, as in ProcessList()
;            with additional columns added:
;            [0][0] - Number of processes listed (can be 0 if no matches found)
;            [1][0] - 1st process name
;            [1][1] - 1st process PID
;            [1][2] - 1st process Parent PID
;            [1][3] - 1st process owner
;            [1][4] - 1st process priority (0 = low, 31 = high)
;            [1][5] - 1st process executable path
;            [1][6] - 1st process CPU usage
;            [1][7] - 1st process memory usage
;            [1][8] - 1st process creation date/time = "MM/DD/YYY hh:mm:ss" (hh = 00 to 23)
;            [1][9] - 1st process command line string
;            ...
;            [n][0] thru [n][9] - last process properties
; On Failure:     	Returns array with [0][0] = 0 and sets @Error to non-zero (see code below)
; Author(s):      	PsaltyDS at http://www.autoitscript.com/forum
; Date/Version:   	12/01/2009  --  v2.0.4
; Notes:        	If an integer PID or string process name is provided and no match is found,
;             		then [0][0] = 0 and @error = 0 (not treated as an error, same as ProcessList)
;          			This function requires admin permissions to the target computer.
;          			All properties come from the Win32_Process class in WMI.
;            		To get time-base properties (CPU and Memory usage), a 100ms SWbemRefresher is used.
;===============================================================================
Func _ProcessListProperties($Process = "", $sComputer = ".")
	Local $sUsername, $sMsg, $sUserDomain, $avProcs, $dtmDate
	Local $avProcs[1][2] = [[0, ""]], $n = 1

	; Convert PID if passed as string
	If StringIsInt($Process) Then $Process = Int($Process)

	; Connect to WMI and get process objects
	$oWMI = ObjGet("winmgmts:{impersonationLevel=impersonate,authenticationLevel=pktPrivacy, (Debug)}!\\" & $sComputer & "\root\cimv2")
	If IsObj($oWMI) Then
		; Get collection processes from Win32_Process
		If $Process == "" Then
			; Get all
			$colProcs = $oWMI.ExecQuery("select * from win32_process")
		ElseIf IsInt($Process) Then
			; Get by PID
			$colProcs = $oWMI.ExecQuery("select * from win32_process where ProcessId = " & $Process)
		Else
			; Get by Name
			$colProcs = $oWMI.ExecQuery("select * from win32_process where Name = '" & $Process & "'")
		EndIf

		If IsObj($colProcs) Then
			; Return for no matches
			If $colProcs.count = 0 Then Return $avProcs

			; Size the array
			ReDim $avProcs[$colProcs.count + 1][10]
			$avProcs[0][0] = UBound($avProcs) - 1

			; For each process...
			For $oProc In $colProcs
				; [n][0] = Process name
				$avProcs[$n][0] = $oProc.name
				; [n][1] = Process PID
				$avProcs[$n][1] = $oProc.ProcessId
				; [n][2] = Parent PID
				$avProcs[$n][2] = $oProc.ParentProcessId
				; [n][3] = Owner
				If $oProc.GetOwner($sUsername, $sUserDomain) = 0 Then $avProcs[$n][3] = $sUserDomain & "\" & $sUsername
				; [n][4] = Priority
				$avProcs[$n][4] = $oProc.Priority
				; [n][5] = Executable path
				$avProcs[$n][5] = $oProc.ExecutablePath
				; [n][8] = Creation date/time
				$dtmDate = $oProc.CreationDate
				If $dtmDate <> "" Then
					; Back referencing RegExp pattern from weaponx
					Local $sRegExpPatt = "\A(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})(?:.*)"
					$dtmDate = StringRegExpReplace($dtmDate, $sRegExpPatt, "$2/$3/$1 $4:$5:$6")
				EndIf
				$avProcs[$n][8] = $dtmDate
				; [n][9] = Command line string
				$avProcs[$n][9] = $oProc.CommandLine

				; increment index
				$n += 1
			Next
		Else
			SetError(2) ; Error getting process collection from WMI
		EndIf
		; release the collection object
		$colProcs = 0

		; Get collection of all processes from Win32_PerfFormattedData_PerfProc_Process
		; Have to use an SWbemRefresher to pull the collection, or all Perf data will be zeros
		Local $oRefresher = ObjCreate("WbemScripting.SWbemRefresher")
		$colProcs = $oRefresher.AddEnum($oWMI, "Win32_PerfFormattedData_PerfProc_Process").objectSet
		$oRefresher.Refresh

		; Time delay before calling refresher
		Local $iTime = TimerInit()
		Do
			Sleep(20)
		Until TimerDiff($iTime) >= 100
		$oRefresher.Refresh

		; Get PerfProc data
		For $oProc In $colProcs
			; Find it in the array
			For $n = 1 To $avProcs[0][0]
				If $avProcs[$n][1] = $oProc.IDProcess Then
					; [n][6] = CPU usage
					$avProcs[$n][6] = $oProc.PercentProcessorTime
					; [n][7] = memory usage
					$avProcs[$n][7] = $oProc.WorkingSet
					ExitLoop
				EndIf
			Next
		Next
	Else
		SetError(1) ; Error connecting to WMI
	EndIf

	; Return array
	Return $avProcs
EndFunc   ;==>_ProcessListProperties

;===============================================================================
; Function:		_IsIP
; Purpose:		Validate if string is an IP address
; Syntax:		_IsIP($sIP)
; Parameters:	$sIP = String to validate as IP address
; Returns:  	Success - 1=IP 2=Subnet
;				Failure - 0 ()
; Notes:
; Author:
; Date/Version:   	10/15/2014  --  v2.0.4
;===============================================================================
Func _IsIP($sIP, $P_strict = 0)
	$t_ip = $sIP
	$port = StringInStr($t_ip, ":") ;check for : (for the port)
	If $port Then ;has a port attached
		$t_ip = StringLeft($sIP, $port - 1) ;remove the port from the rest of the ip
		If $P_strict Then ;return 0 if port is wrong
			$zport = Int(StringTrimLeft($sIP, $port)) ;retrieve the port
			If $zport > 65000 Or $zport < 0 Then Return 0 ;port is wrong
		EndIf
	EndIf
	$zip = StringSplit($t_ip, ".")
	If $zip[0] <> 4 Then Return 0 ;incorect number of segments
	If Int($zip[1]) > 255 Or Int($zip[1]) < 1 Then Return 0 ;xxx.ooo.ooo.ooo
	If Int($zip[2]) > 255 Or Int($zip[1]) < 0 Then Return 0 ;ooo.xxx.ooo.ooo
	If Int($zip[3]) > 255 Or Int($zip[3]) < 0 Then Return 0 ;ooo.ooo.xxx.ooo
	If Int($zip[4]) > 255 Or Int($zip[4]) < 0 Then Return 0 ;ooo.ooo.ooo.xxx
	$BC = 1 ; is it 255.255.255.255 ?
	For $i = 1 To 4
		If $zip[$i] <> 255 Then $BC = 0 ;no
		;255.255.255.255 can never be a ip but anything else that ends with .255 can be
		;ex:10.10.0.255 can actually be an ip address and not a broadcast address
	Next
	If $BC Then Return 0 ;a broadcast address is not really an ip address...
	If $zip[4] = 0 Then ;subnet not ip
		If $port Then
			Return 0 ;subnet with port?
		Else
			Return 2 ;subnet
		EndIf
	EndIf
	Return 1 ;;string is a ip
EndFunc   ;==>_IsIP

;==============================================================================================
; Description:		_FileRegister($FileExt, $Command, $Verb[, $Default = Default[, $Icon = Default[, $Description = Default]]])
;					Registers a file type in Explorer
; Parameter(s):		$FileExt - 	File Extension without period eg. "zip"
;					$Command - 	Program path with arguments eg. '"C:\test\testprog.exe" "%1"'
;								(%1 is 1st argument, %2 is 2nd, etc.)
;								Setting $Command to an empty string "" will skip setting that key and return the value of an existing key
;					$Verb 	- 	Name of action to perform on file
;								eg. "Open with ProgramName" or "Extract Files"
;					$Default - 	(True/False) The verb will be the default for this filetype
;								If the file is not already associated, this will be the default.
;								Setting default to False will return the current default verb
;					$Icon - 	Default icon for filetype including resource # if needed
;								eg. "C:\test\testprog.exe,0" or "C:\test\filetype.ico"
;					$Description - File Description eg. "Zip File" or "ProgramName Document"
; Returns:  		Returns the new verb is setting that key was a success, the old verb if it was not
;					Sets @extended to the new command if setting that key was a success or the old command if not
; Notes:
; Author:
; Date/Version:   	10/15/2014  --  v2.0.4
;===============================================================================================
Func _FileRegister($FileExt, $Command, $Verb = Default, $Default = Default, $Icon = Default, $Description = Default)
	; FileExt is a key representing the file extention and specifying which FileType to use for that extention
	; FileType is a key containing various properties and actions (verbs) that can be used for files of this type

	If $Default = Default Then $Default = False ; Do not make the new verb the default
	If $Command = Default Or $Command = "" Then $Command = "" ; Allow use of Default to be treated as ""

	; Remove the "." if it was included
	If StringLeft($FileExt, 1) = "." Then $FileExt = StringTrimLeft($FileExt, 1)

	; Get the current FileType for the extention
	Local $FileType = RegRead("HKCR\." & $FileExt, "")
	If @error And $Verb = Default Then
		; If FileExt doesn't exist but a verb wasn't specified then we have nothing to do.
		Return SetError(1, 0, "")
	ElseIf @error Then ; The extention doesn't exist so create it
		RegWrite("HKCR\." & $FileExt, "", "REG_SZ", $FileExt & "file") ; Create a new FileType to use with it
		$FileType = $FileExt & "file" ; Make the new Verb default since it doesn't have one
		$Default = True
	EndIf

	; Verb keys can't have spaces, still use $Verb for a display name
	$VerbKey = StringReplace($Verb, " ", "")

	; Set the default verb to use
	Local $CurrentDefaultVerb = RegRead("HKCR\" & $FileType & "\shell", "")
	If $Default Then
		If Not @error Then RegWrite("HKCR\" & $FileType & "\shell", "oldverb", "REG_SZ", $CurrentDefaultVerb) ; Backup default verb
		RegWrite("HKCR\" & $FileType & "\shell", "", "REG_SZ", $VerbKey) ; Make new verb the default
		If Not @error Then $CurrentDefaultVerb = $VerbKey
	EndIf

	If $Verb <> Default Then
		; The display name for the verb
		Local $CurrentVerbName = RegRead("HKCR\" & $FileType & "\shell\" & $VerbKey, "")
		If Not @error Then RegWrite("HKCR\" & $FileType & "\shell\" & $VerbKey, "oldname", "REG_SZ", $CurrentVerbName) ; Backup verb name
		RegWrite("HKCR\" & $FileType & "\shell\" & $VerbKey, "", "REG_SZ", $Verb) ; Set the display name

		; Command is a subkey reprenseting what happens when a particular verb is selected
		Local $CurrentCommand = RegRead("HKCR\" & $FileType & "\shell\" & $VerbKey & "\command", "")
		If $Command <> Default Then
			If Not @error Then RegWrite("HKCR\" & $FileType & "\shell\" & $VerbKey & "\command", "oldcmd", "REG_SZ", $CurrentCommand) ; Backup command
			RegWrite("HKCR\" & $FileType & "\shell\" & $VerbKey & "\command", "", "REG_SZ", $Command) ; Set the command
			If Not @error Then $CurrentCommand = $Command
		EndIf
	EndIf

	; Specify the icon to be used for the FileType
	If $Icon <> Default Then
		Local $CurrentIcon = RegRead("HKCR\" & $FileType & "\DefaultIcon", "")
		If @error Then RegWrite("HKCR\" & $FileType & "\DefaultIcon", "oldicon", "REG_SZ", $CurrentIcon) ; Backup icon
		RegWrite("HKCR\" & $FileType & "\DefaultIcon", "", "REG_SZ", $Icon)
	EndIf

	; Set the description for the the file type
	If $Description <> Default Then
		Local $CurrentDescription = RegRead("HKCR\" & $FileType, "")
		If @error Then RegWrite("HKCR\" & $FileType, "olddesc", "REG_SZ", $CurrentDescription) ; Backup description
		RegWrite("HKCR\" & $FileType, "", "REG_SZ", $Description) ; Write the description
	EndIf

	Return SetError(0, $CurrentCommand, $CurrentDefaultVerb)
EndFunc   ;==>_FileRegister

;===============================================================================
; Description:		FileUnRegister($ext, $verb)
;					UnRegisters a verb for a file type in Explorer
; Parameter(s):		$ext - File Extension without period eg. "zip"
;					$verb - Name of file action to remove
;							eg. "Open with ProgramName" or "Extract Files"
;===============================================================================
Func _FileUnRegister($ext, $Verb)
	$loc = RegRead("HKCR\." & $ext, "")
	If Not @error Then
		$oldicon = RegRead("HKCR\" & $loc & "\shell", "oldicon")
		If Not @error Then
			RegWrite("HKCR\" & $loc & "\DefaultIcon", "", "REG_SZ", $oldicon)
		Else
			RegDelete("HKCR\" & $loc & "\DefaultIcon", "")
		EndIf
		$oldverb = RegRead("HKCR\" & $loc & "\shell", "oldverb")
		If Not @error Then
			RegWrite("HKCR\" & $loc & "\shell", "", "REG_SZ", $oldverb)
		Else
			RegDelete("HKCR\" & $loc & "\shell", "")
		EndIf
		$olddesc = RegRead("HKCR\" & $loc, "olddesc")
		If Not @error Then
			RegWrite("HKCR\" & $loc, "", "REG_SZ", $olddesc)
		Else
			RegDelete("HKCR\" & $loc, "")
		EndIf
		$oldcmd = RegRead("HKCR\" & $loc & "\shell\" & $Verb & "\command", "oldcmd")
		If Not @error Then
			RegWrite("HKCR\" & $loc & "\shell\" & $Verb & "\command", "", "REG_SZ", $oldcmd)
			RegDelete("HKCR\" & $loc & "\shell\" & $Verb & "\command", "oldcmd")
		Else
			RegDelete("HKCR\" & $loc & "\shell\" & $Verb)
		EndIf
	EndIf
EndFunc   ;==>_FileUnRegister