m2-localization/demo-plaintext.monkey2 at master · engor/m2-localization · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

Namespace jentos.locale.demo.plaintext

#Import "<std>"
#Import "<mojo>"
#Import "<mojox>"
#Import "Localization"

#Import "assets/"

Using std..
Using mojo..
Using mojox..
Using jentos.locale..


Function Main()

	' we can load single file format
	'Locale.Load( "asset::translation.json","en" )

	' or directory format
	Locale.Load( "asset::locale/","en" )

	New AppInstance

	New MyWindow

	App.Run()
End


Class MyWindow Extends Window

	Method New()

		Super.New( "",640,480,WindowFlags.Resizable )

		' we update all texts when lang was changed only
		'
		' don't use LocString() in your render loop
		' because it will find string in Map every time

		Locale.LangChanged+=Texts.Actualize

		' also need to assign texts for current lang
		Texts.Actualize()

		' update window title via lambda-binding
		Localized( "app-title",Lambda( t:String )
			Title=t
		End )

	End

	Method OnRender( canvas:Canvas ) Override

		canvas.DrawText( Texts.HelloWorld,20,50 )
		canvas.DrawText( Texts.Hint,20,120 )

		If Keyboard.KeyHit( Key.Enter )
			Local lang:=Locale.Lang="en" ? "ru" Else "en"
			Locale.SetLang( lang )
		Endif

		RequestRender()
	End

	' store all texts of app in special class
	' to simplify access for them
	' use them as read-only members
	'
	Class Texts

		Global AppTitle:=""
		Global HelloWorld:=""
		Global Hint:=""

		Function Actualize()

			AppTitle=Localized( "app-title" )
			HelloWorld=Localized( "hello-world" )
			Hint=Localized( "hint" )
		End
	End

End