Confirm overwriting uncommitted changes when checking out branch

Author: Jeremy Wootten

src/Dialogs/OverwriteUncommittedConfirmationDialog.vala

@@ -0,0 +1,43 @@
+/*
+* Copyright 2025 elementary, Inc. (https://elementary.io)
+*
+* This program is free software; you can redistribute it and/or
+* modify it under the terms of the GNU Lesser General Public
+* License version 3 as published by the Free Software Foundation.
+*
+* This program is distributed in the hope that it will be useful,
+* but WITHOUT ANY WARRANTY; without even the implied warranty of
+* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+* General Public License for more details.
+*
+* You should have received a copy of the GNU Lesser General Public
+* License along with this program; if not, write to the
+* Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
+* Boston, MA 02110-1301 USA
+*/
+
+public class Scratch.Dialogs.OverwriteUncommittedConfirmationDialog : Granite.MessageDialog {
+
+    public string branch_name { get; construct; }
+    public OverwriteUncommittedConfirmationDialog (Gtk.Window parent, string new_branch_name) {
+        Object (
+            buttons: Gtk.ButtonsType.NONE,
+            transient_for: parent,
+            branch_name: new_branch_name
+        );
+    }
+
+    construct {
+        modal = true;
+        image_icon = new ThemedIcon ("dialog-stop");
+
+        primary_text = _("There are uncommitted changes in the current branch");
+        ///TRANSLATORS '%s' is a placeholder for the name of the branch to be checked out
+        secondary_text = _("Uncommitted changes will be permanently lost if <b>'%s'</b> is checked out now.\n\n<i>It is recommended that uncommitted changes are stashed, committed, or reverted before proceeding </i>").printf (branch_name);
+
+        var proceed_button = (Gtk.Button) add_button (_("Checkout and Overwrite"), Gtk.ResponseType.ACCEPT);
+        proceed_button.get_style_context ().add_class (Gtk.STYLE_CLASS_DESTRUCTIVE_ACTION);
+        var cancel_button = add_button (_("Do not Checkout"), Gtk.ResponseType.REJECT);
+        cancel_button.get_style_context ().add_class (Gtk.STYLE_CLASS_SUGGESTED_ACTION);
+    }
+}

src/Services/MonitoredRepository.vala

@@ -254,8 +254,13 @@ namespace Scratch.Services {
             checkout_branch (local_branch);
         }
 
-        private void checkout_branch (Ggit.Branch new_head_branch) {
+        private void checkout_branch (Ggit.Branch new_head_branch, bool confirm = true) {
             //TODO Check current head has no uncommitted changes.since we FORCE the checkout.
+            if (confirm && has_uncommitted) {
+                confirm_checkout_branch (new_head_branch);
+                return;
+            }
+
             git_repo.set_head (((Ggit.Ref)new_head_branch).get_name ());
             // This will force all changes in current branch to be overwritten even if uncommitted.
             // Using SAFE results in unwanted diff files in the staging area even if there are no uncommitted changes
@@ -267,6 +272,19 @@ namespace Scratch.Services {
             branch_name = new_head_branch.get_name ();
         }
 
+        private void confirm_checkout_branch (Ggit.Branch new_head_branch) {
+            var parent = ((Gtk.Application)(GLib.Application.get_default ())).get_active_window ();
+            var dialog = new Scratch.Dialogs.OverwriteUncommittedConfirmationDialog (parent, new_head_branch.get_name ());
+            dialog.response.connect ((res) => {
+                dialog.destroy ();
+                if (res == Gtk.ResponseType.ACCEPT) {
+                    checkout_branch (new_head_branch, false);
+                }
+            });
+
+            dialog.present ();
+        }
+
         public void create_new_branch (string name) throws Error {
             Ggit.Object git_object = git_repo.get_head ().lookup ();
             var new_branch = git_repo.create_branch (name, git_object, Ggit.CreateFlags.NONE);

src/meson.build

@@ -20,6 +20,7 @@ code_files = files(
     'Utils.vala',
     'Dialogs/PreferencesDialog.vala',
     'Dialogs/RestoreConfirmationDialog.vala',
+    'Dialogs/OverwriteUncommittedConfirmationDialog.vala',
     'Dialogs/GlobalSearchDialog.vala',
     'Dialogs/NewBranchDialog.vala',
     'FolderManager/File.vala',