mps/flake.nix at main · integrated-reasoning/mps · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
{
  description = "A fast MPS parser written in Rust";

  inputs = {
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/*.tar.gz";
    naersk.url = "github:nix-community/naersk";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = inputs: with inputs;
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ rust-overlay.overlays.default ];
        };
        inherit (pkgs) lib;

        naersk' = pkgs.callPackage naersk { };

        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = [ "llvm-tools-preview" ];
        };

        additionalDevTools = [
          rustToolchain
          pkgs.cargo-all-features
          pkgs.cargo-deny
          pkgs.cargo-insta
          pkgs.cargo-nextest
          pkgs.rustfmt
          pkgs.clippy
        ] ++ lib.optionals pkgs.stdenv.isLinux [
          pkgs.cargo-llvm-cov
        ];

        buildDependencies = lib.optionals pkgs.stdenv.isDarwin [
          pkgs.apple-sdk_15
        ];

        mps = naersk'.buildPackage {
          src = ./.;
          buildInputs = buildDependencies;
          cargoBuildOptions = x: x ++ [ "--features" "cli" ];
        };
      in
      rec
      {
        packages = {
          default = mps;
        };

        devShell = pkgs.mkShell {
          buildInputs = additionalDevTools ++ buildDependencies;
        };

        image = pkgs.dockerTools.buildLayeredImage {
          name = "mps";
          tag = "latest";
          maxLayers = 120;
          contents = [
            packages.default
          ];
          config.Cmd = [ "mps" ];
        };
      }
    );
}