incognia-api-java/build.gradle at master · inloco/incognia-api-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'com.diffplug.spotless' version '8.4.0'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'io.github.goooler.shadow' version '8.1.8' apply false
}

group = "com.incognia"
version = "3.17.0"

def projectVersion = version.toString()
def testJavaVersion = providers.gradleProperty("testJavaVersion").orElse("8").get().toInteger()
def projectVersionFile = layout.projectDirectory.file("src/main/java/com/incognia/api/ProjectVersion.java")

tasks.register("createProjectVersionFile") {
    outputs.file(projectVersionFile)
    doLast {
        projectVersionFile.asFile.text =
"""package com.incognia.api;

public class ProjectVersion {
  public static final String PROJECT_VERSION = "$projectVersion";
}
"""
    }
}

tasks.named('compileJava') {
    dependsOn(tasks.named("createProjectVersionFile"))
}

repositories {
    mavenCentral()
}

configurations {
    testCompileOnly.extendsFrom compileOnly
    testAnnotationProcessor.extendsFrom annotationProcessor
}

ext {
    lombokVersion = '1.18.44'
}

dependencies {
    compileOnly "org.projectlombok:lombok:$lombokVersion"
    annotationProcessor "org.projectlombok:lombok:$lombokVersion"
    implementation platform("com.squareup.okhttp3:okhttp-bom:5.3.2")
    implementation "com.squareup.okhttp3:okhttp"
    implementation "com.fasterxml.jackson.core:jackson-databind:2.21.2"

    testImplementation 'com.auth0:java-jwt:4.5.1'
    testImplementation 'commons-io:commons-io:2.21.0'
    testImplementation 'org.assertj:assertj-core:3.27.7'
    testImplementation 'org.mockito:mockito-core:4.11.0'
    testImplementation 'org.mockito:mockito-inline:4.11.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:4.11.0'
    testImplementation "com.squareup.okhttp3:mockwebserver"
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.2'
    testImplementation "org.junit.jupiter:junit-jupiter-params:5.10.2"
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
    }
    withSourcesJar()
    withJavadocJar()
}

compileJava {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

spotless {
    java {
        googleJavaFormat()
    }
}

def isShadow = project.findProperty("shadow") == "true"
if (isShadow) {
    apply plugin: 'io.github.goooler.shadow'
    shadowJar {
        archiveClassifier.set('')
        relocate 'okhttp3', 'incognia.shadow.okhttp3'
        relocate 'com.fasterxml', 'incognia.shadow.com.fasterxml'
        relocate 'com.auth0', 'incognia.shadow.com.auth0'
    }
}

tasks.named('test', Test) {
    useJUnitPlatform()
    javaLauncher = javaToolchains.launcherFor {
        languageVersion = JavaLanguageVersion.of(testJavaVersion)
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) { publication ->
            if (isShadow) {
                publication.artifactId = 'incognia-api-client-shaded'
                artifact shadowJar
            } else {
                from components.java
                publication.artifactId = 'incognia-api-client'
            }
            pom {
                name = 'Incognia API Client'
                description = "Java client library for Incognia's API"
                url = 'https://github.com/inloco/incognia-api-java'
                developers {
                    developer {
                        id = 'racevedoo'
                        name = 'Rafael Acevedo'
                        email = 'rafael.acevedo@incognia.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/inloco/incognia-api-java.git'
                    developerConnection = 'scm:git:ssh://github.com/inloco/incognia-api-java.git'
                    url = 'https://github.com/inloco/incognia-api-java'
                }
                licenses {
                    license {
                        name = 'MIT License'
                        url = 'http://www.opensource.org/licenses/mit-license.php'
                    }
                }
            }
        }
    }
    repositories {
        maven {
            url = uri('s3://repo.incognia.com/java')
            authentication {
                awsIm(AwsImAuthentication)
            }
        }
    }
}

tasks.withType(PublishToMavenLocal) {
    dependsOn jar
}