hbci4java/build.gradle at master · hbci4j/hbci4java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
plugins {
  id 'java'
  id 'eclipse'
  id 'java-library-distribution'
  id 'com.intershop.gradle.jaxb' version '7.0.2'
  id 'com.vanniktech.maven.publish' version '0.34.0'
}

repositories {
  mavenCentral()
}

configurations {
  jaxb
}

eclipse {
  classpath {
    downloadSources = true
  }
}

java {
  sourceCompatibility = JavaVersion.VERSION_17
  withSourcesJar()
  // https://github.com/vanniktech/gradle-maven-publish-plugin/issues/772
  // Javadoc wird durch das Plugin konfiguriert. Andernfalls gibt es eine Fehlermeldung
  //  withJavadocJar()
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

test {
  testLogging.showStandardStreams=false

  beforeTest { descriptor ->
     logger.lifecycle("Running test: " + descriptor)
  }
}

jar.doFirst {
  manifest {
    attributes(
      "Implementation-Version": archiveVersion,
      "Specification-Version": archiveVersion
    )
  }
}

tasks.withType(Javadoc).configureEach {
  failOnError = false
  options.addStringOption('Xdoclint:none', '-quiet')
  options.encoding = 'UTF-8'
  options.charSet = 'UTF-8'
}

tasks.named('sourcesJar') {
  // Kann sich der User selbst generieren
  exclude 'org/kapott/hbci/sepa/jaxb/**'
}

jar {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

def xsdDir  = file('src/main/resources')
def jaxbOut = file("${layout.buildDirectory.get()}/generated/jaxb")
def jaxbPackage = 'org.kapott.hbci.sepa.jaxb.'
jaxb {
  javaGen {
    camt05200101 { schema = file(new File(xsdDir,'/camt.052.001.01.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_01' }
    camt05200102 { schema = file(new File(xsdDir,'/camt.052.001.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_02' }
    camt05200103 { schema = file(new File(xsdDir,'/camt.052.001.03.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_03' }
    camt05200104 { schema = file(new File(xsdDir,'/camt.052.001.04.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_04' }
    camt05200105 { schema = file(new File(xsdDir,'/camt.052.001.05.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_05' }
    camt05200106 { schema = file(new File(xsdDir,'/camt.052.001.06.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_06' }
    camt05200107 { schema = file(new File(xsdDir,'/camt.052.001.07.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_07' }
    camt05200108 { schema = file(new File(xsdDir,'/camt.052.001.08.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_08' }
    camt05200109 { schema = file(new File(xsdDir,'/camt.052.001.09.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'camt_052_001_09' }

    pain00100102 { schema = file(new File(xsdDir,'/pain.001.001.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_001_02' }
    pain00100103 { schema = file(new File(xsdDir,'/pain.001.001.03.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_001_03' }
    pain00100109 { schema = file(new File(xsdDir,'/pain.001.001.09.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_001_09' }
    pain00100111 { schema = file(new File(xsdDir,'/pain.001.001.11.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_001_11' }
    pain00100202 { schema = file(new File(xsdDir,'/pain.001.002.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_002_02' }
    pain00100203 { schema = file(new File(xsdDir,'/pain.001.002.03.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_002_03' }
    pain00100303 { schema = file(new File(xsdDir,'/pain.001.003.03.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_001_003_03' }

    pain00200110 { schema = file(new File(xsdDir,'/pain.002.001.10.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_002_001_10' }
    pain00200111 { schema = file(new File(xsdDir,'/pain.002.001.11.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_002_001_11' }
    pain00200112 { schema = file(new File(xsdDir,'/pain.002.001.12.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_002_001_12' }
    pain00200113 { schema = file(new File(xsdDir,'/pain.002.001.13.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_002_001_13' }
    pain00200114 { schema = file(new File(xsdDir,'/pain.002.001.14.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_002_001_14' }

    pain00800101 { schema = file(new File(xsdDir,'/pain.008.001.01.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_001_01' }
    pain00800102 { schema = file(new File(xsdDir,'/pain.008.001.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_001_02' }
    pain00800108 { schema = file(new File(xsdDir,'/pain.008.001.08.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_001_08' }
    pain00800110 { schema = file(new File(xsdDir,'/pain.008.001.10.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_001_10' }
    pain00800201 { schema = file(new File(xsdDir,'/pain.008.002.01.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_002_01' }
    pain00800202 { schema = file(new File(xsdDir,'/pain.008.002.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_002_02' }
    pain00800302 { schema = file(new File(xsdDir,'/pain.008.003.02.xsd')); outputDir = jaxbOut; packageName = jaxbPackage + 'pain_008_003_02' }
  }
}
sourceSets.main.java.srcDirs += 'build/generated/jaxb'
compileJava.dependsOn 'jaxb'

mavenPublishing {
    // true beduetet, dass das Artifact automatisch veröffentlicht wird.
    // Wenn man es auf "false setzt, muss man zu "Deployments" im "Maven Central Portal" und dort auf "Publish" klicken.
    // https://vanniktech.github.io/gradle-maven-publish-plugin/central/#uploading-with-automatic-publishing
    publishToMavenCentral(true)
    signAllPublications()
    coordinates(project.groupId, project.name, project.version.toString())

    pom {
        name = "HBCI4j"
        description = 'HBCI4j - Home Banking Computer Interface for Java'
        inceptionYear = "2020"
        url         = 'https://github.com/hbci4j/hbci4java'

        licenses {
          license {
            name = 'GNU Lesser General Public License'
            url  = 'https://www.gnu.org/licenses/old-licenses/lgpl-2.1'
          }
        }

        developers {
          developer {
            name = 'Olaf Willuhn'
            email = 'github@willuhn.de'
          }
          developer {
            name = 'Janning Vygen'
            email = 'vygen@kicktipp.de'
          }
        }
        scm {
          url                 = 'https://github.com/hbci4j/hbci4java'
          connection          = 'scm:git:git://github.com/hbci4j/hbci4java.git'
          developerConnection = 'scm:git:ssh://git@github.com/hbci4j/hbci4java.git'
        }
      }
    }

tasks.withType(PublishToMavenRepository).configureEach {
    dependsOn tasks.test
    dependsOn tasks.tag
}

tasks.withType(PublishToMavenLocal).configureEach {
    dependsOn tasks.test
}

def tagName = "${project.name}-${project.version}"
tasks.register("createTag", Exec) {
  workingDir project.rootDir
  commandLine 'git', 'tag', tagName
}
tasks.register("pushTag", Exec) {
  workingDir project.rootDir
  commandLine 'git', 'push', 'origin', tagName
}

tasks.register('tag') {
    dependsOn 'createTag', 'pushTag'
}


dependencies {
  implementation 'jakarta.xml.bind:jakarta.xml.bind-api:4.0.2'
  implementation 'org.glassfish.jaxb:jaxb-runtime:4.0.5'
  testImplementation 'junit:junit:4.+'
}