Justfile

set shell := ["bash", "-euo", "pipefail", "-c"]

# Run pg_regress and then diff every expected output against results.
regress pg_version="pg18":
  #!/usr/bin/env bash
  set -euo pipefail
  cd "{{justfile_directory()}}"
  mkdir -p tests/pg_regress/results
  cargo pgrx regress "{{pg_version}}" --resetdb
  for expected in tests/pg_regress/expected/*.out; do
    file="$(basename "$expected")"
    result="tests/pg_regress/results/$file"
    if [ -f "$result" ]; then
      diff -u "$expected" "$result"
    fi
  done

test:
  cd {{justfile_directory()}}
  cargo test -v

# Profile cold/warm call latency.
# Example: just profile pg18
profile pg_version="pg18":
  #!/usr/bin/env bash
  set -euo pipefail
  cd "{{justfile_directory()}}"
  cargo pgrx start {{pg_version}}
  cargo pgrx install --features "{{pg_version}}" --no-default-features --release
  cargo pgrx connect {{pg_version}} < tests/profiling/setup_vs_exec.sql

# Profile a more realistic _pg.execute + JSON shaping workload.
# Example: just profile-pg-execute pg18
profile-pg-execute pg_version="pg18":
  #!/usr/bin/env bash
  set -euo pipefail
  cd "{{justfile_directory()}}"
  cargo pgrx start {{pg_version}}
  cargo pgrx install --features "{{pg_version}}" --no-default-features --release
  cargo pgrx connect {{pg_version}} < tests/profiling/pg_execute_workload.sql

# Start PostgREST against the local pgrx Postgres instance.
# Example: just postgrest
postgrest pg_version="pg18" api_port="3000" db_name="postgrest_demo":
  cd "{{justfile_directory()}}"
  ./examples/postgrest/run.sh "{{pg_version}}" "{{api_port}}" "{{db_name}}"

# Set up the streaming demo and continuously print inserted rows plus trigger output.
# Example: just streaming
streaming pg_version="pg18" db_name="streaming_demo":
  cd "{{justfile_directory()}}"
  ./examples/streaming/run.sh "{{pg_version}}" "{{db_name}}"

# Run the _pg.execute example that joins two tables, then queries a third.
# Example: just pg-execute
pg-execute pg_version="pg18" db_name="pg_execute_demo":
  cd "{{justfile_directory()}}"
  ./examples/pg_execute/run.sh "{{pg_version}}" "{{db_name}}"