beefweb/CMakeLists.txt at master · hyperblast/beefweb · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
cmake_minimum_required(VERSION 3.24)

# Use cmake scripts provided by boost, not the cmake itself
if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.30.0")
    cmake_policy(SET CMP0167 NEW)
endif()

project(
    beefweb
    VERSION 0.11
    HOMEPAGE_URL "https://github.com/hyperblast/beefweb"
)

set(PROJECT_VERSION_FINAL 0)

if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
    enable_language(OBJCXX)
endif()

set_property(GLOBAL PROPERTY USE_FOLDERS ON)

set(CMAKE_MODULE_PATH       "${CMAKE_CURRENT_SOURCE_DIR}/cmake;${CMAKE_MODULE_PATH}")
set(EXTLIB_SOURCE_DIR       "${CMAKE_CURRENT_SOURCE_DIR}/cpp/extlibs")
set(EXTLIB_INSTALL_DIR      "${CMAKE_CURRENT_BINARY_DIR}/cpp/extlibs-root")
set(EXTLIB_LICENSES_FILE    "${EXTLIB_SOURCE_DIR}/licenses.txt")

include(EnvInfo)
include(ProjectInfo)
include(Utils)

option(ENABLE_TESTS             "Build tests" OFF)
option(ENABLE_GIT_REV           "Include Git revision in produced binaries" OFF)
option(ENABLE_WERROR            "Treat warnings as errors" OFF)
option(ENABLE_LOCAL_LIBS        "Build with local libraries" ON)
option(ENABLE_JS                "Build JS parts" ON)

local_library_option(boost          ENABLE_LOCAL_BOOST "")
local_library_option(nljson         ENABLE_LOCAL_NLJSON "")
local_library_option(catch          ENABLE_LOCAL_CATCH "ENABLE_TESTS")
local_library_option(stringencoders ENABLE_LOCAL_STRINGENCODERS "")

if(OS_POSIX)
    if(NOT OS_MAC)
        option(ENABLE_STATIC_STDLIB "Build with static libstdc++" OFF)
    endif()

    option(ENABLE_DEADBEEF "Build plugin for deadbeef player" ON)
    option(
        DEADBEEF_INSTALL_INTO_ROOT
        "Install into CMAKE_INSTALL_PREFIX instead of CMAKE_INSTALL_PREFIX/lib/deadbeef. Useful for generating archive package."
        OFF
    )

    local_library_option(deadbeef ENABLE_LOCAL_DEADBEEF "ENABLE_DEADBEEF")

    if(DEADBEEF_INSTALL_INTO_ROOT)
        set(DEADBEEF_INSTALL_DIR ".")
    else()
        set(DEADBEEF_INSTALL_DIR "lib/deadbeef")
    endif()
endif()

if(OS_WINDOWS OR OS_MAC)
    option(ENABLE_FOOBAR2000 "Build plugin for foobar2000 player" ON)

    if(ENABLE_FOOBAR2000)
        local_library(foosdk)
    endif()
endif()

if(OS_WINDOWS)
    local_library_option(zlib ENABLE_LOCAL_ZLIB "")
endif()

if(ENABLE_GIT_REV)
    detect_git_revision(PROJECT_GIT_REV)
else()
    set(PROJECT_GIT_REV unknown)
endif()

if(IS_MULTI_CONFIG)
    set(WEBUI_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/js/webui/$<CONFIG>)
    file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/build_config.json "{\"isMultiConfig\":true}")
else()
    set(WEBUI_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/js/webui/output)
    file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/build_config.json "{\"isMultiConfig\":false}")
endif()

print_status()

add_subdirectory(cpp)

if(ENABLE_JS)
    add_subdirectory(js)
endif()

include(Packages)
include(CPack)