dot_zshrc

# vim:ft=zsh:

ZIM_HOME=${XDG_CACHE_HOME:-$HOME/.cache}/zim

# Download zimfw plugin manager if missing.
if [ ! -s ${ZIM_HOME}/zimfw.zsh ]; then
  curl -fsSL --create-dirs -o ${ZIM_HOME}/zimfw.zsh \
      https://github.com/zimfw/zimfw/releases/latest/download/zimfw.zsh
fi

# Install missing modules, and update ${ZIM_HOME}/init.zsh if missing or outdated.
if [[ ! ${ZIM_HOME}/init.zsh -nt ${ZDOTDIR:-$HOME}/.zimrc ]]; then
  source ${ZIM_HOME}/zimfw.zsh init
fi

stty -ixon
stty -ixoff

# Initialization code that may require console input (password prompts, [y/n]
# confirmations, etc.) must go above this block; everything else may go below.
if [[ -r "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh" ]]; then
  source "${XDG_CACHE_HOME:-$HOME/.cache}/p10k-instant-prompt-${(%):-%n}.zsh"
fi

# Options
setopt correct
unsetopt correctall
setopt no_nomatch
setopt rm_star_silent

platform=$(uname)

# add a couple homebrew paths for macos systems
if [ $platform = Darwin ]; then
  export PATH=/opt/homebrew/opt/llvm/bin:/opt/homebrew/opt/gnu-sed/libexec/gnubin:/opt/homebrew/opt/make/libexec/gnubin${PATH:+:${PATH}}
fi

export FZF_BASE=$HOME/.local/share/nvim/lazy/fzf
export PATH=~/.local/bin:/usr/local/bin${PATH:+:${PATH}}

# set the ssh agent socket path for linux
if [ $platform = Linux -a ! -S "$SSH_AUTH_SOCK" ]; then
  export SSH_AUTH_SOCK=$XDG_RUNTIME_DIR/ssh-agent.socket
fi

# Plugins
VI_MODE_SET_CURSOR=true
ZSH_TMUX_AUTOREFRESH=true
source ${ZIM_HOME}/init.zsh

zmodload zsh/complist

# Environment variables
export LANG=en_US.utf-8
export LC_ALL="$LANG"
export LESS=-MIRXF
export NINJA_STATUS="[%u/%r/%f %o/s %e] "
export COLORTERM=truecolor
if hash nvim 2>/dev/null; then
    export EDITOR=nvim
else
    export EDITOR=vim
fi

# Set up bindings
bindkey -M viins 'jk' vi-cmd-mode
bindkey -M vicmd 'k' history-substring-search-up
bindkey -M vicmd 'j' history-substring-search-down
bindkey -M menuselect '' reverse-menu-complete

bindkey -M vicmd 'v' visual-mode
bindkey -M vicmd 'V' visual-line-mode

autoload -U select-bracketed
zle -N select-bracketed
for m in visual viopp; do
    for c in {a,i}${(s..)^:-'()[]{}<>bB'}; do
        bindkey -M $m $c select-bracketed
    done
done

autoload -U select-quoted
zle -N select-quoted
for m in visual viopp; do
    for c in {a,i}{\',\",\`}; do
        bindkey -M $m $c select-quoted
    done
done


# aliases
alias glom="git log HEAD..origin/\$(git_main_branch)"
alias git_current_branch="git rev-parse --abbrev-ref HEAD"

# set some history options
setopt hist_expire_dups_first
#setopt hist_ignore_all_dups
setopt hist_reduce_blanks

# set some more options
setopt clobber # allow > redirection to truncate existing files

# Keep a ton of history.
HISTSIZE=200000
SAVEHIST=100000
HISTFILE=~/.zsh_history
export HISTIGNORE="ls:cd:cd -:pwd:exit:date:* --help"

# Completion
zstyle ':completion:*' accept-exact '*(N)'
zstyle ':completion:*' use-cache on
zstyle ':completion:*' cache-path ~/.zsh/cache
zstyle -e ':completion:*:default' list-colors 'reply=("${PREFIX:+=(#bi)($PREFIX:t)*==34=34}:${(s.:.)LS_COLORS}")';

# Make it easy to append your own customizations that override the above by
# loading all files from .zshrc.d directory. Also load all files in
# subdirectories of .zshrc.other.d to make it easy to symlink other castles
function source_dir {
    for dotfile in $1/*.zsh; do
        if [ -r "${dotfile}" ]; then
            source "${dotfile}"
        fi
    done
}
source_dir ~/.zshrc.d
for dir in ~/.zshrc.other.d/*; do
    source_dir $dir
done

# Dedupe the PATH environment variable
typeset -U PATH path

[[ ! -f ~/.p10k.zsh ]] || source ~/.p10k.zsh