sortbloom/paper_plot_workload_time.gp at main · efficient/sortbloom · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
### Common styling
set title "Bloom filter query time for different workloads" font ",24"
set ylabel "Average time per query (ns)" font ",22"
set xlabel "Positive queries (%)" font ",22"
set grid ytics
set key samplen 2 width -2 font ",19"
set tics font ",14"
set terminal pdfcairo size 6in,4in color enhanced font "Helvetica,11" linewidth 2 rounded
# set yrange [0:40]
set yrange [0:40]
set bmargin 4
set key maxrows 4
set key opaque

# X axis: show integer ticks and range -0.5..5.5
set xrange [-0.5:5.5]
set xtics 1
set mxtics 1

# Optional: reference line at speedup = 1
# set arrow 1 from graph 0, first 1 to graph 1, first 1 nohead dt 2

# Path prefix (may be overridden via `gnuplot -c paper_plot_speedup_lines.gp PREFIX`)
prefix = "results/plots/final_workload_2/"
if (exists("ARGC") && ARGC >= 1) {
    prefix = ARG1
}

# set yrange [1:1.5]
set output "paper-bf-workload-time.pdf"

# plot \
#   prefix . "CustRangeMap--no-sort.raw"               using 4:2:3 with yerrorlines lt 8 pt 7 title "baseline", \
#   prefix . "CustRangeMap--full-sort.raw"               using 4:2:3 with yerrorlines lc rgb "#009E73" pt 7 title "full-sort", \
#   prefix . "CustRangeMap--partial-lut-big-0-16.raw"    using 4:2:3 with yerrorlines lt 5 pt 7 title "partition-16", \
#   prefix . "LdsRangeMap--full-sort.raw"                using 4:2:3 with yerrorlines lt 6 pt 7 title "lds-full-sort", \
#   prefix . "LdsRangeMap--partial-lut-big-0-16.raw"     using 4:2:3 with yerrorlines lt 4 pt 7 title "lds-partition-16", \
#   prefix . "CustRangeMap--no-sort-16.0-hs4s4.raw"         using 4:2:3 with yerrorlines lt 7 pt 7 title "cpsbbf(4,4)", \
#   prefix . "CustRangeMap--no-sort-16.0-sbbf.raw"         using 4:2:3 with yerrorlines lt 1 pt 7 title "sbbf *", \
#   prefix . "CustRangeMap--no-sort-16.0-cbf.raw"        using 4:2:3 with yerrorlines lt 2 pt 7 title "cbf *", \
#   prefix . "CustRangeMap--no-sort-16.0-pbf.raw"        using 4:2:3 with yerrorlines lt 3 pt 7 title "pbf *"

# If you want the draw order and key order to be different, use keyentry
plot \
  prefix . "CustRangeMap--no-sort.raw"                 using 4:2:3 with yerrorlines lt 8 pt 7 notitle, \
  prefix . "CustRangeMap--full-sort.raw"               using 4:2:3 with yerrorlines lc rgb "#009E73" pt 7 notitle, \
  prefix . "LdsRangeMap--full-sort.raw"                using 4:2:3 with yerrorlines lt 6 pt 7 notitle, \
  prefix . "CustRangeMap--no-sort-16.0-pbf.raw"        using 4:2:3 with yerrorlines lt 3 pt 7 notitle, \
  prefix . "CustRangeMap--no-sort-16.0-cbf.raw"        using 4:2:3 with yerrorlines lt 2 pt 7 notitle, \
  prefix . "CustRangeMap--partial-lut-big-0-16.raw"    using 4:2:3 with yerrorlines lt 5 pt 7 notitle, \
  prefix . "LdsRangeMap--partial-lut-big-0-16.raw"     using 4:2:3 with yerrorlines lt 4 pt 7 notitle, \
  prefix . "CustRangeMap--no-sort-16.0-hs4s4.raw"      using 4:2:3 with yerrorlines lt 7 pt 7 notitle, \
  prefix . "CustRangeMap--no-sort-16.0-sbbf.raw"       using 4:2:3 with yerrorlines lt 1 pt 7 notitle, \
  \
  keyentry with yerrorlines lt 8 pt 7 title "baseline *", \
  keyentry with yerrorlines lc rgb "#009E73" pt 7 title "full-sort", \
  keyentry with yerrorlines lt 5 pt 7 title "partition-16", \
  keyentry with yerrorlines lt 6 pt 7 title "lds-full-sort", \
  keyentry with yerrorlines lt 4 pt 7 title "lds-partition-16", \
  keyentry with yerrorlines lt 7 pt 7 title "cpsbbf(4,4)", \
  keyentry with yerrorlines lt 1 pt 7 title "sbbf *", \
  keyentry with yerrorlines lt 2 pt 7 title "cbf *", \
  keyentry with yerrorlines lt 3 pt 7 title "pbf *"


unset output