CMakeLists.txt

cmake_minimum_required(VERSION 3.5)
project(iridium VERSION 5.0.1)

#----------------#
# Global options #
#----------------#
message(STATUS "------- Starting configuration ---------")
# Enabling C++14
set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

# Default build type
set(DEFAULT_BUILD_TYPE "Release")
# default static build without tests
set(STATIC ON CACHE BOOL "Link libraries statically")
# Organize targets into folders
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
set(CMAKE_SUPPRESS_REGENERATION ON)
set(CMAKE_SKIP_PACKAGE_ALL_DEPENDENCY ON)
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_MODULE_PATH})
set(COMMIT_ID_IN_VERSION ON CACHE BOOL "Include git commit # in Version")
set(BUILD_TESTS OFF CACHE BOOL "build tests")

# Tags the version for tests and betas, comment for release
# set(PROJECT_VERSION_TWEAK "heavytest")

#----------------#
# Cooking stuffs #
#----------------#
#get rid of "QT_QMAKE_EXECUTABLE not used by the project" in QtCreator
set(ignoreMe "${QT_QMAKE_EXECUTABLE}")

# Handle build types and set possible values of build type for cmake-gui
if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
  message(STATUS "Setting build type to '${DEFAULT_BUILD_TYPE}' as none was specified.")
  set(CMAKE_BUILD_TYPE "${DEFAULT_BUILD_TYPE}" CACHE STRING "Choose the type of build." FORCE)
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release")
endif()

# Output directories
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${CMAKE_BUILD_TYPE})
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)

# Compile tests on Debug
if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")
    set(BUILD_TESTS ON)
endif()

# Set version
find_package(BuildVersion REQUIRED)
# Threads
find_package(Threads)

#----------#
# includes #
#----------#
include_directories(include src external "${CMAKE_CURRENT_BINARY_DIR}/version")

if(APPLE)
    include_directories(SYSTEM /usr/include/malloc)
    enable_language(ASM)
endif()


#-----------#
# Platforms #
#-----------#
if(MSVC)
    include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src/Platform/Windows)
elseif(APPLE)
    set(CMAKE_OSX_DEPLOYMENT_TARGET 10.13)
    include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src/Platform/OSX)
    include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src/Platform/Posix)
else()
    include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src/Platform/Linux)
    include_directories(${CMAKE_CURRENT_SOURCE_DIR}/src/Platform/Posix)
endif()

set(STATIC ${MSVC} CACHE BOOL "Link libraries statically")


# // todo clean this mess...

if(MSVC)
    add_definitions("/bigobj /MP /W3 /GS- /D_CRT_SECURE_NO_WARNINGS /wd4996 /wd4345 /D_WIN32_WINNT=0x0600 /DWIN32_LEAN_AND_MEAN /DGTEST_HAS_TR1_TUPLE=0 /D_VARIADIC_MAX=8 /D__SSE4_1__")
    set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10485760")
    if(STATIC)
        foreach(VAR CMAKE_C_FLAGS_DEBUG CMAKE_CXX_FLAGS_DEBUG CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO CMAKE_C_FLAGS_RELEASE CMAKE_CXX_FLAGS_RELEASE)
            string(REPLACE "/MD" "/MT" ${VAR} "${${VAR}}")
        endforeach()
    endif()
    include_directories(SYSTEM ${CMAKE_CURRENT_SOURCE_DIR}/src/platform/msc)
else()
    if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
        # This option has no effect in glibc version less than 2.20.
        # Since glibc 2.20 _BSD_SOURCE is deprecated, this macro is recomended instead
        add_definitions("-D_DEFAULT_SOURCE -D_GNU_SOURCE")
    endif()
    set(ARCH native CACHE STRING "CPU to build for: -march value or default")
    if("${ARCH}" STREQUAL "default")
        set(ARCH_FLAG "")
    else()
        set(ARCH_FLAG "-march=${ARCH}")
    endif()
    set(WARNINGS "-Wall -Wextra -Wpointer-arith -Wundef -Wvla -Wwrite-strings -Wno-error=extra -Wno-error=unused-function -Wno-error=deprecated-declarations -Wno-error=sign-compare -Wno-error=strict-aliasing -Wno-error=type-limits -Wno-unused-parameter -Wno-error=unused-variable -Wno-error=undef -Wno-error=uninitialized -Wno-error=unused-result")
    if(CMAKE_C_COMPILER_ID STREQUAL "Clang" OR CMAKE_C_COMPILER_ID STREQUAL "AppleClang")
        set(WARNINGS "${WARNINGS} -Wno-error=mismatched-tags -Wno-error=null-conversion -Wno-overloaded-shift-op-parentheses -Wno-error=shift-count-overflow -Wno-error=tautological-constant-out-of-range-compare -Wno-error=unused-private-field -Wno-error=unneeded-internal-declaration -Wno-error=unused-function -Wno-error=missing-braces -Wno-unused-lambda-capture -Wno-exceptions -Wno-unknown-pragmas")
    else()
        set(WARNINGS "${WARNINGS} -Wlogical-op -Wno-error=maybe-uninitialized -Wno-error=clobbered -Wno-error=unused-but-set-variable")
    endif()
    if(MINGW)
        set(WARNINGS "${WARNINGS} -Wno-error=unused-value")
        set(MINGW_FLAG "-DWIN32_LEAN_AND_MEAN")
        include_directories(SYSTEM src/platform/mingw)
    else()
        set(MINGW_FLAG "")
    endif()
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS 5.1))
        set(WARNINGS "${WARNINGS} -Wno-error=odr")
    endif()
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND (CMAKE_C_COMPILER_VERSION VERSION_GREATER 6))
        set(WARNINGS "${WARNINGS} -Wno-logical-op -Wno-error=terminate -Wno-error=init-self")
    endif()
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND (CMAKE_C_COMPILER_VERSION VERSION_GREATER 7))
        set(WARNINGS "${WARNINGS} -Wno-format-truncation -Wno-implicit-fallthrough -Wno-error=stringop-overflow")
    endif()
    set(C_WARNINGS "-Waggregate-return -Wnested-externs -Wold-style-definition -Wstrict-prototypes")
    set(CXX_WARNINGS "-Wno-reorder -Wno-missing-field-initializers")
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c11 ${MINGW_FLAG} ${WARNINGS} ${C_WARNINGS} ${ARCH_FLAG} -maes")
    if(NOT APPLE)
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
    endif()
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${MINGW_FLAG} ${WARNINGS} ${CXX_WARNINGS} ${ARCH_FLAG} -maes")
    if(APPLE)
        set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DGTEST_HAS_TR1_TUPLE=0")
        #  Disable ld boost warnings
        set(CMAKE_CXX_VISIBILITY_PRESET hidden)
    endif()
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.8))
        set(DEBUG_FLAGS "-g3 -Og -gdwarf-4 -fvar-tracking -fvar-tracking-assignments -fno-inline -fno-omit-frame-pointer")
    else()
        set(DEBUG_FLAGS "-g3 -O0 -fno-omit-frame-pointer")
    endif()

    if(CMAKE_C_COMPILER_ID STREQUAL "Clang" OR CMAKE_C_COMPILER_ID STREQUAL "AppleClang")
        set(DEBUG_FLAGS "${DEBUG_FLAGS} -Wno-delete-non-virtual-dtor")
    endif()

    # release flags
    set(RELEASE_FLAGS "-Ofast -DNDEBUG -Wno-unused-variable -Wno-uninitialized -Wno-unused-function -Wno-sign-compare")
    if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_C_COMPILER_VERSION VERSION_LESS 4.8))
        set(RELEASE_FLAGS "${RELEASE_FLAGS} -Wno-strict-aliasing -Wno-unused-but-set-variable")
    endif()
    if(CMAKE_C_COMPILER_ID STREQUAL "Clang" OR CMAKE_C_COMPILER_ID STREQUAL "AppleClang")
        set(RELEASE_FLAGS "${RELEASE_FLAGS} -Wno-undef -Wno-delete-non-virtual-dtor -Wno-unused-private-field -Wno-unused-lambda-capture -Wno-exceptions")
    endif()

    if(NOT APPLE)
        # There is a clang bug that does not allow to compile code that uses AES-NI intrinsics if -flto is enabled
        if (CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_SYSTEM_NAME STREQUAL "Linux"
                AND CMAKE_BUILD_TYPE STREQUAL "Release" AND ((CMAKE_C_COMPILER_VERSION VERSION_GREATER 4.9) OR (CMAKE_C_COMPILER_VERSION VERSION_EQUAL 4.9)))
            # On linux, to build in lto mode, check that ld.gold linker is used: 'update-alternatives --install /usr/bin/ld ld /usr/bin/ld.gold HIGHEST_PRIORITY'
            set(CMAKE_AR gcc-ar)
            set(CMAKE_RANLIB gcc-ranlib)
        endif()
        #set(RELEASE_FLAGS "${RELEASE_FLAGS} -flto")
    else() # remove ranlib complaining for no symbols
        set(CMAKE_C_ARCHIVE_CREATE   "<CMAKE_AR> Scr <TARGET> <LINK_FLAGS> <OBJECTS>")
        set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> Scr <TARGET> <LINK_FLAGS> <OBJECTS>")
        set(CMAKE_C_ARCHIVE_FINISH   "<CMAKE_RANLIB> -no_warning_for_no_symbols -c <TARGET>")
        set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> -no_warning_for_no_symbols -c <TARGET>")
    endif()
    #if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND NOT MINGW)
    #  set(RELEASE_FLAGS "${RELEASE_FLAGS} -fno-fat-lto-objects")
    #endif()
    set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${DEBUG_FLAGS}")
    set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${DEBUG_FLAGS}")
    set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${RELEASE_FLAGS}")
    set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} ${RELEASE_FLAGS}")
    if(STATIC AND NOT APPLE)
        set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc -static-libstdc++")
    endif()
endif()

set(Boost_NO_BOOST_CMAKE ON)
set(BOOST_IGNORE_SYSTEM_PATHS_DEFAULT OFF)
option(BOOST_IGNORE_SYSTEM_PATHS "Ignore boost system paths for local boost installation" ${BOOST_IGNORE_SYSTEM_PATHS_DEFAULT})
if (${BOOST_IGNORE_SYSTEM_PATHS} STREQUAL "ON")
  set(Boost_NO_SYSTEM_PATHS TRUE)
endif()
if(STATIC)
    set(Boost_USE_STATIC_LIBS ON)
    set(Boost_USE_STATIC_RUNTIME ON)
endif()
find_package(Boost 1.68 REQUIRED COMPONENTS atomic system filesystem thread date_time chrono regex serialization program_options)
include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
if(MINGW)
    set(Boost_LIBRARIES "${Boost_LIBRARIES};ws2_32;mswsock")
elseif(APPLE)
    set(Boost_LIBRARIES "${Boost_LIBRARIES}")
elseif(NOT MSVC)
    set(Boost_LIBRARIES "${Boost_LIBRARIES};rt")
endif()


#---------#
# Summary #
#---------#

message(STATUS "========== building ${PROJECT_NAME} Core version : ${PROJECT_VERSION} build ${PROJECT_VERSION_TWEAK} ${CMAKE_BUILD_TYPE} =======")
message(STATUS "Compiler : ${CMAKE_CXX_COMPILER_ID} version ${CMAKE_CXX_COMPILER_VERSION}")
message(STATUS "Version : ${VERSION}")
message(STATUS "Revision : ${COMMIT_ID}")
message(STATUS "Arch : ${ARCH}")
message(STATUS "Boost version : ${Boost_LIB_VERSION}")
message(STATUS "Link libraries statically : ${STATIC}" )
message(STATUS "Build tests : " ${BUILD_TESTS})
message(STATUS "----------------------------------------------------------")
message(STATUS "C Flags ${CMAKE_C_FLAGS_RELEASE}")
message(STATUS "CXX Flags ${CMAKE_CXX_FLAGS_RELEASE}")

#----------#
# sources  #
#----------#

add_subdirectory(external)
add_subdirectory(src)

if(BUILD_TESTS)
  add_subdirectory(tests)
else()
  configure_file(${CMAKE_CURRENT_SOURCE_DIR}/CTestCustom.cmake ${CMAKE_CURRENT_BINARY_DIR})
endif()