Add option to disable library installation to avoid GNUInstallDirs warning in submodule usage

[vpetrigo]

When using this library as a submodule in a parent CMake project, the unconditional inclusion of GNUInstallDirs generates a warning during project configuration if no language has been enabled yet in the parent project:

CMake Warning (dev) at /tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:433 (message):
  Unable to determine default CMAKE_INSTALL_LIBDIR directory because no
  target architecture is known.  Please enable at least one language before
  including GNUInstallDirs.
Call Stack (most recent call first):
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:276 (_GNUInstallDirs_LIBDIR_get_default)
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:276 (cmake_language)
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:525 (_GNUInstallDirs_cache_path)
  cmake-build/_deps/printf_library-src/CMakeLists.txt:168 (include)

Additionally, when using the library as a submodule, the installation commands are often unnecessary since the library is built directly as part of the parent project.

Proposed Solution:

Introduce a CMake option to control whether installation commands should be processed:

option(PRINTF_INSTALL_LIBRARY "Install printf library" OFF)

if (PRINTF_INSTALL_LIBRARY)
    include(GNUInstallDirs)
    # ... the rest of the installation commands ...
endif ()

Those changes are:

• Eliminates the warning when using the library as a submodule
• Allows users to opt-in to installation when needed
• Follows common CMake practices for libraries that support both standalone and embedded usage
• Slightly improves configuration time for projects that don't need installation

If this change is acceptable, I'm happy to prepare a pull request implementing it. 😊

[eyalroz]

When using this library as a submodule in a parent CMake project, the unconditional inclusion of GNUInstallDirs generates a warning during project configuration if no language has been enabled yet in the parent project

But how is that possible, given that this repository's CMakeLists enables the C language?

Additionally, when using the library as a submodule, the installation commands are often unnecessary since the library is built directly as part of the parent project.

I think I may not be fully grasping what you mean by 'submodule'. Sorry for being a bit dense perhaps, but can you explain very specifically what you mean by that? including what CMake commands are used in the parent project?

[vpetrigo]

I have that library either as a Git submodule or a CMake FetchContent module:

# Git
git submodule add <printf/url> <dir/in/my/project>
# CMake
FetchContent_Declare(printf_library
        GIT_REPOSITORY https://github.com/eyalroz/printf.git
        GIT_TAG v6.3.0
        EXCLUDE_FROM_ALL)
FetchContent_MakeAvailable(printf_library)

With the Git submodule I then add the printf library as a subdirectory:

set(BUILD_SHARED_LIBS OFF)
add_subdirectory(printf/)
target_compile_options(printf PRIVATE -Wno-overflow)

Doing so results in the warning that I posted in my original message.

[eyalroz]

Putting the whether-or-not-to install issue aside for a second (as it's legit issue and I need to give this a bit of thought and maybe see what other libraries do), let me focus on the the GNUInstallDirs module inclusion. If I use the following CMakeLists.txt:

cmake_minimum_required (VERSION 3.10)
project( foo LANGUAGES CXX)
set(BUILD_SHARED_LIBS OFF)
add_subdirectory(printf/)
add_executable(foo foo.cpp)

with the printf repo as a subdirectory - I don't get any warnings.

Perhaps you add_subdirectory()'ed before defining your own outer-level project?

[vpetrigo]

With the GCC/Clang it normally works fine. In my project I have a XC32 compiler and a custom CMake toolchain file. The MRE available in the attachment. The CMake project generation occurs with the following command:

$ cmake -DCMAKE_TOOLCHAIN_FILE="cmake/toolchain.cmake" -G Ninja -S . -B cmake-build
-- The C compiler identification is GNU 8.3.1
-- Looking for sys/types.h
-- Looking for sys/types.h - found
-- Looking for stdint.h
-- Looking for stdint.h - found
-- Looking for stddef.h
-- Looking for stddef.h - found
-- Check size of long
-- Check size of long - done
-- Check size of long long
-- Check size of long long - done
-- Check size of intmax_t
-- Check size of intmax_t - done
CMake Warning (dev) at C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:433 (message):
  Unable to determine default CMAKE_INSTALL_LIBDIR directory because no                                                                                                                                   
  target architecture is known.  Please enable at least one language before                                                                                                                               
  including GNUInstallDirs.                                                                                                                                                                               
Call Stack (most recent call first):                                                                                                                                                                      
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:276 (_GNUInstallDirs_LIBDIR_get_default)                                                                                        
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:276 (cmake_language)                                                                                                            
  C:/Users/vladi/tools/cmake/share/cmake-4.2/Modules/GNUInstallDirs.cmake:525 (_GNUInstallDirs_cache_path)                                                                                                
  libs/printf/CMakeLists.txt:168 (include)                                                                                                                                                                
This warning is for project developers.  Use -Wno-dev to suppress it.                                                                                                                                     
                                                                                                                                                                                                          
-- Configuring done (2.0s)
-- Generating done (0.0s)
-- Build files have been written to: D:/Projects/c-cpp/temporary/printf_warn/cmake-build

printf_warn.zip

[eyalroz]

And what happens if you move the include(GNUInstallDirs) somewhere else? e.g. to the end of your outer CMakeLists.txt? And turn off the install commands with the option like you suggested? Do you not get the same warning?

[vpetrigo]

The following changes remove the warning:

Subject: [PATCH] cmake: Add installation enable/disable option
---
Index: CMakeLists.txt
IDEA additional info:
Subsystem: com.intellij.openapi.diff.impl.patch.CharsetEP
<+>UTF-8
===================================================================
diff --git a/CMakeLists.txt b/CMakeLists.txt
--- a/CMakeLists.txt	(revision f1b728cbd5c6e10dc1f140f1574edfd1ccdcbedb)
+++ b/CMakeLists.txt	(date 1771083833980)
@@ -12,6 +12,7 @@
 
 option(BUILD_TESTS          "Build test programs for the library" OFF)
 option(BUILD_SHARED_LIBS    "Build the library as a shared (dynamically-linked) object rather than a static one " ON)
+option(PRINTF_ENABLE_INSTALL "Enable printf library install" ON)
 
 # Boolean options which go into config.h
 
@@ -165,55 +166,57 @@
 # Installation
 # -------------------------
 
-include(GNUInstallDirs)
+if (PRINTF_ENABLE_INSTALL)
+	include(GNUInstallDirs)
 
-# Note: No need for a config.cmake file for setting dependencies - as there
-# are no dependencies; this library is self-contained
+	# Note: No need for a config.cmake file for setting dependencies - as there
+	# are no dependencies; this library is self-contained
 
-install(
-	TARGETS printf
-	EXPORT printf_export
-	RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
-	ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
-	LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
-	INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
-)
+	install(
+			TARGETS printf
+			EXPORT printf_export
+			RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+			ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+			LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+			INCLUDES DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
+	)
 
-install(
-	FILES "src/printf/printf.h"
-	DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/printf"
-)
+	install(
+			FILES "src/printf/printf.h"
+			DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/printf"
+	)
 
-export(
-	EXPORT printf_export
-	NAMESPACE "printf::"
-	FILE "${PROJECT_BINARY_DIR}/printf-targets.cmake"
-)
+	export(
+			EXPORT printf_export
+			NAMESPACE "printf::"
+			FILE "${PROJECT_BINARY_DIR}/printf-targets.cmake"
+	)
 
-install(
-	EXPORT printf_export
-	FILE "printf-targets.cmake"
-	DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
-	NAMESPACE "printf::"
-)
+	install(
+			EXPORT printf_export
+			FILE "printf-targets.cmake"
+			DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
+			NAMESPACE "printf::"
+	)
 
-include(CMakePackageConfigHelpers)
+	include(CMakePackageConfigHelpers)
 
-configure_package_config_file(
-	"cmake/printf-config.cmake.in"
-	"${CMAKE_CURRENT_BINARY_DIR}/printf-config.cmake"
-	INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
-)
+	configure_package_config_file(
+			"cmake/printf-config.cmake.in"
+			"${CMAKE_CURRENT_BINARY_DIR}/printf-config.cmake"
+			INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
+	)
 
-write_basic_package_version_file(
-	"printf-config-version.cmake"
-	VERSION ${PROJECT_VERSION}
-	COMPATIBILITY SameMinorVersion
-)
+	write_basic_package_version_file(
+			"printf-config-version.cmake"
+			VERSION ${PROJECT_VERSION}
+			COMPATIBILITY SameMinorVersion
+	)
 
-install(
-	FILES
-		"${CMAKE_CURRENT_BINARY_DIR}/printf-config-version.cmake"
-		"${CMAKE_CURRENT_BINARY_DIR}/printf-config.cmake"
-	DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
-)
+	install(
+			FILES
+			"${CMAKE_CURRENT_BINARY_DIR}/printf-config-version.cmake"
+			"${CMAKE_CURRENT_BINARY_DIR}/printf-config.cmake"
+			DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/printf"
+	)
+endif ()

Then in CMakeLists.txt:

set(BUILD_SHARED_LIBS OFF)
set(PRINTF_ENABLE_INSTALL OFF)
FetchContent_Declare(printf_library
        GIT_REPOSITORY https://github.com/eyalroz/printf.git
        GIT_TAG v6.3.0
        EXCLUDE_FROM_ALL)
FetchContent_MakeAvailable(printf_library)

Result:

cmake -DCMAKE_TOOLCHAIN_FILE="cmake/toolchain.cmake" -G Ninja -S . -B cmake-build --fresh
-- The C compiler identification is GNU 8.3.1
-- Looking for sys/types.h
-- Looking for sys/types.h - found
-- Looking for stdint.h
-- Looking for stdint.h - found
-- Looking for stddef.h
-- Looking for stddef.h - found
-- Check size of long
-- Check size of long - done
-- Check size of long long
-- Check size of long long - done
-- Check size of intmax_t
-- Check size of intmax_t - done
-- Configuring done (2.4s)
-- Generating done (0.0s)
-- Build files have been written to: D:/Projects/c-cpp/temporary/printf_warn/cmake-build

[vpetrigo]

Hey @eyalroz, sorry for bothering you. Would like to confirm whether you would accept a PR with the proposed changes above or not? Ultimately, nothing would change for an end user. That option would allow to disable installation step skipping of the printf library if necessary.

[eyalroz]

I'm the one who should apologize, I should have attended to this sooner. I would accept a relevant PR, yes.

[eyalroz]

I commited a prospective fix onto a separate branch. What do you think? It's a bit crude...

[vpetrigo]

For me the fix looks good. One thing to mention: if someone adds CMake commands not related to installation routine after line 232, they will not be executed if PRINTF_NO_INSTALL flag is set:

printf/CMakeLists.txt

Line 232 in f6af071

)

Besides that, the update do the necessary exclusion of the GNUInstallDirs module which produces warnings under some environments.

[eyalroz]

One thing to mention: if someone adds CMake commands not related to installation routine after line 232, they will not be executed if PRINTF_NO_INSTALL flag is set

Well, it's a stretch, and I wanted to avoid indentation, but I guess better to be on the safe side for the sake of library users not shooting themselves in the foot. Done, and merging this.