Hooks: use the appropriate Cabal unit ID

This commit updates the logic in Distribution.Client.Dependency,
namely addDefaultSetupDependencies, to add an implicit Cabal dependency
for the custom setup stanza of packages with build-type: Hooks.

This ensures we always pick a version of Cabal that is compatible with
whatever other libraries the custom-setup stanza depends on (such as
Cabal-hooks).

Test in T11331.

Fixes #11331

Author: sheaf

cabal-install/src/Distribution/Client/Dependency.hs

@@ -637,8 +637,17 @@ addDefaultSetupDependencies defaultSetupDeps params =
               { PD.packageDescription =
                   pkgdesc
                     { PD.setupBuildInfo =
+                        -- See 'addCabalDepForHooks' for an explanation of
+                        -- what is going on here.
                         case PD.setupBuildInfo pkgdesc of
-                          Just sbi -> Just sbi
+                          Just sbi ->
+                            let
+                              sbi' =
+                                case PD.buildType pkgdesc of
+                                  PD.Hooks -> addCabalDepForHooks sbi
+                                  _ -> sbi
+                             in
+                              Just sbi'
                           Nothing -> case defaultSetupDeps srcpkg of
                             Nothing -> Nothing
                             Just deps
@@ -657,6 +666,26 @@ addDefaultSetupDependencies defaultSetupDeps params =
         gpkgdesc = srcpkgDescription srcpkg
         pkgdesc = PD.packageDescription gpkgdesc
 
+-- | Add an implicit dependency on @Cabal@ for a @build-type: Hooks@ package
+-- that doesn't explicitly depend on @Cabal@. Rationale: we need the @Cabal@
+-- library in order to compile @main = defaultMainWithSetupHooks setupHooks@.
+--
+-- This ensures the solver picks a consistent version of @Cabal@ when other
+-- packages in the @setup-depends@ stanza depend on @Cabal@.
+-- See https://github.com/haskell/cabal/issues/11331.
+--
+-- NB: don't do this for @build-type: Custom@, as it is possible for such
+-- packages to not depend on @Cabal@ at all (although basically unheard of
+-- in practice).
+addCabalDepForHooks :: PD.SetupBuildInfo -> PD.SetupBuildInfo
+addCabalDepForHooks sbi@(PD.SetupBuildInfo{PD.setupDepends = deps})
+  | any ((== cabalPkgName) . depPkgName) deps =
+      sbi
+  | otherwise =
+      sbi{PD.setupDepends = Dependency cabalPkgName anyVersion mainLibSet : deps}
+  where
+    cabalPkgName = mkPackageName "Cabal"
+
 -- | If a package has a custom setup then we need to add a setup-depends
 -- on Cabal.
 addSetupCabalMinVersionConstraint

cabal-testsuite/PackageTests/SetupHooks/T11331/Cabal-bad/Cabal.cabal

@@ -0,0 +1,6 @@
+cabal-version: 2.4
+name: Cabal
+version: 3.16.666.0
+library
+  default-language: Haskell2010
+  build-depends: stub == 0.1

cabal-testsuite/PackageTests/SetupHooks/T11331/Cabal-good/Cabal.cabal

@@ -0,0 +1,10 @@
+cabal-version: 2.4
+name: Cabal
+version: 3.16.777.0
+library
+  default-language: Haskell2010
+  build-depends: base, stub == 0.2
+  exposed-modules:
+    Distribution.Simple.SetupHooks
+    Distribution.Simple
+  hs-source-dirs: src

cabal-testsuite/PackageTests/SetupHooks/T11331/Cabal-good/src/Distribution/Simple.hs

@@ -0,0 +1,13 @@
+module Distribution.Simple ( defaultMainWithSetupHooks ) where
+
+import System.Exit ( exitFailure )
+import Distribution.Simple.SetupHooks ( SetupHooks )
+
+defaultMainWithSetupHooks :: SetupHooks -> IO ()
+defaultMainWithSetupHooks _ = do
+  putStrLn "Chosen GOOD Cabal"
+  exitFailure
+  -- NB: we call 'exitFailure' here so that cabal-install, who is invoking
+  -- this code thinking it is building the package, doesn't try to proceed
+  -- when actually we haven't done anything (e.g. try to read a package
+  -- description file).

cabal-testsuite/PackageTests/SetupHooks/T11331/Cabal-good/src/Distribution/Simple/SetupHooks.hs

@@ -0,0 +1,3 @@
+module Distribution.Simple.SetupHooks where
+
+data SetupHooks = SetupHooks

cabal-testsuite/PackageTests/SetupHooks/T11331/Setup.hs

@@ -0,0 +1,14 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+
+module Main where
+
+-- Cabal
+import Distribution.Simple ( defaultMainWithSetupHooks )
+
+-- T11331
+import SetupHooks ( setupHooks )
+
+--------------------------------------------------------------------------------
+
+main :: IO ()
+main = defaultMainWithSetupHooks setupHooks

cabal-testsuite/PackageTests/SetupHooks/T11331/SetupHooks.hs

@@ -0,0 +1,4 @@
+module SetupHooks (setupHooks) where
+
+-- fancy-hooks
+import FancyHooks (setupHooks)

cabal-testsuite/PackageTests/SetupHooks/T11331/T11331.cabal

@@ -0,0 +1,18 @@
+cabal-version:       3.14
+name:                T11331
+version:             0.1.0.0
+synopsis:            Test for Cabal bug 11331
+license:             BSD-3-Clause
+author:              NA
+maintainer:          NA
+category:            Testing
+build-type:          Hooks
+
+custom-setup
+  setup-depends: fancy-hooks
+
+library
+  default-language: Haskell2010
+  build-depends: stub == 0.1
+
+-- See cabal.test.hs for explanation of this test.

cabal-testsuite/PackageTests/SetupHooks/T11331/cabal.project

@@ -0,0 +1 @@
+packages: .

cabal-testsuite/PackageTests/SetupHooks/T11331/cabal.test.hs

@@ -0,0 +1,56 @@
+import Test.Cabal.Prelude
+
+{- Test for https://github.com/haskell/cabal/issues/11331
+
+This test works by having a package database with two Cabal libraries in it,
+a good one (Cabal-good) and a poisoned one (Cabal-bad).
+
+Cabal-good depends on stub == 0.2 and Cabal-bad depends on stub == 0.1.
+
+Moreover, we have a fancy-hooks package in the package database, that has been
+built against Cabal-good.
+
+T11331 has the following Cabal file:
+
+  T11331.setup --> fancy-hooks
+  T11331.lib   --> stub == 0.1
+
+The test checks that, for the setup component, we correctly use Cabal-good
+and not Cabal-bad, as only Cabal-good is compatible with fancy-hooks (correct
+ABI hash of Cabal dependency).
+-}
+main :: IO ()
+main = cabalTest $ recordMode DoNotRecord $ withPackageDb $ do
+  -- Build good package set 'fancy-hooks -> Cabal-good -> stub-0.2' first.
+  withDirectory "stub-0.2" $ do
+    setup "configure" []
+    setup "build" []
+    setup "register" ["--inplace"]
+  withDirectory "Cabal-good" $ do
+    setup "configure" []
+    setup "build" []
+    setup "register" ["--inplace"]
+  withDirectory "fancy-hooks" $ do
+    setup "configure" []
+    setup "build" []
+    setup "register" ["--inplace"]
+
+  -- Now build bad package set 'Cabal-bad -> stub-0.1'.
+  withDirectory "stub-0.1" $ do
+    setup "configure" []
+    setup "build" []
+    setup "register" ["--inplace"]
+  withDirectory "Cabal-bad" $ do
+    setup "configure" []
+    setup "build" []
+    setup "register" ["--inplace"]
+
+  -- Now try to build 'T11331' with cabal-install, using the package database
+  -- that we carefully crafted above. This tests that cabal-install picks
+  --  'Cabal-good' for the setup component of 'T11331', otherwise we will fail.
+  dbDir <- testPackageDbDir <$> getTestEnv
+
+  -- This fails because the fake Cabal-good defaultMain doesn't do anything
+  -- except print "Chosen GOOD Cabal".
+  res <- fails $ cabal' "build" [ "--package-db=" ++ dbDir, "T11331" ]
+  assertOutputContains "Chosen GOOD Cabal" res