dev-python/scanpy: add ebuild

Signed-off-by: Michael Schubert <mschu.dev@gmail.com>

Author: mschubert

dev-python/scanpy/Manifest

@@ -0,0 +1 @@
+DIST scanpy-1.11.3.tar.gz 14089431 BLAKE2B 10285f8b0fccee0d596081a82830126e452c23b376f2d9bb9b0a67b52cac730f9a2940fbf9765dc9d691e75d330b255d995b5c62c07244631fab2b70b21ef7db SHA512 973b161c3400d348a260b9cfba8ff13a5104f761565b3e3bdff88392ccfd57b1bd67beb2b16becbbd24cc7f87f5d3fe29e44e7dd32edd3b038e78d4278e33c6e

dev-python/scanpy/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<pkgmetadata>
+	<maintainer type="person">
+		<email>mschu.dev@gmail.com</email>
+		<name>Michael Schubert</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">scanpy</remote-id>
+		<remote-id type="github">scverse/scanpy</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/scanpy/scanpy-1.11.3.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Single-cell analysis in Python (scalable to >1M cells)"
+HOMEPAGE="https://github.com/scverse/scanpy"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/anndata-0.8[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.24.1[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-3.7.5[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.5.3[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.11.1[${PYTHON_USEDEP}]
+	>=dev-python/seaborn-0.13.2[${PYTHON_USEDEP}]
+	>=dev-python/h5py-3.7.0[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	>=dev-python/scikit-learn-1.1.3[${PYTHON_USEDEP}]
+	>=dev-python/statsmodels-0.14.4[${PYTHON_USEDEP}]
+	dev-python/patsy[${PYTHON_USEDEP}]
+	>=dev-python/networkx-2.7.1[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	>=dev-python/numba-0.57.1[${PYTHON_USEDEP}]
+	>=dev-python/umap-learn-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/pynndescent-0.5.13[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	dev-python/session-info2[${PYTHON_USEDEP}]
+	>=dev-python/legacy-api-wrap-1.4.1[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# flaky got an unexpected keyword argument 'reruns'
+	tests/test_backed.py::test_backed_error
+	# related: https://github.com/scverse/scanpy/issues/1418
+	tests/test_plotting.py
+	tests/test_plotting_embedded/test_spatial.py
+)