compartmap/flake.nix at master · huishenlab/compartmap · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
{
  description = "Flake to get compartmap development environment";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  inputs.flake-utils.url = "github:numtide/flake-utils";

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = nixpkgs.legacyPackages.${system};

      Depends = with pkgs.rPackages; [
        BiocSingular
        bsseq
        csaw
        HDF5Array
        RaggedExperiment
        SummarizedExperiment
      ];

      Imports = with pkgs.rPackages; [
        BiocParallel
        DelayedArray
        DelayedMatrixStats
        GenomicRanges
        ggplot2
        impute
        Matrix
        parallelly
        reshape2
        RMTstat
        rtracklayer
        scales
      ];

      Suggests = with pkgs.rPackages; [
        BiocStyle
        knitr
        markdown
        minfi
        minfiData
        Rcpp
        rmarkdown
        roxygen2
        SingleCellExperiment
        testthat
      ];

      rDevDeps = with pkgs.rPackages; [
        TxDb_Hsapiens_UCSC_hg19_knownGene
        TxDb_Hsapiens_UCSC_hg38_knownGene
        TxDb_Mmusculus_UCSC_mm9_knownGene
        TxDb_Mmusculus_UCSC_mm10_knownGene
        biocthis
        covr
        devtools
        DT
        htmltools
        styler
        usethis
      ];

      sysDeps = with pkgs; [
        R
      ];

      tex = (pkgs.texlive.combine {
        inherit (pkgs.texlive) scheme-medium
        inconsolata
        xkeyval
        etoolbox;
      });
      sysDevDeps = with pkgs; [
        air-formatter
        checkbashisms
        html-tidy
        tex
      ];

      # default package
      rDeps = [ Depends Imports Suggests ];
      compartmap = pkgs.rPackages.buildRPackage {
        name = "compartmap";
        src = self;
        nativeBuildInputs = sysDeps;
        propagatedBuildInputs = rDeps;
      };
      # Create R development environment with compartmap and other useful libraries
      rvenv = pkgs.rWrapper.override {
        packages = rDeps ++ rDevDeps ++ sysDeps ++ sysDevDeps;
      };
    in {
      packages.default = compartmap;
      devShells.default = pkgs.mkShell {
          buildInputs = rDeps ++ rDevDeps ++ sysDeps ++ sysDevDeps;
          inputsFrom = pkgs.lib.singleton compartmap;
          packages = pkgs.lib.singleton rvenv;
      };
    });
}