backbone/flake.nix at trunk · electrichive/backbone · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
{
  description = "electrichive infrastructure as code";
  inputs = {
    devshell.url = github:numtide/devshell;
    flake-utils.url = github:numtide/flake-utils;
    nixpkgs.url = github:nixos/nixpkgs;
    terranix.url = github:terranix/terranix;
  };
  outputs =
    inputs@{ self
    , devshell
    , flake-utils
    , nixpkgs
    , terranix
    }: flake-utils.lib.eachDefaultSystem (system:
    let
      project = "hive";
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ devshell.overlay ];
      };
      tf = rec {
        config = terranix.lib.terranixConfiguration {
          inherit system;
          modules = [ ./infra ];
        };
        commandToApp = command: {
          type = "app";
          program = toString (pkgs.writers.writeBash "${command}" ''
            result="config.tf.json"
            terraform="${pkgs.terraform}/bin/terraform"
            [[ -e $result ]] && rm -f $result
            cp ${config} $result
            $terraform init
            $terraform ${command}
          '');
        };
      };
    in
    rec {
      packages.tf = tf.config;
      packages.default = packages.tf;

      apps = pkgs.lib.genAttrs [ "apply" "plan" "destroy" ] tf.commandToApp;

      devShell = pkgs.devshell.mkShell {
        name = "${project}-shell";
        commands = [{ package = "devshell.cli"; }];
        packages = with pkgs; [
          awscli2
        ];
      };
    }
    );
}