Hooks: use the appropriate Cabal unit ID

This commit updates the logic in SetupWrapper for determining which
installed Cabal unit ID to use. When we are compiling a package with
build-type Hooks via an external Setup executable, we need to add a
dependency on Cabal. However, we must be sure to use the same version of
Cabal that the Cabal-hooks dependency depends on, to avoid #11331.

Fixes #11331

Author: sheaf

cabal-install/src/Distribution/Client/SetupWrapper.hs

@@ -908,8 +908,22 @@ getExternalSetupMethod verbosity options pkg bt = do
         [] ->
           dieWithException verbosity $ InstalledCabalVersion (packageName pkg) (useCabalVersion options)
         pkgs ->
-          let ipkginfo = fromMaybe err $ safeHead . snd . bestVersion fst $ pkgs
-              err = error "Distribution.Client.installedCabalVersion: empty version list"
+          let ipkginfo
+                -- If using build-type: Hooks, pick the Cabal unit Id that is
+                -- a dependency of Cabal-hooks (#11331).
+                --
+                -- This is not very elegant, but the alternative of adding a
+                -- Cabal dependency BEFORE solving is not appropriate, because
+                -- we only need Cabal to compile Setup.hs. It would be wrong to
+                -- impose a Cabal dependency in the general case
+                -- (e.g. compiling an external Hooks executable).
+                | bt == Hooks
+                , Just (cabalHooksCompId, _) <- find (isCabalHooksPkgId . snd) (useDependencies options)
+                , Just cabalHooksIPI <- PackageIndex.lookupComponentId index cabalHooksCompId
+                , Just cabalIPI <- find (isCabalPkgId . IPI.sourcePackageId) $ mapMaybe (PackageIndex.lookupUnitId index) (IPI.depends cabalHooksIPI)
+                = cabalIPI
+                | let err = error "Distribution.Client.installedCabalVersion: empty version list"
+                = fromMaybe err $ safeHead . snd . bestVersion fst $ pkgs
            in return
                 ( packageVersion ipkginfo
                 , Just . IPI.installedComponentId $ ipkginfo
@@ -1166,6 +1180,7 @@ getExternalSetupMethod verbosity options pkg bt = do
               hPutStr logHandle output
         return $ i setupProgFile
 
-isCabalPkgId, isBasePkgId :: PackageIdentifier -> Bool
+isCabalPkgId, isCabalHooksPkgId, isBasePkgId :: PackageIdentifier -> Bool
 isCabalPkgId (PackageIdentifier pname _) = pname == mkPackageName "Cabal"
+isCabalHooksPkgId (PackageIdentifier pname _) = pname == mkPackageName "Cabal-hooks"
 isBasePkgId (PackageIdentifier pname _) = pname == mkPackageName "base"

cabal-testsuite/PackageTests/SetupHooks/T11331/SetupHooks.hs

@@ -0,0 +1,36 @@
+{-# LANGUAGE CPP #-}
+{-# LANGUAGE OverloadedRecordDot #-}
+
+module SetupHooks (setupHooks) where
+
+-- Cabal
+import           Distribution.Simple.Flag (fromFlag)
+import           Distribution.Simple.Setup (CommonSetupFlags (..))
+import qualified Distribution.Simple.Utils as Utils
+import           Distribution.Types.LocalBuildConfig (PackageBuildDescr (..))
+import           Distribution.Verbosity
+
+-- Cabal-hooks
+import qualified Distribution.Simple.SetupHooks as SetupHooks
+
+--------------------------------------------------------------------------------
+
+setupHooks :: SetupHooks.SetupHooks
+setupHooks = SetupHooks.noSetupHooks {
+      SetupHooks.configureHooks = myConfigureHooks
+    }
+
+myConfigureHooks :: SetupHooks.ConfigureHooks
+myConfigureHooks = SetupHooks.noConfigureHooks {
+      SetupHooks.postConfPackageHook = Just myPostConfPackageHook
+    }
+
+myPostConfPackageHook :: SetupHooks.PostConfPackageInputs -> IO ()
+myPostConfPackageHook pcpi = do
+    Utils.notice verb "Hello, world"
+  where
+    verb = getVerbosity pcpi.packageBuildDescr
+
+getVerbosity :: PackageBuildDescr -> Verbosity
+getVerbosity pbd =
+  fromFlag pbd.configFlags.configCommonFlags.setupVerbosity

cabal-testsuite/PackageTests/SetupHooks/T11331/T11331.cabal.in

@@ -0,0 +1,18 @@
+cabal-version:       3.14
+name:                T11331
+version:             0.1.0.0
+synopsis:            Test for Cabal bug 11331
+license:             BSD-3-Clause
+author:              NA
+maintainer:          NA
+category:            Testing
+build-type:          Hooks
+
+custom-setup
+  setup-depends:
+    base, Cabal-hooks
+
+library
+  default-language: Haskell2010
+  -- The test adds "build-depends: containers" for a specific version of containers
+

cabal-testsuite/PackageTests/SetupHooks/T11331/cabal.project

@@ -0,0 +1 @@
+packages: .

cabal-testsuite/PackageTests/SetupHooks/T11331/cabal.test.hs

@@ -0,0 +1,31 @@
+import Test.Cabal.Prelude
+import System.Directory ( copyFile )
+
+-- Test for https://github.com/haskell/cabal/issues/11331
+main = cabalTest $ do
+
+  mpkgdb <- testPackageDbPath <$> getTestEnv
+  case mpkgdb of
+    Nothing -> skip "Cabal-hooks library unavailable."
+    Just _pkgdb -> recordMode DoNotRecord $ do
+
+      cwd <- testCurrentDir <$> getTestEnv
+      let
+        cabalTemplate = cwd </> "T11331.cabal.in"
+        cabalFile = cwd </> "T11331.cabal"
+
+      -- Add a dependency on 'containers == 0.7' to the library stanza.
+      liftIO $ do
+        copyFile cabalTemplate cabalFile
+        appendFile cabalFile "  build-depends: containers == 0.7"
+
+      cabal "v2-build" []
+
+      cabal "v2-clean" []
+
+      -- Change the dependency to 'containers == 0.8'
+      liftIO $ do
+        copyFile cabalTemplate cabalFile
+        appendFile cabalFile "  build-depends: containers == 0.8"
+
+      cabal "v2-build" []